Suites maxi

[Claude]

Bonsoir le Forum,

Soit des suites de chiffres en A1:A13
3
3
4
1
2
3
3
3
3
3
2
1
1
par rapport aux 4 chiffres 1, 2, 3, 4 il s'agit
d'afficher en E2:E5 le nombre de suites maximums
c'est-à-dire le nombre de fois ou un chiffre s'est reproduit
le plus souvent à la suite
Par exemple pour le chiffre 3 nous avons 5 sorties consécutives
soit une suite max de 5

Par quelle formule peut on afficher les résultats ?

Ci-joint un petit travail

Avec tous mes remerciements

Claude

 

[rafael]

Re : Suites maxi

Bonsoir Claude

Ci-joint ma vision du problème, j'ai rajouté 4 colonnes pour définir le NB maxi de suite de valeurs identique consécutives

 

[Claude]

Re : Suites maxi

Merci Rafael,

C'est pas mal comme vision, je pense que ce sera pas trop encombrant pour l'introduire dans mon travail. En tout cela résoud mon problème.

Grand merci.

Amicalement. Claude

 

[JeanMarie]

Re : Suites maxi

Bonjour Claude, Rafael

Une autre proposition, sans rajout de colonnes supplémentaires.

Formule à valider par les touches Ctrl+shift+Entrer

=SI(ESTNA(EQUIV(I4;A$3:A$15;0));"";MAX(FREQUENCE(SI(A$3:A$15=I4;LIGNE(A$3:A$15));SI(A$3:A$15<>I4;LIGNE(A$3:A$15)))))

à mettre en J4, et à glisser vers le bas.

@+Jean-Marie

 

[mutzik]

Re : Suites maxi

Bonjour à tous,

JeanMarie, je suis encore tout bluffé de cette formule (que je mets au chaud) et que j'essaierai de comprendre à tête reposée

 

[Claude]

Re : Suites maxi

Merci Jean-Marie,

Ca deviens intéressant ta formule, mais je n'arrive pas à l'appliquer dans le contexte même du travail joint à ma question !!
Pourrais tu m'éclairer ?

Avec tous mes remerciements.

Amicalement. Claude

 

[JeanMarie]

Re : Suites maxi

Bonsoir,

Formule à mettre dans la cellule E2, en la validant par Ctrl+shift+Entrer

=SI(ESTNA(EQUIV(D2;A$1:A$13;0));"";MAX(FREQUENCE(SI(A$1:A$13=D2;LIGNE(A$1:A$13));SI(A$1:A$13<>D2;LIGNE(A$1:A$13)))))

Voici quelques commentaires :
- la partie ESTNA(EQUIV(D2;A$1:A$13;0)) contrôle la présence de la valeur à tester en max-série (D2), c'est plus efficace à la fonction NB.SI(A$1:A$13;D2)=0

Pour la fonction FREQUENCE, celle-ci utilise le contenu de deux matrices.
* La première matrice (A) sera composée d'une valeur logique FAUX indiquant que la valeur de la cellule Ax est différente de la valeur Dx, tandis que valeur numérique indique le n° de la ligne au figure une correspondance.

*La deuxième matrice (B) est aussi composée de valeurs numériques et logiques. Cette matrice (B) est l'inverse de la matrice (A).

La fonction FREQUENCE va retourner une matrice verticale, chaque valeur de cette matrice sera le nombre de valeurs de la matrice (A) comprises dans chaque tranche de la matrice (B)n-1 à (B)n.

La fonction MAX retournant la valeur max de la matrice frequence.

J'espère que ces petites infos vont vous permettent de comprendre la formule.

@+Jean-Marie

 

[Claude]

Re : Suites maxi

Bonsoir Jean-Marie,

Je trouve la formule prodigieuse. Elle évite bien des acrobaties, surtout au niveau de l'espace travail sur la feuille de calcul.

Merci beaucoup.

Amicalement. Claude