Somme.Si à partir de plusieurs feuilles

[slackk]

Bonjour,

Voici ma formule :

=SOMME.SI(Feuil13!A4:A24;Feuil21!$A4;Feuil13!D4😀24)

Je voudrais qu' à la place de "Feuil13!A4:A24" cela prenne toutes les feuilles de 1 jusqu'à la 13.

Est ce possible ?

 

[Monique]

Re : Somme.Si à partir de plusieurs feuilles

Bonjour,

Deux méthodes en pièce jointe
(sur 3 feuilles seulement, tu adapteras)

 

[slackk]

Re : Somme.Si à partir de plusieurs feuilles

Merci, je pense que ça fonctionne mais j'ai "#REF!" peut etre parce que sur les différentes feuilles c'est différents

exemple de ce que j'ai :

=SOMMEPROD(SOMME.SI(INDIRECT(NomOnglets&"!A4:A24");Feuil21!$A4;INDIRECT(NomOnglets&"!D4😀24")))

et ça donne ça apres evaluation de l'erreur :

=SOMMEPROD(SOMME.SI(INDIRECT(#REF!);Feuil21!$A4;INDIRECT("#REF!")

ça veut dire quoi ?

 

[Monique]

Re : Somme.Si à partir de plusieurs feuilles

Bonjour,

La plage nommée "NomOnglets" :
est-ce que tu l'as nommée avec ce genre de formule,
de façon à ce que la formule ne prenne pas en compte des cellules vides :
=DECALER($K$2;;;NBVAL($K$2:$K$14))

Elle ne doit pas avoir de lignes entre les noms des feuilles
Elle ne doit pas avoir le nom d'une feuille qui n'existe pas

Vérifie bien les noms de cette plage par rapport aux noms des onglets (orthographe, un espace en trop, etc)

A propos d'espace, si le nom de l'un des onglets comporte un espace,
les formules en B et D sont à modifier
Mettre une apostrophe entre guillemets avant le nom de la plage nommée et une apostrophe avant le point d'exclamation
(fonctionne aussi même s'il n'y a d'espace nulle part)

B4  =SOMMEPROD(SOMME.SI(INDIRECT("'"&NomOnglets&"'!A4:A24");$A4;INDIRECT("'"&NomOnglets&"'!D4:D24")))

D4 =SOMMEPROD(NB.SI(INDIRECT("'"&NomOnglets&"'!A4:A24");$A4))

 

[slackk]

Re : Somme.Si à partir de plusieurs feuilles

C'est ok tout fonctionne correctement, grand merci !