Simplification formule SI et formule.

[JJ1]

Bonjour,
Je joins un exemple où j'ai une formule SI en U1 qui renvoit 1 si les nombres situés en G1:K1 ne sont pas plus de 1 dans chaque colonne (H5:W13) mais il m'a fallu 16 sommeprod...(elle fonctionne).
Je voudrais aussi récupérer en ligne 2 pour chaque nombre sa valeur en ligne 14 (flêche)
Merci de votre aide et bonne journée.

 

[Chris401]

Re : Simplification formule SI et formule.

Bonjour

Pour le point 1, formule matricielle :

=SI(SOMME(N(FREQUENCE(SI(NB.SI(DECALER($H$5:$W$13;;COLONNE($H$5:$W$13)-COLONNE($H$5:$H$13);;1);TRANSPOSE($G$1:$K$1));COLONNE($H$5:$W$13));COLONNE($H$5:$W$13))>1))=0;1;0)

Pour le point 2 - en G2 à tirer vers la droite :

=DECALER($H$14;0;SOMMEPROD(($H$5:$W$13=G1)*COLONNE($H$5:$W$13))-COLONNE($H$14))

Cordialement
Chris

 

[R@chid]

Re : Simplification formule SI et formule.

Bonjour JJ1,
Bonjour Chris,
Bonjour le Forum,
en G2,

=INDEX($H14:$W14;MIN(SI($H5:$W13=G1;COLONNE($H5:$W13)-7)))

@ valider par Ctrl+Maj+Entree
@ tirer vers la droite

en U1,

=SOMME(N(FREQUENCE(SI(SOUS.TOTAL(3;DECALER(G5:G13;;COLONNE(H5:W13)-7));H5:W13);G1:K1)=1))

@ valider par Ctrl+Maj+Entree

Voir PJ...
Amicalement

 

[JJ1]

Re : Simplification formule SI et formule.

Bonjour Chris 401, Rachid,

Merci pour vos 2 formules, je n'aurais pas pensé à utiliser Frequence mais elle ne renvoie pas 1 ou 0, pour le point 1 (en U1) j'ai utilisé la formule de Chris.

Pour le point 2 en G2, si le nombre est absent de la matrice, la formule de Chris renvoie REF et celle de Rachid 1, je garde la valeur 1.

Encore merci pour cette aide et bon am

 

[R@chid]

Re : Simplification formule SI et formule.

Bonjour JJ1,
Bonjour Chris,
pour je vais dire que j'ai pas compris la question, tu peux me l'expliquer STP???
Amicalement

 

[JJ1]

Re : Simplification formule SI et formule.

Re Rachid,

Je souhaitais que la formule renvoie 1 si les 5 nombres étaient "éparpillés "dans les colonnes de la matrice et 0 si 2 nombres (ou plus sur les 5) étaient dans une même colonne.
C'est pas simple.

Pour le point 2 (G2), si le nombre est absent dans la matrice, la formule renvoie 0: (j'ai modifié avec un test supplémentaire)
=SI(NB.SI($H$5:$W$13;G$1)=0;0;INDEX($H14:$W14;MIN(SI($H5:$W13=G1;COLONNE($H5:$W13)-7))))

Merci

Amicalement.

 

[R@chid]

Re : Simplification formule SI et formule.

ReBonjour,
J'ai compris maintenant,
tu peux utiliser cette formule en U1 tout en gardant la ligne Intermediaire...

=N(NB.SI(H4:W4;1)=SOMME(H4:W4))

Amicalement