Somme de toute une plage sous beaucoup de conditions

[marine1]

😕

Bonjour,

En pièce jointe mon tableau.

je cherche à faire la somme de cette condition sur toute une page: =SI(ET(L5=0;K5<=5000);K5;SI(ET(L5=0;K5>5000);5000;SI(K5>=L5;L5;K5)))

Cette condition se résume à:
"Si garantie =0 et facturation <=5000 alors on met le montant de facturation
Or si garantie=0 mais facturation>=5000, alors on met 5000
Sinon, si facturation >= Garantie, on met le montant de la garantie et si facturation<= garantie on met le montant de la farturation"


Soit:
Mais ici je voudrais cette condition sur toute la plage C4:C627 et D4😀627 et classé par pays ( soit sous la condition que la plage A4:B627 = Allemagne par exemple)
Cela se résumerai à:
"Si garantie =0 et facturation <=5000 alors on fait la somme des facturations répondant à cette condition
Or si garantie=0 mais facturation>=5000, alors on met 5000
Sinon, si facturation >= Garantie, on fait la somme des garanties répondant à cette condition et si facturation<= garantie on fait la somme des facturations répondant à cette condition
-----> cela sur toute la plage des garanties et facturation mais selon les pays "

 

[Dugenou]

Re : Somme de toute une plage sous beaucoup de conditions

Bonjour,
Avec un sommeprod cela semble fonctionner !

=SOMMEPROD(($A$4:$A$627=F17)*(($D$4:$D$627=0)*($C$4:$C$627<=5000)*$C$4:$C$627)+(($A$4:$A$627=F17)*($D$4:$D$627=0)*($C$4:$C$627>5000)*5000)+(($A$4:$A$627=F17)*($C$4:$C$627>=$D$4:$D$627)*$D$4:$D$627)+(($A$4:$A$627=F17)*($C$4:$C$627<$D$4:$D$627)*$C$4:$C$627))

attention dans le fichier joint il y a (je pense) une coquille sur la "formule qui marche"
=SI(ET(D7=0;C7<=5000);C7;SI(ET(D7=0;C5>5000);5000;SI(C7>=D7;D7;C7)))

Voir PJ

 

[Jocelyn]

Re : Somme de toute une plage sous beaucoup de conditions

Bonjour le Forum,
Bonjour marine1,

un essai en fichier joint, dans la colonne en jaune j'ai étiré ta formule qui fonctionne pour en faire le total pour la france afin de comparer le résultat avec ma formule globale

je t'ai mis 2 formules une qui utilise les référence de plage de style $D$4:$D$627 et une qui utilise des plages nommées dynamique avec celle ci si tu ajoutes des données tu n'as rien a changer dans les formules

Regarde et dis nous

Cordialement


EDIT : Bonjour Dugenou 🙂

 

[R@chid]

Re : Somme de toute une plage sous beaucoup de conditions

Bonjour @ tous,
Sauf erreur de ma part,
Vous ne voyez pas qu'il y a un petit problème sur les test,
=SI(ET(D7=0;C7<=5000);C7;SI(ET(D7=0;C7>5000);5000;SI(C7>=D7;D7;C7)))
Lorsque D7=0 on a toujours C7>D7 et malgré tout on prend le C7 pourquoi on va revenir prendre D7 dans le dernier test..

Merci de revenir préciser la demande avec un test logique..

@ + +

 

[marine1]

Re : Somme de toute une plage sous beaucoup de conditions

Merci beaucoup, la formule =SOMMEPROD(($A$2:$A$65536=A633)*(($L$2:$L$65536=0)*($K$2:$K$65536<=5000)*($K$2:$K$65536))+(($A$2:$A$65536=A633)*($L$2:$L$65536=0)*($K$2:$K$65536>5000)*5000)+($A$2:$A$65536=A633)*((L2:L65536<>0)*($K$2:$K$65536>=$L$2:$L$65536)*($L$2:$L$65536))+(($A$2:$A$65536=A633)*(L2:L65536<>0)*($K$2:$K$65536<$L$2:$L$65536)*$K$2:$K$65536))

Merci beaucoup!! la première formule est bonne il falklait juste rajouter les deux points soulignés en gras. En tout cas j'aurai pas trouvé toute seule, merci!

Je regarde les autres formules de suite, voir si il y en avait une plus simple

 

[marine1]

Re : Somme de toute une plage sous beaucoup de conditions

Rachid,

Parce que les deux premières conditions existent seulement pour D=0 tandis que les deux dernières, au contraire, existent pour D7<>0

 

[marine1]

Re : Somme de toute une plage sous beaucoup de conditions

Dans la fonction:
+SOMMEPROD($A$2:$A$65536=A632)*(($L$2:$L$65536=0)*($K$2:$K$65536>=5000)*($K$2:$K$65536-5000))
est ce qu'on a le droit de mettre une soustraction dans la somme que l'on veut faire?
Soit
"sur la plage L2:L65536 où les montants sont égaux à 0 additionner tous les montants K2:K65536 mais en enlevant 5000 à chacun de ces montants"