Simplifier une formule

[beegees]

Bonjour tout le monde,

J'aimerais savoir si il est possible de rendre cette formule plus facile :

=SI(ET(AG19>47;AE19="Aj");((SI(D19>9;D19*$D$7)+SI(E19>9;E19*$E$7)+SI(F19>9;F19*$F$7)+SI(G19>9;G19*$G$7)+SI(H19>9;H19*$H$7)+SI(I19>9;I19*$I$7)+SI(J19>9;J19*$J$7)+SI(K19>9;K19*$K$7)+SI(L19>9;L19*$L$7)+SI(M19>9;M19*$M$7)+SI(N19>9;N19*$N$7)+SI(O19>9;O19*$O$7)+SI(P19>9;P19*$P$7)+SI(Q19>9;Q19*$Q$7)+SI(R19>9;R19*$R$7))/SOMME.SI(D19:R19;">9";$D$7:$R$7))*AN19;"")

Quand je dis plus facile, je veux dire plus courte.

En même temps, pourriez-vous m'expliquez à quoi elle sert ?

Merci d'avance.

beegees

 

[Tibo]

Re : Simplifier une formule

Salut Beegees,

Sans autre explications, difficile de te dire s'il est possible de simplifier cette formule.

Il faudrait d'abord que tu nous joignes un fichier et surtout que tu nous expliques à quoi elle sert. Or il semble que tu ne le saches pas non plus.

On va pas aller bien loin ainsi

Bon dimanche

A te lire

@+

 

[Kobaya]

Re : Simplifier une formule

salut tout le monde,

si j'ai bien analysé :

si AG19>47 et AE19="Aj", additionner le contenu des cellules D19 à R19 dont le contenu est supérieur à 9, et divise cette somme par la somme des cellules D19 à R19 si leur valeur est supérieur à 9 (autrement dit une moyenne), et à multiplier le tout par AN19.

voilà... mais même avec ce que j'ai décortiqué, comme dit Tibo,

On va pas aller bien loin ainsi

si tu ne nous donnes pas plus de détails (pour la simplification)

mets une pièce jointe 🙂

 

[Samantha]

Re : Simplifier une formule

Bonjour Beeges, Tibo Kpbaya,

Hum Hum .....Si jécoute bien ce que dis Kobaya, ça sent fortement le SOMMEPROD là....

Nous attendons avec impatience la PJ 😉

Edit :
Sinon, solution avec Nommage de formules :

=SI(ETAG19>47;AE19="Aj");SOMMECompD19;CompE19;CompF19;CompG19;CompH19;CompI19;CompJ19;CompK19;CompL19;CompM19;CompN19;CompO19;CompP19;CompQ19;CompR19)/SOMME.SI(D19:R19;">9";$D$7:$R$7))*AN19;"")

En collant chacune des formules du type SI(D19>9;D19*$D$7) dans une cellule hors du tableau ou mieux dans une autre feuille et en nommant chacune par le Menu Insérer/Nom/Définir

A tester

Reviens nous dire

A te lire

Sam

 

[Monique]

Re : Simplifier une formule

Bonjour,

Cette formule doit faire la même chose :
=SI(ET(NB.SI(D19:R19;">"&9);AG19>47;AE19="aj");SOMMEPROD((D19:R19>9)*D19:R19*D$7:R$7)/SOMME.SI(D19:R19;">"&9;D$7:R$7)*AN19;"")

Cette partie :
=SI(D19>9;D19*$D$7)+SI(E19>9;E19*$E$7)+SI(F19>9;F19*$F$7)+SI(G19>9;G19*$G$7)+SI(H19>9;H19*$H$7)+SI(I19>9;I19*$I$7)+SI(J19>9;J19*$J$7)+SI(K19>9;K19*$K$7)+SI(L19>9;L19*$L$7)+SI(M19>9;M19*$M$7)+SI(N19>9;N19*$N$7)+SI(O19>9;O19*$O$7)+SI(P19>9;P19*$P$7)+SI(Q19>9;Q19*$Q$7)+SI(R19>9;R19*$R$7)
c'est du SommeProd :
=SOMMEPROD((D19:R19>9)*D19:R19*D$7:R$7)

ça donne :
=SI(ET(AG19>47;AE19="aj");SOMMEPROD((D19:R19>9)*D19:R19*D$7:R$7)/SOMME.SI(D19:R19;">"&9;D$7:R$7)*AN19;"")

Il manque 1 condition, si la ligne 19 ne contient pas de nombre > 9, on obtient #DIV/0!
Pour éviter le #DIV/0! :
=SI(ET(NB.SI(D19:R19;">"&9);AG19>47;AE19="aj");SOMMEPROD((D19:R19>9)*D19:R19*D$7:R$7)/SOMME.SI(D19:R19;">"&9;D$7:R$7)*AN19;"")

Ta formule peut faire une moyenne de notes avec coefficients.
Les notes en ligne 19
les coeff en ligne 7
ne sont prises en compte que les notes > 9
SommeProd multiplie chaque note > 9 par son coefficient et fait la somme des produits note*coeff
Puis la formule divise le résultat par la somme des coeff pris en compte
=SI(NB.SI(D19:R19;">"&9);SOMMEPROD((D19:R19>9)*D19:R19*D$7:R$7)/SOMME.SI(D19:R19;">"&9;D$7:R$7);"")

Ensuite tu as, en plus, des conditions en AE19, en AG19 et tu multiplies le tout par AN19

 

[beegees]

Re : Simplifier une formule

Bonjour tout le monde,

Merci à toutes et à tous pour vos réponses aussi complètes que variées.

Voici la feuille excel, je pense que ça sera plus facile pour vous tous.

Merci
beegees

 

[Samantha]

Re : Simplifier une formule

Re : oubliage de trombonne ?

Sam