Bonjour,
Je récapitule aussi.
=SOMMEPROD((A1:A3)*(B1:B3=3))
fait la somme des cellules de la colonne A dont la cellule située sur la même ligne en colonne B est égale à 3
Même chose mais en mieux car, sous cette forme, A1:A10 peut contenir autre chose que des valeurs numériques :
=SOMMEPROD((A1:A10);(B1:B10=3)*1)
En général, on l'écrit dans l'autre sens, la plage à sommer à la fin :
=SOMMEPROD((B1:B10=3)*1;A1:A10)
Le *1 sert à rendre numérique le résultat de (B1:B10=3)
(on peut mettre aussi /1 ou +0 ou -0)
Sinon, c'est une succession de VRAI et FAUX
=SOMMEPROD(({FAUX;FAUX;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX})*1;{7;8;9;0;0;0;0;0;0;0})
VRAI pour 1 et FAUX pour 0
=SOMMEPROD(({0;0;1;0;0;0;0;0;0;0});{7;8;9;0;0;0;0;0;0;0})
Si tu valides ces 2 dernières formules, tu obtiens le même résultat qu'avec la formule d'origine.
Les 2 matrices, c'est {0;0;1;0;0;0;0;0;0;0} et {7;8;9;0;0;0;0;0;0;0}
Le VRAI et le FAUX
Si tu tapes dans une cellule =VRAI, tu obtiens VRAI (heureusement)
Si tu tapes =VRAI*1, tu obtiens 1
=VRAI+VRAI, tu obtiens 2
=VRAI+FAUX, tu obtiens 1
=VRAI*FAUX, tu obtiens 0
Si tu as plusieurs critères :
=SOMMEPROD((B1:B10=3)*(C1:C10="Toto")*(D1
10=10)*(E1:E10="ok");A1:A10)
fait la somme des cellules de la colonne A, à condition qu'il y ait sur la même ligne :
3 en colonne B,
toto ou TOTO ou tOtO en colonne C,
10 en colonne D,
ok en colonne E
Là, pas besoin de rendre numérique les valeurs entre parenthèses, le * entre chaque critère le fait.
Dans ce genre de formules,
Le * équivaut au ET des formules conditionneles classiques,
le + équivaut au OU
et le moins veut dire "sauf"
=SOMMEPROD(((B1:B10=3)+(B1:B10=2));A1:A10)
fait la somme des cellules de la colonne A dont la cellule située sur la même ligne en colonne B est égale soit à 3 soit à 2
=SOMMEPROD((ESTNUM(B1:B10)-(B1:B10=1));A1:A10)
fait la somme des cellules de la colonne A dont la cellule située sur la même ligne en colonne B contient n'importe quel nombre sauf 1.
Cette impression que tu as que l'on pouvait également écrire :
=SOMMEPROD(A1:A5;B1:B5=3)
ce n'est pas qu'une impression, sauf que "=3" est en trop ou bien je ne vois pas ce que tu veux dire.
Sous cette forme, d'accord :
=SOMMEPROD(A1:A5;B1:B5)
Cette formule fait la somme des produits, ligne par ligne :
=A1*B1+A2*B2+A3*B3+A4*B4+A5*B5
Celle-ci fait la somme des produits, colonne par colonne :
=SOMMEPROD(A12:Z12;A13:Z13)
elle équivaut à :
=A12*A13+B12*B13+C12*C13+etc+etc
Un peu long pour un récapitulatif.…