XL 2016 Trouver et sommer des tps symbolisés par un nom (voir fichier joint)

[XLMan]

Bonjour à tous,
Je souhaite créer un calendrier au mois et je tombe sur un Pb que je n'arrive pas à solutionner et j'ai besoin d'une aide d'expert sur une formule matricielle qui est censée cumuler l'équivalent tps de la journée considérée lorsque je trouve "Vcs". En fait comme exemple si je trouve "Vcs" en regard du mercredi pour Em eline je souhaite additionner le tps correspondant du mercredi soit 4:30 à toutes les autres Vs que je trouve. Et ce ds une seule cellule type matricielle.

J'ai décomposé la formule matricielle : {=SOMME(SI($H7:$AL7="Vcs";INDEX(Tab_nb_heures_jour;EQUIV($A7;personnel_nb_heure_jour;0);EQUIV(TEXTE($H$3:$AL$3;"jjj");jour_semaine_court;0));""))} du mieux que j'ai pu pour rendre explicite mon pb, voir exemple fourni. J'y suis presque mais je n'obtiens pas le résultat escompté ???

J'ai joint un fichier light avec 3 onglets dont "Calendrier mois" où trouver le détail de la formule

En espérant avoir été claire.

Merci d'avance à vous tous pour votre aide sur cette formule.

Gaëlle

 

[Jocelyn]

Bonjour le Forum,
Bonjour XLMan,

un essai en fichier joint

Cordialement

 

[job75]

Bonjour XLMan, salut Jocelyn, heureux de te revoir,

Une formule matricielle assez simple en E5 du fichier joint :

=SOMME((H5:AL5="Vcs")*(H$3:AL$3=TRANSPOSE(jour_semaine_court))*TRANSPOSE(DECALER(jour_semaine_court;EQUIV(A5;personnel_nb_heure_jour;0);)))

A+

 

[XLMan]

Bonjour Jocelyn, Job75,
Vous êtes des champions. Je comprends pourquoi je n'y arrivais pas vu la complexité de la formule. Les 2 fonctionnent mais la concision de la formule de Job75 me va bien.

Juste que si Job75 pouvait m'expliquer en qq mots pourquoi transpose et décaler. Bref comment elle marche pour moi-même m'améliorer.
En tout cas merci encore à vous deux. C'est hyper sympa.
A+
Gaëlle

 

[job75]

DECALER permet de décaler comme il faut vers le bas la plage T2:Z2 de la feuille Cfg.

TRANSPOSE est nécessaire parce que les 2 plages jour_semaine_court et DECALER(xxx) n'ont pas la même largeur que les 2 plages H5:AL5 et H$3:AL$3.

La fonction SOMME opère donc sur une matrice à 2 dimensions, c'est une méthode assez classique.

 

[Jocelyn]

Bonjour Job75 , je ne songe jamais à ce transpose

Bonne journée a tous

 

[XLMan]

Merci @Jocelyn et @job75 pour l'explication.
Juste un point, si je trouve autre chose que "Vcs" par exemple EM (comme Enfants malades) et M comme Maladie. Comment je fais pour les ajouter car j'ai essayé ceci et ça ne marche pas. C'est pourtant logique !!! :
{=SOMME((H9:AL9="Vcs")*(H9:AL9="EM")*(H9:AL9="M")*(H$3:AL$3=TRANSPOSE(jour_semaine_court))*TRANSPOSE(DECALER(jour_semaine_court;EQUIV(A9;personnel_nb_heure_jour;0))]

ou même
{=SOMME(OU(H9:AL9="Vcs");(H9:AL9="EM");(H9:AL9="M"))*(H$3:AL$3=TRANSPOSE(jour_semaine_court))*TRANSPOSE(DECALER(jour_semaine_court;EQUIV(A9;personnel_nb_heure_jour;0))]

Voir mon fichier (attention j'ai remplacé les formules et tapé directement EM et M ds les cases mais ça ne gêne pas pour le calcul à réaliser.

Merci encore pour votre aide
Gaëlle

 

[XLMan]

Désolé mais je ne sais pas pourquoi il y a 2 smiley à la place du ; . Ils sont arrivés quand j'ai envoyé le message ???

 

[job75]

Bonjour XLMan, Jocelyn, le forum,

En matriciel OU se traduit par l'opérateur + ET par l'opérateur * donc formule matricielle en E5 :

=SOMME(((H5:AL5="Vcs")+(H5:AL5="M")+(H5:AL5="EM"))*(H$3:AL$3=TRANSPOSE(jour_semaine_court))*TRANSPOSE(DECALER(jour_semaine_court;EQUIV(A5;personnel_nb_heure_jour;0);)))

Quant aux smileys ils sont dus aux 2 caractères point virgule et parenthèse, avec les balises de code il n'y a plus ce problème.

A+

 

[XLMan]

Bonjour Job75,
Merci pour le retour mais j'avais également essayé celle-ci mais ça ne fonctionne pas.
En appliquant votre formule je trouve 2:15 avec des parenthèses de moins je trouve 13:45 alors que finalement je devrais avoir 35:45 (voir fichier joint)

Encore merci pour votre aide
Gaëlle

 

[job75]

En appliquant votre formule je trouve 2:15

Bah il faut mettre la colonne E au format personnalisé [h]:mm ce qui donne 26:15.

 

[XLMan]

Oups merci pour l'info je n'ai pas fait gaffe. C'est piégeant ce truc
Bon WE
Gaëlle