Transposition Horizontale / Verticale

[jipi06]

Bonjour à toutes et tous

j'a un tableau horizontal de 500 lignes et 12 colonnes
ex extrait
Pierre ; A ; 6 ; 15 ; 9 ; 43
Paul ; A ; 9 ; 43
Jacques ; A ; 43 ; 25 ; 13

Je voudrais obtenir un résultat en vertical de ce type :

Nom Dir Action
Pierre A 6
Pierre A 15
Pierre A 9
Pierre A 43
Paul A 9
Paul A 43
Jacques A 43
Jacques A 25
Jacques A 13

J'ai essayé les TCD et la fonction Transpose sans succès.
Je join un fichier exemple ss doute plus explicite.

Merci de votre aide

 

[Minick]

Re : Transposition Horizontale / Verticale

Salut,

Un exemple (le resultat sera sur la meme feuille a partir de M10:

Option Explicit

Sub TransposeBdd()
    Dim LigSrc  As Integer, LigDst As Integer, ColSrc As Byte
    
    Application.ScreenUpdating = False
        With Sheets("Liste")
            LigDst = 10
            For LigSrc = 2 To .Range("A65536").End(xlUp).Row
                If Application.WorksheetFunction.CountA(.Range("C" & LigSrc & ":L" & LigSrc)) <> 0 Then
                    For ColSrc = 3 To 12
                        If Not IsEmpty(.Cells(LigSrc, ColSrc)) Then
                            .Range("M" & LigDst).Value = .Range("A" & LigSrc).Value
                            .Range("N" & LigDst).Value = .Range("B" & LigSrc).Value
                            .Range("O" & LigDst).Value = .Cells(LigSrc, ColSrc).Value
                            LigDst = LigDst + 1
                        End If
                    Next ColSrc
                End If
            Next LigSrc
        End With
    Application.ScreenUpdating = True
End Sub

 

[jipi06]

Re : Transposition Horizontale / Verticale

Merci Beaucoup

c'est exactement ce que je cherchais...

A bientôt

 

[Manu62]

Re : Transposition Horizontale / Verticale

Salut,

A voir si cela convient

C'est le même résultat que Minick sans VBA avec la fonction equiv et index

A+

Manu