Totaliser des colonnes identiques MAIS sur plusieurs feuilles

[mike13]

Bonjour le Forum,

J'ai beau chercher et me creuser la tête, je n'arrive pas à totaliser des ventes pour chaque vendeur dès l'instant où je dois les totaliser avec plusieurs feuilles.
J'utilise la formule suivante : =SOMMEPROD(('Mois 1:[Mois 3]Mois 3'!A2:A15="Michel")*('Mois 1:[Mois 3]Mois 3'!B2:B15<>"")) qui me renvoie #REF! car je sélectionne 3 feuilles.
Or sur une seule feuille, çà marche bien.

Le fichier joint explique certainement mieux mes propos.

Merci par avance pour votre aide.

Mike13

 

[pierrejean]

Re : Totaliser des colonnes identiques MAIS sur plusieurs feuilles

Bonjour Mike13

Sugestion:

=SOMMEPROD((A2:A15="Michel")*(B2:B15<>""))+SOMMEPROD(('Mois 2'!A2:A15="Michel")*('Mois 2'!B2:B15<>""))+SOMMEPROD(('Mois 3'!A2:A15="Michel")*('Mois 3'!B2:B15<>""))

 

[mike13]

Re : Totaliser des colonnes identiques MAIS sur plusieurs feuilles

Merci

Est ce que c'est la seule solution (je t'en remercie PierreJean) car j'ai un tableau avec 12 feuilles ?

Mike13

 

[BOISGONTIER]

Re : Totaliser des colonnes identiques MAIS sur plusieurs feuilles

Bonjour,

En 3D

Pour 12 feuilles LIGNE($1:$12) et 26 lignes (COLONNE(A:Z))

=SOMMEPROD((T(DECALER(INDIRECT("'"&"Mois "& LIGNE($1:$12)&"'!a2");COLONNE(A:Z)-1;0))=A3)*(T(DECALER(INDIRECT("'"&"Mois "&LIGNE($1:$12)&"'!b2");COLONNE(A:Z)-1;0))<>""))

JB

 

[mike13]

Re : Totaliser des colonnes identiques MAIS sur plusieurs feuilles

Vous êtes géniaux, comme d'hab, mais Boisgontier, je ne la comprends pas. Et pourtant, elle marche super.
En plus facile, est ce possible ?
Je sais mes lacunes et m'en excuse.

Mike13

 

[BOISGONTIER]

Re : Totaliser des colonnes identiques MAIS sur plusieurs feuilles

Si le test se fait uniquement sur la première colonne

=SOMMEPROD(NB.SI(INDIRECT("'Mois "&LIGNE($1:$12)&"'!A2:A26");A3))

Formules Matricielles 3D

JB

 

[mike13]

Re : Totaliser des colonnes identiques MAIS sur plusieurs feuilles

Re,

Merci à tous pour vos bons plans

Mike13