Si imbriqués avec et/ou et fonction PLANCHER

[Stephdeumonac]

Bonjour

Je dois faire une formule répondant à plusieurs conditions mais je n’arrive pas à ajouter ces conditions ensemble.

Je souhaite que si la cellule B5 correspond à « CEE » alors un calcul différent en fonction du contenu de la cellule A5 s’applique par tranches de 7 jours (pour cela utilisation de la fonction PLANCHER avec la différence entre D5 = date de fin et C5 = date de début)

En résumé :
Condition de base => Si B5= « CEE » alors appliquer les conditions suivantes :

Si A5 = « 4/5 » « 6/8 » « 9/11 » « 12/14 » alors =PLANCHER((((D5-C5)+1)/7);1)
(toutes les tranches de 7 jours on rajoute 1 dans la colonne « indemnité » 7 jours = 1, 14 jours = 2 ect…)

Et

Si A5 = « 15/17 » ou « Iti. » Alors =PLANCHER(((((D6-C6)+1)/7)*3);3)
(toutes les tranches de 7 jours on rajoute 3 dans la colonne « indemnité » 7 jours = 3, 14 jours = 6 ect…)


(de fait si B5 est différent de « CEE » alors ne rien faire »)

Ce n’est peut-être pas très clair, alors j'ai rajouté le fichier avec en E5 et E6 la formule permettant de calculer le résultat par tranche de 7 jours.... mais sans tenir compte des autres conditions de la cellule A5

Merci par avance pour votre aide !

 

[Stephdeumonac]

Re : Si imbriqués avec et/ou et fonction PLANCHER

Je suis arrivé à faire une partie des conditions :

=SI(ET(B7="CEE";(OU(A7="4-5";A7="6-8";A7="9-11";A7="12-14")));(PLANCHER((((D7-C7)+1)/7);1));"")

=SI(ET(B8="CEE";(OU(A8="15-17";A8="Iti")));PLANCHER(((((D8-C8)+1)/7)*3);3);"")

Mais je n'arrive pas à imbriquer ces 2 formules entre elles :/

 

[ROGER2327]

Re : Si imbriqués avec et/ou et fonction PLANCHER

Bonsoir Stephdeumonac.


Essayez :

=SIERREUR(SI(B5="CEE";SI(CHERCHE(A5&" ";" 4-5 6-8 9-11 12-14 15-17 Iti. ")>20;PLANCHER((D5-C5+1)*3/7;3);PLANCHER((D5-C5+1)/7;1));"");"")

ROGER2327
#6820

Mardi 10 Absolu 141 (Dilution - Vacuation)
1[SUP]er[/SUP] Sanculottide An CCXXI, 9,2685h - fête de la Vertu
2013-W38-2T22:14:40Z

 

[ROGER2327]

Re : Si imbriqués avec et/ou et fonction PLANCHER

Suite...


... ou bien :

=SIERREUR(SI(ET(B5="CEE";CHERCHE(" "&A5&" ";" 4-5 6-8 9-11 12-14 15-17 Iti. ")>20);PLANCHER((D5-C5+1)*3/7;3);PLANCHER((D5-C5+1)/7;1));"")

ROGER2327
#6821

Mardi 10 Absolu 141 (Dilution - Vacuation)
1[SUP]er[/SUP] Sanculottide An CCXXI, 9,4324h - fête de la Vertu
2013-W38-2T22:38:16Z

 

[Stephdeumonac]

Re : Si imbriqués avec et/ou et fonction PLANCHER

Bonjour Roger,

La seconde proposition renvoi un calcul si la cellule B5 est différente de "CEE".
Par contre la 1er formule fonctionne parfaitement

Juste une petite question : à quoi correspond l'argument >20 ?
SI(CHERCHE(A5&" ";" 4-5 6-8 9-11 12-14 15-17 Iti. ")>20

J'étais bien loin de trouver la solution avec mes ET et OU Merci beaucoup pour votre aide

 

[ROGER2327]

Re : Si imbriqués avec et/ou et fonction PLANCHER

Re...

Vous avez raison : la deuxième formule ne convient pas.
D'ailleurs, la première est également critiquable. Fatigue due à l'heure tardive ???

Meilleure est certainement :​

=SIERREUR(SI(ET(B5="CEE";C5<>"";D5<>"");SI(CHERCHE(" "&A5&" ";" 4-5 6-8 9-11 12-14 15-17 Iti. ")>19;PLANCHER((D5-C5+1)*3/7;3);PLANCHER((D5-C5+1)/7;1));"");"")

(Voyez le classeur joint.)

Quant à la signification du ">20" (ou ">19" dans la nouvelle formule), l'aide sur les fonctions donne la réponse :

(...)
Les fonctions CHERCHE et CHERCHERB recherchent une chaîne de texte au sein d’une seconde chaîne de texte et renvoient le numéro de la position de départ de la première chaîne de texte à partir du premier caractère de la seconde chaîne de texte.
(...)

Dans le cas qui nous occupe, la fonction

CHERCHE(" "&A5&" ";" 4-5 6-8 9-11 12-14 15-17 Iti. ")>19

renvoie VRAI si la chaîne " "&A5&" " figure au-delà du 19[SUP]ème[/SUP] caractère de " 4-5 6-8 9-11 12-14 15-17 Iti. ", autrement dit dans le cas où A5 contient 15-17 ou Iti..​

Bonne journée.


ROGER2327
#6822

Mercredi 11 Absolu 141 (Sainte Purée, sportswoman - fête Suprême Quarte)
2ème Sanculottide An CCXXI, 5,1599h - fête du Génie
2013-W38-3T12:23:02Z