Microsoft 365 Transformer une date dynamique en fixe après transfert

[ChantalTreize]

Bonjour tout le monde,
J'ai un formulaire avec une date au format Aujourdhui() lorsque je l'envoie dans la BDD elle reste à ce format.
Ce que je voudrais c'est que cette date se transforme en format fixe pour que ça ne bouge plus
Est ce dans le domaine du réalisable ou pure utopie ?
Par avance un grand merci
Chantal

 

[patricktoulon]

re
Bonjour
puré!! vous avez un tableau structuré comme BDD servez vous en comme tel
arrêtez les copy insert et paste comme avec un range normal c'est archaïque

 

[Chris401]

Bonjour
Essaye ce code :

Sub Enregistrement()
    Sheets("BDD").Range("B3").EntireRow.Insert
    Sheets("Formulaire").Range("B4:D4").Copy
    Sheets("BDD").Range("B3").PasteSpecial Paste:=xlPasteValues
    Application.CutCopyMode = False
End Sub

 

[patricktoulon]

re
purée lea tableaux structuré sont sensé vous simplifier la vie
apprenez a vous en servir!!
voila la bonne méthode
c'est simple rapide et efficace
vous constaterez que la date en bdd n'est plus la formule "=AUJOUDHUI()"

Sub Enregistrement()
'patricktoulon
    With Range("Tableau1").ListObject
        .ListRows.Add(1).Range.Value = Range("B4:D4").Value
    End With
End Sub

c'est pas compliqué non !!???

 

[Hasco]

Bonjour,

voici une proposition. J'ai rajouté quelques fonctionalités qui me semblaient opportunes mais vous ferez comme vous voudrez. Dans la macro, il n'y a pas copie des cellules mais seulement de leur valeur.

Sub Enregistrement()
Dim lr As ListRow
    '
    ' Travailler à partir du tableau structuré de la feuille BDD
    With ThisWorkbook.Sheets("BDD").ListObjects("Tableau1")
        ' Récupérer sa ligne d'insertion ou en créer une nouvelle
        If .InsertRowRange Is Nothing Then
            Set lr = .ListRows.Add()
        Else
            Set lr = .InsertRowRange()
        End If
    End With
    '
    ' Alimenter la ligne du tableau
    With ThisWorkbook.Sheets("Formulaire").Range("B4:D4")
    lr.Range.Value = .Value
       If MsgBox("Données enregistrées!" & vbCrLf & _
                    "Voulez-vous effacer les données du formulaire ?", _
                    vbQuestion + vbYesNo, "Enregistrer") = vbYes Then
        ' Si oui
        ' Vider les données à droite de la date du jour
        .Offset(, 1).Resize(, .Columns.Count - 1) = Empty
       End If
       ' Pour repartir sur une nouvelle saisie
        .Cells(2).Select
    End With
End Sub

Cordialement

[Edition] Je ne sais pas pourquoi les messages précédents (à part ceux d'un blacklisté) ne sont pas apparus, même au rafraîchissement !?
@David Aubert : Super l'icône "Copier dans le presse papier" dans l'éditeur de ligne de code 🙂
[/Edition]

 

[David Aubert]

Bonjour à tous,
Merci @Hasco pour le commentaire sur la copie de code mais malheureusement cela ne fonctionne pas encore, en tout cas pas chez moi.
Cela fonctionne chez vous?
Merci
David

 

[Hasco]

Hello @David Aubert ,

J'avais pas testé 🙁 Hélas non, ça ne fonctionne pas encore ! Mais je suis sûr que tu arriveras à nous faire quelque chose 🙂
bonne journée à toi
Ges