si double clic sur cellule aors copie ligne dans feuil2

[pascal21]

bonjour
j'ai regardé sur le forum mais je n'arrive pas à adapter ce que je vois
donc j'ai des données en feuil1 de a4 à g84 (pour l'instant)
je cherche le moyen qui, au double clic sur une cellule de la colonne A me recopierait les colonnes a à g de cette ligne dans la feuille2
il va sans dire que je peux avoir besoin de recopier plusieurs lignes
dans ce cas elles se mettent les unes à le suite des autres dans la feuille2
comment faire ceci
merci
je vous joint un petit exemple

 

[Kobaya]

Re : si double clic sur cellule aors copie ligne dans feuil2

Bonjour Pascal21,

Rajoute ce ceci dans le module de code de Feuil1 :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    ' si colonne A
    If Target.Column = 1 Then
        ' .End(xlUp) est l'équivalent de CTRL+flèche haut
        ' puis .Offset(1, 0) pour redescendre d'une ligne
        Range(Cells(Target.Row, 1), Cells(Target.Row, 7)).Copy Destination:=Sheets("Feuil2").Range("A65536").End(xlUp).Offset(1, 0)
        
        ' pour sortir du mode édition
        Cancel = True
    End If
End Sub

 

[Dull]

Re : si double clic sur cellule aors copie ligne dans feuil2

Salut Pascal21, le Forum

Essaye ce code

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Cancel = True
Dim DerLig As Integer
If Not Intersect([A4:A100], Target) Is Nothing Then
DerLig = Sheets("Feuil2").Range("A65536").End(xlUp).Row + 1
    Range(Target.Offset(0, 6).Address & ":" & Target.Address).Copy _
        Destination:=Sheets("Feuil2").Range("A" & DerLig)
End If
End Sub

EDITION: Salut Kobaya avais pas raffraichit

Bonne Journée

 

[CBernardT]

Re : si double clic sur cellule aors copie ligne dans feuil2

Bonjour Pascal21 et le forum,

pas de difficulté pour ce report à moins d'avoir raté quelque chose ?

Le code :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
' Traitement si le doubleclick est situé en colonne A
If Not Application.Intersect(Target, Range("A:A")) Is Nothing Then
' Déclaration de la variable
Dim Derlig As Integer
' Désactivation de l'affichage
Application.ScreenUpdating = False
' Initialisation de la variable
Derlig = Sheets("Feuil2").Range("A65536").End(xlUp).Row ' Dernière ligne de la colonne A
' Report d'un enregistrement
Range(ActiveCell, ActiveCell.Offset(0, 6)).Copy Sheets("Feuil2").Range("A" & Derlig + 1)
End If
End Sub

EDITION : Salut Kobaya et Dull

 

[pascal21]

Re : si double clic sur cellule aors copie ligne dans feuil2

bonjour à tous et merci pour vos réponses
dans tout ce choix; j'ai utilisé la méthode de dull

 

[conquerant1066]

Re : si double clic sur cellule aors copie ligne dans feuil2

Bonjour à tous,

J'ai réalisé un macro "Private Sub Worksheet_BeforeDoubleClick" qui fonctionne très bien. Elle permet à un utilisateur de scanner un code à barres dans une cellule que je veux fixe et en double cliquant sur certaines cellules de copier mon CàB sur la cellule choisie. Tout cela fonctionne bien

Mon problème est que si mon utilisateur ne clic qu'une seule fois, alors le prochain utilisateur qui scannera enverra le code barre sur une cellule bidon.

Bref, connaissez vous une fonction me permettant soit par tempo, soit par fonction "1 Clic" de faire en sorte que ma cellule code barre se retrouve active.

Merci de votre aide.

 

[conquerant1066]

Re : si double clic sur cellule aors copie ligne dans feuil2

Bonjour à tous,

J'ai réalisé une macro "Private Sub Worksheet_BeforeDoubleClick" permettant à un utilisateur de scanner un code à barres et ensuite, par double clic, de définir un emplacement où copier ce CàB. Tout ceci fonctionne trés bien.

Mon problème est que si un utilisateur ne clic qu'une seule fois, lorsque l'utilisateur suivant va scanner sont CàB, celui ci se trouvera n'importe où (là ou aura eu lieu le clic unique du précèdent utilisateur).

Bref, connaissez vous un moyen d'intégrer à ma macro "double clic" un parametre soit de temporisation, soit par un clic pour faire en sorte que ma cellule Code à Barres se retrouve active en cas de clic unique.

Merci de vos cogitages

 

[conquerant1066]

Re : si double clic sur cellule aors copie ligne dans feuil2

Veuillez excuser mon bégayage 😱

 

[pascal21]

Re : si double clic sur cellule aors copie ligne dans feuil2

bonjour le conquérant
pour le doublon pas grave
mais tu aurais dù ouvrir un nouveau fil ta question n'ayant rien à voir avec le sujet de celui-ci
demande à la modération de déplacer ton sujet
enfin moi ce que j'en dis, si tu veux des réponses

 

[conquerant1066]

Re : si double clic sur cellule aors copie ligne dans feuil2

Ok merci pascal21 c'est fait