Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

XL 2019 Supprimer noms des colonnes d'une feuille

C

carlos

XLDnaute Impliqué
Supporter XLD
Bonjour,
J'aimerais effacer les noms attribués aux colonnes avec ce code mais cela ne marche pas.
Private Sub CommandButton1_Click()
Dim N As Name
With Worksheets("Test")
For Each N In .Names
N.Delete
Next
End With

Merci
 

Pièces jointes

  • Supprimer les noms des colonnes d'une feuille.xlsm
    19.4 KB · Affichages: 8
Solution
Bonjour à tous ,

Un autre code qui tient compte aussi des noms désignant des zones à plusieurs colonnes disjointes ou non (ces noms seront supprimés) ou bien des noms faisant référence à un mélange de colonnes et de plages qui ne sont pas des colonnes (les noms seront conservés).
VB: 
Sub OterNomColEntiere()
Const Feuille = "Test"
Dim N As Name, addr, xrg As Range, xarea As Range, xcol As Range, uniquementCol As Boolean
   DefinirNoms    ' >>>>> à supprimer hors ntest
   For Each N In ThisWorkbook.Names
      uniquementCol = True       ' a priori le nom de fait référence qu'à des colonnes (on va vérifier)
      ' si la rérérence du nom ne commence par "=" & Feuille alors uniquementCol est faux
      ' et on quitte la boucle (pas la...
Trier par date Trier par votes

Dranreb

XLDnaute Barbatruc
Bonjour.
Il y a deux noms de niveau classeur ChampsZER = Test!$C:$C et Nom =Test!A:$A
Mais il n'y a aucun nom de niveau feuille.
Réécrite comme ça la Sub les supprime bien :
VB: 
Private Sub CommandButton1_Click()
   Dim N As Name
   For Each N In ThisWorkbook.Names
      If N.RefersToRange.Worksheet.Name = Me.Name Then N.Delete
      Next N
   End Sub
 
Dernière édition:
Vote positif 0 Vote négatif

sylvanu

XLDnaute Barbatruc
Supporter XLD
Bonjour Carlos, Oneida, Dranreb,
Si j'ai bien compris :
VB: 
Private Sub CommandButton1_Click()
Dim N
With Worksheets("Test")
    For Each N In ActiveWorkbook.Names
        N.Delete
    Next
End With
End Sub
Mais cela efface tous les noms de colonnes, sans aucun filtrage, sinon introduire des IF ou Case pour filtrer.
 
Vote positif 0 Vote négatif

Dranreb

XLDnaute Barbatruc
Information: Les noms de niveau feuille correspondent aussi à des noms de niveau classeur mais dont la propriété Name est préfixée du nom de la feuille suivi d'un point d'exclamation.
La collection Names d'un objet Worksheet reprend ces objets Name de l'objet Workbook mais avec une clé d'accès différente de leur propriété Name, débarrassée du préfixe.
Votre procédure aurait donc supprimé des noms Test!ChampsZER et Test!Nom
 
Vote positif 0 Vote négatif

sylvanu

XLDnaute Barbatruc
Supporter XLD
Re,
Autre approche donné par Aria, supprime que les noms de colonnes à l'exception de tous autres :
VB: 
Private Sub CommandButton1_Click()
    Dim nom As Name
    ' Parcourir tous les noms dans le gestionnaire de noms
    For Each nom In ThisWorkbook.Names
        ' Vérifier si le nom fait référence à une colonne
        If InStr(1, nom.RefersTo, ":") > 0 Then
            nom.Delete      ' Supprimer le nom
        End If
    Next nom
    MsgBox "Tous les noms de colonnes ont été supprimés avec succès !"
End Sub
 
Vote positif 0 Vote négatif
C

carlos

XLDnaute Impliqué
Supporter XLD
Super , ca marche avec ce code :
Sub SupNomF2()
Dim N As Name
On Error Resume Next
For Each N In ThisWorkbook.Names
If N.RefersToRange.Worksheet.Name = "BGT Santorin" Then N.Delete
Next N
End Sub
Bien joué le : On error resume next
Merci
Merci Sylvanu. Je la garde sous le coude
 
Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc
Bonjour carlos, le forum,

Cette macro supprime les noms définis dans le classeur ou dans des feuilles s'ils font référence à des colonnes entières :
VB: 
Private Sub CommandButton1_Click()
Dim N As Name
For Each N In ThisWorkbook.Names
    If TypeOf Evaluate(N.RefersTo) Is Range Then If Evaluate(N.RefersTo).Rows.Count = Rows.Count Then N.Delete
Next
End Sub
A+
 
Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc
Cette macro supprime uniquement les noms qui font référence à des colonnes de la feuille "Test" et évite les noms des plages constituées de plusieurs zones :
VB: 
Private Sub CommandButton1_Click()
Dim N As Name
For Each N In ThisWorkbook.Names
    If TypeOf Evaluate(N.RefersTo) Is Range Then _
        If Evaluate(N.RefersTo).Parent.Name = "Test" Then _
            If Evaluate(N.RefersTo).Areas.Count = 1 Then _
                If Evaluate(N.RefersTo).Rows.Count = Rows.Count Then N.Delete
Next
End Sub
 
Vote positif 0 Vote négatif

mapomme

XLDnaute Barbatruc
Supporter XLD
Bonjour à tous ,

Un autre code qui tient compte aussi des noms désignant des zones à plusieurs colonnes disjointes ou non (ces noms seront supprimés) ou bien des noms faisant référence à un mélange de colonnes et de plages qui ne sont pas des colonnes (les noms seront conservés).
VB: 
Sub OterNomColEntiere()
Const Feuille = "Test"
Dim N As Name, addr, xrg As Range, xarea As Range, xcol As Range, uniquementCol As Boolean
   DefinirNoms    ' >>>>> à supprimer hors ntest
   For Each N In ThisWorkbook.Names
      uniquementCol = True       ' a priori le nom de fait référence qu'à des colonnes (on va vérifier)
      ' si la rérérence du nom ne commence par "=" & Feuille alors uniquementCol est faux
      ' et on quitte la boucle (pas la bonne feuille)
      If Not (N.RefersTo Like "=" & Feuille & "*") Then
         uniquementCol = False
      Else
         Set xrg = Range(Mid(N.RefersTo, 2))    ' le range qui définit N
         For Each xarea In xrg.Areas            ' pour chaque plage de xrg
            For Each xcol In xarea.Columns      ' pour chaque colonne de la plage
               ' si le nombre de ligne d ela plage n'est pas le nombre de colonne d'une feuille excel
               ' alors uniquementCol est faux et on quitte la boucle des colonnes
               If xcol.Rows.Count <> Rows.Count Then uniquementCol = False: Exit For
            Next xcol
            ' si on n'a pas que des colonnes entières dans la plage alors on quitte la boucle des plages
            If Not uniquementCol Then Exit For
         Next xarea
      End If
         ' si on a une plage qui ne contient des colonnes alors on efface le nom
         If uniquementCol Then N.Delete
   Next N
   AfficherNoms "Les Noms restant après traitement"    ' à >>>>> supprimer hors ntest
End Sub
 

Pièces jointes

  • carlos- supprimer nom ref à colonnes- v1.xlsm
    23 KB · Affichages: 1
Vote positif 0 Vote négatif
Solution
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

C
  • Question
XL 2016 accès feuilles masquées par bouton
2
Réponses
26
Affichages
347
vgendron
  • Question
XL 2021 Comment supprimer des noms du gestionnaire de noms dans un classeur
Réponses
7
Affichages
179
jeff1494
A
  • Question
XL 2019 Mélange aléatoire colonne A sur colonne G ne fonctionne pas
Réponses
3
Affichages
204
arvin
A
M
  • Question
Microsoft 365 Macro VBA supprimer une colonne
Réponses
5
Affichages
346
marie3107
M
C
  • Résolu(e)
Autres Copier des données vers une nouvelle feuille excel VBA
2
Réponses
25
Affichages
575
Carolinebd
C
C
  • Résolu(e)
XL 2016 Répartir dans des Groupes d'Effectifs Aléatoires ... mais pas trop
Réponses
2
Affichages
264
crocrocro
C
  • Question
XL 2021 Optimisation code pour affichage ligne et colonne
Réponses
14
Affichages
673
patricktoulon
T
  • Résolu(e)
XL 2016 macro et feuille protégé
2
Réponses
18
Affichages
579
laurent950
F
  • Question
Microsoft 365 Changement de fonctionnement d'une macro suite au passage à windows 10
Réponses
1
Affichages
446
francha62
F
  • Question
Microsoft 365 Retrouver les dépendants de cellules nommées
Réponses
6
Affichages
403
crocrocro
C
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…