sommeprod

olivierdelabas1 · 29 Avril 2006

Bonjour le forum

J'ai un petit soucis avec sommeprod

j'ai une de mes matrices qui ne fonctionne pas, je pense savoir laquelle (j'en suis même sur.., c'est la deuxiéme '140NP', peut on melanger du texte et des chiffre, si oui quel est la solution à mon probleme

Merci

=SOMMEPROD((((($F$3:$F$227=115)+($F$3:$F$227='140NP')*($E$3:$E$227='CDI')*($H$3:$H$227='CONDUCTEUR'))))) :side:

Bebere · 29 Avril 2006

bonjour Olivier
essaye comme suit,il y avait un espace dans conducteur,trop de parenthèses

=SOMMEPROD(($F$3:$F$227=115)+($F$3:$F$227='140NP')*($E$3:$E$227='CDI')*($H$3:$H$227='CONDUCTEUR'))
à bientôt

olivierdelabas1 · 29 Avril 2006

Merci Bebere,

Donc je peux mélanger du texte et des chiffres dans les conditions............????

merci encore :side:
OLIVIER

Monique · 29 Avril 2006

Bonjour,

Bébère, il me semble qu'il reste un problème de parenthèses

à essayer :
=SOMMEPROD((($F$3:$F$227=115)+($F$3:$F$227='140NP'))*($E$3:$E$227='CDI')*($H$3:$H$227='CONDUCTEUR'))

Compte le nombre de fois où il y a CDI en E et Conducteur en H
et, en F, soit 115 soit 140 NP
(115 en numérique, sinon tu mets ='115')

olivierdelabas1 · 29 Avril 2006

Bonsoir Monique,

Comment d'habitute vos réponse me sont d'un trés grand secours,(merci aussi a Berbere), si je resume la situation
SOMMEPROD((($F$3:$F$227=115)+($F$3:$F$227=\\'140NP\\'))
à la fin de mes deux premiere matrice et si je leur demande ET je dois mettre deux paranthéses?
1- a quoi servent'elles?
2- Puisje encore soluciter votre aide monique -si vous suivez ce fil), mais malheureusement je dois quitté Excel-Dowloads pour quelques heures
Merci Olivier

:side:

Monique · 29 Avril 2006

Re,

SommeProd(((Plage1=Cond1a)+(Plage1=Cond1b))*(Plage3=Cond3)*(Plage4=Cond4))

Le * équivaut au ET des formules conditionnelles,
le + équivaut au OU

Ces 2 formules n'ont pas le même résultat :
=((2*2)+(3*3))*2
=(2*2)+(3*3)*2

L'intérieur de chaque parenthèse est traduit par des VRAI ou FAUX,
VRAI équivaut à 1 et FAUX équivaut à 0
VRAI * VRAI = 1
VRAI + FAUX = 1
VRAI * FAUX = 0

Les Cond1a et Cond1b s'ajoutent, c'est soit telle valeur, soit telle autre valeur
Les 2 autres conditions sont 'multipliées par' VRAI donc 1 ou FAUX donc 0
(SommeProd fait la somme des produits)

Ta formule sur 3 lignes et 3 colonnes :
=SOMMEPROD(((A2:A4=1)+(A2:A4=2))*(B2:B4='A')*(C2:C4='X'))
(seul la 1ère ligne remplit 3 conditions)
En sélectionnant dans la barre de formule et en appuyant sur F9,
ça donne :
=SOMMEPROD((({FAUX;VRAI;FAUX})+({VRAI;FAUX;FAUX}))*(B2:B4='A')*(C2:C4='X'))

=SOMMEPROD((({FAUX;VRAI;FAUX})+({VRAI;FAUX;FAUX}))*({VRAI;FAUX;VRAI})*({VRAI;VRAI;VRAI}))
puis :
=SOMMEPROD(({1;1;0})*({VRAI;FAUX;VRAI})*({VRAI;VRAI;VRAI}))
puis :
=SOMMEPROD({1;0;0})

Bebere · 30 Avril 2006

bonjour Monique,Olivier
Monique les 2 formules que tu donnes en exemple
n'ont pas le même résultat
parce que non respect des priorités opérateurs
(+*)
dans l'exemple j'ai écrit la même formule de 3 facons différentes et mêmes résultats
si Olivier pouvait nous mettre un exemple de son cas,cela m'intéresserait
à bientôt [file name=SomProd.zip size=1643]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/SomProd.zip[/file]

Monique · 30 Avril 2006

Bonjour,

A quoi tu joues, Bébère ?
Je ne comprends rien.
Quelles sont les 2 formules dont tu parles ?
Et puis je n'ai pas du tout envie d'écrire un roman par jour

J'ai écrit ça :
Ces 2 formules n'ont pas le même résultat :
=((2*2)+(3*3))*2
=(2*2)+(3*3)*2
et c'était un exemple pour l'importance des parenthèses

Plus bas, j'ai écrit ça :
Ta formule sur 3 lignes et 3 colonnes :
=SOMMEPROD(((A2:A4=1)+(A2:A4=2))*(B2:B4='A')*(C2:C4='X'))
Mais c'était la formule d'Olivier transposée à un exemple de 3 lignes 3 colonnes,
et c'était pour faire des essais,
c'était un exemple
et ça dénombrait, ça ne faisait pas une somme

Dans l'exemple que tu postes,
(tu demandes une somme, je demandais un comptage comme Olivier)
si tu mets n'importe quoi (sauf un 'a') en B4, la 2ème formule ne donne pas le bon résultat
Tu mets un 'b' en B5 et un 1 en A5, et tu constates

Ta 1ère formule, d'accord
=SOMMEPROD((($A$1:$A$11=1)+($A$1:$A$11=11))*($B$1:$B$11='a')*$C$1:$C$11)
Elle fait la somme de C1:C11 à condition que
1 ) il y ait soit un 1 soit un 11 en A1:A11
2 ) il y ait un 'a' en B1:B11

Ta 3ème formule n'est que la 1ère décomposée,
elle sert de preuve, disant que oui, la 1ère fonctionne
et que non, la 2ème ne fonctionne pas

Bebere · 30 Avril 2006

simplement Monique je posais une question,un point c'est tout
à bientôt

olivierdelabas1 · 30 Avril 2006

heu..........bonjour Monique,Bebere, le forum,..

Je vais regarder tout cela cette aprés midi tranquillement...... :whistle:

Si j'ai encore un p'tit doute je renvoi sur ce fil une p'tite demande......le plus important pour moi c'est surtout de bien conprendre ce que je fait....parceque au vu de la façon d'écrire la formule le resultat change pas mal, sur mon tableau la difference de resultat est de 30, suivant ou je place les paranthéses.....en tout cas merci beaucoup, bon appetit, et peut etre à cette aprés midi :side:

Monique · 30 Avril 2006

Re,

Les 3 sommeprod de Bébère,
décomposées
et mises ligne par ligne
On voit (peut-être ?) mieux le rôle des parenthèses

Olivier, dis-nous ce que tu veux compter,
les parenthèses seront placées selon ce que tu veux compter. [file name=SomProdOlivier.zip size=4847]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/SomProdOlivier.zip[/file]

Bebere · 30 Avril 2006

merçi Monique,ma lanterne éclaire mieux
à bientôt

olivierdelabas1 · 30 Avril 2006

RE,

Ci joint un extrait de mon tableau ou je souhaite appliquer sommeprod, (normalement il y'a plus de 200 lignes salariés), je ne suis pas contre une autre solution que sommeprod, si c'est plus 'pratique' ou plus 'efficace'
merci
olivier :side: [file name=AIDE_20060430161456.zip size=19857]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/AIDE_20060430161456.zip[/file]

Monique · 30 Avril 2006

Re,

Les listes de validation sont refaites,
elles n'ont plus de blancs
Les plages faisant les listes sont renommées 'ListEtc'
parce que, dans la feuille 'Janvier', toutes les plages sont aussi nommées.

Pour faire les comptes, j'ai utilisé tes listes de validation
au lieu de taper les noms dans les formules
La formule :
SOMMEPROD((Contrat=O6)*(Emploi=Q6))
au lieu de
SOMMEPROD(($E$3:$E$18='CDI')*($H$3:$H$18='CONDUCTEUR'))

Le tableau est déménagé à droite, de façon à insérer autant de colonnes que de critères (donc de listes de validation)
500 lignes, c'est un peu beaucoup, j'ai stoppé à 100,
il semble que la suite soit exactement la même chose,
plus quelques trucs avec lesquels tu vas t'arranger

Autre chose, les cellules ne sont plus fusionnées, mais 'centrées sur plusieurs colonnes' ou rien [file name=SomProdOlivierV1.zip size=32474]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/SomProdOlivierV1.zip[/file]

Message édité par: monique, à: 30/04/2006 19:11

olivierdelabas1 · 30 Avril 2006

merci Monique,

Je me mets au boulot de suite............

Olivier B)

sommeprod

olivierdelabas1

XLDnaute Occasionnel

Bebere

XLDnaute Barbatruc

olivierdelabas1

XLDnaute Occasionnel

Monique

Nous a quitté

olivierdelabas1

XLDnaute Occasionnel

Monique

Nous a quitté

Bebere

XLDnaute Barbatruc

Pièces jointes

Monique

Nous a quitté

Bebere

XLDnaute Barbatruc

olivierdelabas1

XLDnaute Occasionnel

Monique

Nous a quitté

Pièces jointes

Bebere

XLDnaute Barbatruc

olivierdelabas1

XLDnaute Occasionnel

Pièces jointes

Monique

Nous a quitté

Pièces jointes

olivierdelabas1

XLDnaute Occasionnel

Discussions similaires

sommeprod

XLDnaute Occasionnel

XLDnaute Barbatruc

XLDnaute Occasionnel

Nous a quitté

XLDnaute Occasionnel

Nous a quitté

XLDnaute Barbatruc

Pièces jointes

Nous a quitté

XLDnaute Barbatruc

XLDnaute Occasionnel

Nous a quitté

Pièces jointes

XLDnaute Barbatruc

XLDnaute Occasionnel

Pièces jointes

Nous a quitté

Pièces jointes

XLDnaute Occasionnel

Discussions similaires

Privacy & Transparency

Privacy & Transparency