XL 2010 supprimer lignes

[ccpapy]

bonsoir,
je voudrai supprimer les lignes contenant un nom dans certaines colonnes.

un fichier joint avec mes débuts de code. je ne vois pas où se situe l'erreur
je masque mes lignes mais pas dans la bonne page 😕

merci

 

[mapomme]

Bonsoir @ccpapy,

Essayez ce code :

Sub polo()
Dim MonFiltre, c As Range
MonFiltre = Sheets("Base").Range("I1").Value
With Sheets("test")
  For Each c In .Range("d1:d" & .Range("a65536").End(xlUp).Row): c.EntireRow.Hidden = c.Value <> MonFiltre: Next c
  Application.Goto .Range("A1"), True
End With
End Sub

 

[ccpapy]

merci,
si je veux supprimer les lignes plutôt que de les masquer ?
.Hidden remplacé par .Delete me fait une erreur .

 

[mapomme]

Re,

merci,
si je veux supprimer les lignes plutôt que de les masquer ?
.Hidden remplacé par .Delete me fait une erreur .

Essayez :

Sub Suppr()
Dim MonFiltre, c As Range, i&
  MonFiltre = Sheets("Base").Range("I1").Value
  Application.ScreenUpdating = False
  With Sheets("test")
    ' afficher toutes les lignes - pour le bon fonctionnement de l'instruction END()
    .Rows.Hidden = False
    'supprimer les lignes qui ne contiennent pas MonFiltre
    '   remplacer <> par = pour supprimer les lignes contenant MonFiltre
    For i = .Cells(.Rows.Count, "a").End(xlUp).Row To 1 Step -1
      If .Cells(i, "d") <> MonFiltre Then .Rows(i).Delete
    Next i
    Application.Goto .Range("A1"), True
  End With
End Sub

 

[ccpapy]

merci encore.
fonctionne parfaitement.
bonne journée