XL 2010 supprimer un chiffre si et seulement si placé en début de cellule

CISCO

XLDnaute Barbatruc

• 3 Février 2017

• #2

Bonsoir

Essaye avec

Code:

=SI(ESTNUM(--STXT(A1;1;1));STXT(A1;CHERCHE(" ";A1);9^9);A1)

@ plus

 

Vote positif 0 Vote négatif

B

Boo2bafoot

XLDnaute Nouveau

• 3 Février 2017

• #3

Salut Seb,

Teste cette formule en A2 :

Code:

=SI(ESTNUM(GAUCHE(A1;1)*1);DROITE(A1;NBCAR(A1)-CHERCHE(" ";A1));A1)

Bonne soirée

Edit: Je n'avais pas vu la réponse de Cisco, que je salue... Désolé si ça fait doublon

 

Vote positif 0 Vote négatif

sebbbbb

XLDnaute Impliqué

• 3 Février 2017

• #4

Parfait
merci à vous 2
quelle réactivité !

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 4 Février 2017

• #5

Bonjour sebbbbb, CISCO, Boo2bafoot,

Une autre solution :

Code:

=SUPPRESPACE(STXT(A1;MAX(1;ESTNUM(-GAUCHE(A1))*TROUVE(" ";A1&" "));9^9))

Noter que TROUVE(" ";A1&" ") évite de renvoyer une erreur s'il n'y a aucun espace en A1.

Remarquer que cette formule évite la fonction SI grosse consommatrice d'octets en mémoire :

- formule de CISCO => 68 octets (mais elle serait à compléter car elle donne un espace superflu)

- formule de Boo2bafoot => 71 octets

- formule de job75 => 56 octets.

A+

 

Vote positif 0 Vote négatif

sebbbbb

XLDnaute Impliqué

• 4 Février 2017

• #6

Super
Merci

 

Vote positif 0 Vote négatif

sebbbbb

XLDnaute Impliqué

• 4 Février 2017

• #7

Excellent
Merci

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 4 Février 2017

• #8

Re,

Optimisée pour fonctionner dans tous les cas de figure, la formule avec SI de CISCO :

Code:

=SUPPRESPACE(SI(ESTNUM(-GAUCHE(A1));STXT(A1;CHERCHE(" ";A1&" ");9^9);A1))

"pèse" 70 octets.

A+

 

Vote positif 0 Vote négatif

sebbbbb

XLDnaute Impliqué

• 9 Août 2017

• #9

bonjour
est il possible d'adapter cette formule pour que ce soit l'inverse ; cad que seule les chiffres figurant à gauche apparaissent et pas le reste.
un grand merci par avance
seb

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 9 Août 2017

• #10

Bonsoir sebbbbb,

Si le nombre situé en tête est séparé du reste par un espace :

Code:

=SIERREUR(--GAUCHE(A1;TROUVE(" ";A1&" "));"")

A+

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 9 Août 2017

• #11

Re,

Si le nombre en tête n'est pas toujours séparé du reste par un espace :

Code:

=SIERREUR(--GAUCHE(A1;SOMMEPROD(--ESTNUM(-(GAUCHE(A1;LIGNE(INDIRECT("1:"&NBCAR(A1))))&0))));"")

Edit : &0 est nécessaire au cas où le texte qui suit commence par " a" ou " p", voyez ce fil :

https://www.excel-downloads.com/threads/12-a-ou-12-p.20019156/

En outre cela permet de récupérer des nombres négatifs.

Bonne nuit.

 

Dernière édition: 10 Août 2017

Vote positif 0 Vote négatif

sebbbbb

XLDnaute Impliqué

• 10 Août 2017

• #12

EXCELLENT ! encore une fois
merci infiniment
seb

 

Vote positif 0 Vote négatif