XL 2016 Supprimer dans colonne sous condition

[karinette]

Bonjour à tous.
Je cherche une macro qui me permettrait de supprimer des valeurs suivant une condition.
Je m'explique, dans la colonne A, j'ai des valeurs "X" ou "W".
Ce que j'aimerais, c'est que suivant ces valeurs les cellules sur la même ligne soit supprimer de la façon suivante :
Exemple pour ligne 2 :
Si valeur "X" en A2, suppression des cellules B2 et C2.
Si valeur "W" en A2, suppression des cellules B2, C2 et D2.
J'avais fais un semblant de code, mais je devais le faire ligne par ligne. Je pense qu'il y a moyen de le faire avec une boucle

Merci d'avance de vos retour.

 

[mapomme]

Bonjour,

Essayez le code :

Sub Supprimer()
Dim i&, t
   If Me.FilterMode Then Me.ShowAllData
   t = Range("a1:d" & Cells(Rows.Count, "a").End(xlUp).Row)
   For i = 1 To UBound(t)
      If t(i, 1) = "X" Or t(i, 1) = "W" Then t(i, 2) = "": t(i, 3) = ""
      If t(i, 1) = "W" Then t(i, 4) = ""
   Next i
   Range("a1").Resize(UBound(t), 4) = t
End Sub

 

[Phil69970]

Bonjour @karinette
Edit Bonjour @mapomme et @Lolote83

Je te propose ce code

Sub Sup()
Dim Derlig&, i&
Derlig = Worksheets("sheet1").Range("A" & Rows.Count).End(xlUp).Row
For i = 1 To Derlig
    If Range("A" & i) = "X" Then Range("B" & i & ":C" & i).ClearContents
    If Range("A" & i) = "W" Then Range("B" & i & ":D" & i).ClearContents
Next i
End Sub

Merci de ton retour

@Phil69970

 

[Lolote83]

Bonjour Karinette,
Code à tester

Sub TEST()
    For F = 1 To 35
        Select Case Cells(F, "A")
            Case Is = "X"
                Range("B" & F & ":C" & F).ClearContents
            Case Is = "W"
                Range("B" & F & ":D" & F).ClearContents
        End Select
    Next F
End Sub

@+ Lolote83

 

[karinette]

Merci de vos réponses, je vais tester tout ça

 

[karinette]

C'est vraiment parfait ... ça fonctionne à merveille !!

 

[Phil69970]

Re

Et quelle version tu as choisis ?

@Phil69970