si feuille existe

[rchristian]

Bonjour,

Dans la macro suivante :

Sub InsertFeuilleM2()
'Déclaration des variables
Dim I As Long

For I = 1 To 60
Sheets("ModelM2").Copy after:=Worksheets(Worksheets.Count)
'ActiveSheet.Copy after:=Worksheets(Worksheets.Count)
ActiveSheet.Name = "M2PlaceB" & Format(I, "000")
ActiveSheet.Range("X2") = "B" & Format(I, "000")
ActiveSheet.Protect UserInterfaceOnly:=True
Next I
End Sub

je voudrais vérifier si la feuille "M2PlaceB001" existe avant de lancer la procédure.
Avez vous un solution ? merci d'avance.

Christian

 

[ROGER2327]

Re : si feuille existe

Bonsoir rchristian,

Sub InsertFeuilleM2()
Dim I As Long, J As Long, N As String
    For I = 1 To 60
        N = "M2PlaceB" & Format(I, "000")
        For J = 1 To Sheets.Count
            If Sheets(J).Name = N Then Exit For
        Next J
        If J > Sheets.Count Then
            Sheets("ModelM2").Copy after:=Worksheets(Worksheets.Count)
            ActiveSheet.Name = N
            ActiveSheet.Range("X2") = "B" & Format(I, "000")
            ActiveSheet.Protect UserInterfaceOnly:=True
        End If
    Next I
End Sub

devrait le faire.​

Bonne nuit !
ROGER2327

 

[ROGER2327]

Re : si feuille existe

Re-bonsoir, je n'ai pas fait attention à ce que la demande est sur le forum Excel2007. Je n'ai testé qu'avec Excel2003.

 

[rchristian]

Re : si feuille existe

Merci pour la réponse, mais je voudrais tester que la feuille "M2PlaceB001" car si elle existe les autres existent

 

[ROGER2327]

Re : si feuille existe

Sub InsertFeuilleM2()
Dim I As Long
    For I = 1 To Sheets.Count
        If Sheets(I).Name = "M2PlaceB001" Then Exit For
    Next I
    If I > Sheets.Count Then
        For I = 1 To 60
            Sheets("ModelM2").Copy after:=Worksheets(Worksheets.Count)
            ActiveSheet.Name = "M2PlaceB" & Format(I, "000")
            ActiveSheet.Range("X2") = "B" & Format(I, "000")
            ActiveSheet.Protect UserInterfaceOnly:=True
        Next I
    End If
End Sub

 

[rchristian]

Re : si feuille existe

Merci pour la réponse.

A+