SOMME DECALER

[FRED]

Bonjour du matin à toutes et à tous et au forum,

J'ai un tableau avec les mois de l'année, dans chaque colonne mois, j'ai 3 colonnes intérieures.

Je veux obtenir une somme décaler par rapport à une liste de choix des mois.
Quand je mets FEVRIER dans la liste de choix, je veux que cela me calcule toutes les 1 ères colonne de chaque mois.

Faire la somme décaler avec SOMME DECALER ET EQUIV QUADN IL N' y a que des colonnes je sais faire, mais je ne sais pas dire à SOMME DECALER de sauter les sous colonnes qui ne m'intéresse pas .

Je vous ai fais un exemple.

 

[Monique]

Bonjour,

=SOMME(DECALER(A5:A10;;(EQUIV(D14;K4:K15;0)-1)*3;😉)

Si tu mets ta liste des mois et la cellule D14 au format date mmmm, (tu tapes des dates et non le nom des mois)
=SOMME(DECALER(A5:A10;;(MOIS(D14)-1)*3;😉)

 

[FRED]

Merci Monique de t'être penchée sur mon cas, mais ce matin je me suis mal exprimé, j'ai fais mon exemple rapidement avant de partir au boulot.

J'ai repris mon fichier pour préciser ce que j'avais omis de préciser.
Tu as compris ce que j'avais demandé au départ mais comme je me suis mal exprimé cela n'a pas atteint le but escompté, je n'ai qu'à m'en prendre à moi , tu n'as fait que de me donner ce que j'avais demandé !!!!


Si tu pouvais jeter un ti coup d'oeil sur ce que j'ai modifié.

Merci encore.

 

[Monique]

Rebonjour,

Pour avoir le total de la colonne A du mois inscrit en E15, selon tes critères de lieu
En C14 et à recopier vers le bas :
=SOMMEPROD(($A$6:$A$11=$B14)*DECALER($B$6:$B$11;;(EQUIV(E$15;$L$5:$L$16;0)-1)*3;😉)

Pour avoir le cumul de toutes les colonnes A depuis janvier jusqu'au mois inscrit en E15 inclus (toujours selon le lieu) :
=SOMMEPROD(($A$6:$A$11=$B14)*(MOD(COLONNE($B$6:$AK$11);3)=2)*(COLONNE($B$6:$AK$11)<=(EQUIV($E$15;$L$5:$L$16;0))*3);$B$6:$AK$11)
AK parce que tes 12 mois à 3 colonnes vont arriver jusqu'à la colonne AK

 

[FRED]

Magique, vraiment tu mérites un 20/20.

C'est type top, vous me faites adorer de plus en plus EXCEL et VBA.

Chapeau à toutes et à tous.
Bonne soirée

 

[FRED]

Bonjour Monique et le forum,

Argh je me tire les cheveux, j'ai compris comment fonctionnait la formule suivante : =SOMMEPROD(($A$6:$A$11=$B14)*(MOD(COLONNE($B$6:$AK$11);3)=2)*(COLONNE($B$6:$AK$11)<=(EQUIV($E$15;$L$5:$L$16;0))*3);$B$6:$AK$11)


Mais ou je bloque c'est pour dans mon exemple, que j'avais joint précédemment, calculer sous le même principe mais avec la colonne intitulé T je ne vois pas quel paramètre il faut changer pour qu'il passe alors de mois en mois aux colonnes T

Je pense que cela se situe à ce niveau là : (MOD(COLONNE($B$6:$AK$11);3)=2) car c'est le seul endroit dans la celulle ou cela parle du choix de la colonne, mais j'ai beau changer le 2 en 3 rien y fait.

Merci d'avance et bon week end !

 

[Monique]

Bonjour,

La formule =MOD(COLONNE();3) te donne le reste de la division par 3 du N° de la colonne
=MOD(COLONNE(A1);3) donne 1
=MOD(COLONNE(B1);3) donne 2
=MOD(COLONNE(C1);3) donne 0
=MOD(COLONNE(D1);3) donne 1 et on repart et il n'y a pas de 3

Total des T pour le mois demandé :
=SOMMEPROD(($A$6:$A$11=$B14)*DECALER($B$6:$B$11;;(EQUIV(E$15;$AL$5:$AL$16;0)-1)*3+1;😉)
Total des B pour le mois demandé :
=SOMMEPROD(($A$6:$A$11=$B14)*DECALER($B$6:$B$11;;(EQUIV(E$15;$AL$5:$AL$16;0)-1)*3+2;😉)
$AL$5:$AL$16 est la plage des mois

Cumul depuis janvier jusqu'au mois demandé
Pour les T
=SOMMEPROD(($A$6:$A$11=$B14)*(MOD(COLONNE($B$6:$AK$11);3)=0)*(COLONNE($B$6:$AK$11)<=(EQUIV($E$15;$AL$5:$AL$16;0))*3);$B$6:$AK$11)
Pour les B
=SOMMEPROD(($A$6:$A$11=$B14)*(MOD(COLONNE($B$6:$AK$11);3)=1)*(COLONNE($B$6:$AK$11)<=(EQUIV($E$15;$AL$5:$AL$16;0))*3+1);$B$6:$AK$11)