SI, CNUM, DROITE: Formules seules OK, imbriquées KO

[rico99]

J'ai un petit souci avec une formule, quand je prend celle-ci par morceau elle fonctionne, mais dés qu'elle est imbriquées j'ai une erreur sur DROITE.

Je voudrais remplacer la partie rouge de la première formule par la seconde, mais cela ne fonctionne pas, en théorie cela donne la troisième formule mais elle ne peut être saisie dans une cellule car j'ai excel qui la rejete en se positionnant sur DROITE.

Première formule
=SI($B29="Asap";SI($C29="";WORKDAY(Champs_date_dep;$L29;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20));WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)));18));$L29;Listes!$K$2:$K$20))

deuxième formule
=SI($C29>WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)));18));0;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20);WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)));18));$L29;Listes!$K$2:$K$20))

Troisième formule (formule souhaitée)

=SI($B29="Asap";SI($C29="";WORKDAY(Champs_date_dep;$L29;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20));SI($C29>WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)));18));0;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20);WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)));18));$L29;Listes!$K$2:$K$20))

Merci par avance pour votre aide

 

[rico99]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

pour l'histoire du workday ça doit être une question de version, de mon côté ça fonctionne avec ...

pour ce qui est du fonctionnement:

en colonne A, j'ai un ordonnencement de séquence. Seq1, Seq2, Seq3, ....
En colonne B, j'ai le déclenchement différents cas de figure

ASAP: sans date en colonne C:
cette tâche débutera aujourd'hui et prendra 2 jours de délai, soit J+2

ASAP: avec une date en colonne C
Cette tâche débutera à la date de la colonne C et prendra 2 jours de délai

After SeqX sand date en colonne C
Cette tâche débutera après la date de fin de la SeqX + 2 jours de délai

After SeqX (ou X représente le numéro de séquence de la colonne A): avec une date en colonne C
Cette tâche débutera après la date de fin de la SeqX + 2 jours de délai si la date en colonne C est inférieure à la date de fin de la SeqX, ou bien à la date de la colonne C si celle-ci est supérieure

En colonne L: J'ai un délai exprimé en nb de jours ouvrés

Le but est de faire un MAX() du range en colonne R (qui contient la formule souhaitée) afin d'avoir selon les dates saisies, le type de déclenchement et le délai, la date finale de réalisation de l'ensemble des tâches.

voilà, est-ce un peu plus clair ? :$

 

[hbenalia]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

Bonjour à tous, bonjour rico


Je te retrouve même ici, la formule suivante est peut-être la bonne... J'ai fait des tests sur cette formule par des exemples choisis arbitrairement et avec des "Evaluations de formules", ces tests m'ont semblé satisfaisants... Testes-la sur ton fichier et me dire tes remarques...

= SI($B29="Asap";SI($C29="";WORKDAY(Champs_date_dep;$L29;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20));SI($C29>WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(DROITE($B29;1)*1);0;CNUM(DROITE($B29;1)));18));0;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20);WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(DROITE($B29;1)*1);0;CNUM(DROITE($B29;1)));18));$L29;Listes!$K$2:$K$20)))

Cordialement

 

[Habitude]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

=SI($B29="Asap";SI($C29="";WORKDAY(Champs_date_dep;$L29;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20));SI($C29>WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)));18));0;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20);WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)));18));$L29;Listes!$K$2:$K$20))

Si 1er niveau
Workday 2ieme niveau
indirect 3ieme niveau
adresse 4ieme niveau
si 5ieme niveau
esterreur 6ieme niveau
cnum 7ieme niveau
Droite 8ieme niveau (ca plante donc à droite)


Essaie de Remplacer la formule que tu as mise 2 fois

+SI(ESTERREUR(CNUM(DROITE($B29;1)));0;CNUM(DROITE($B29;1)))

Par

+SI((CODE(DROITE($B29;1))<=57)*(CODE(DROITE($B29;1))>=48)=0;0;CNUM(DROITE($O32;1)))

Tu devrais gagner 1 niveau d'imbrication

Si 1er niveau
Workday 2ieme niveau
indirect 3ieme niveau
adresse 4ieme niveau
si 5ieme niveau
code 6ieme niveau
Droite 7ieme niveau (limite)

 

[ROGER2327]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

Suite... (sans trop d'espoir)

[COLOR="DarkSlateGray"][B]=(B29="ASAP")*(SERIE.JOUR.OUVRE(SI(C29;C29;A$1);2))+SI(GAUCHE(B29;9)="After Seq";SERIE.JOUR.OUVRE(MAX(C29;SERIE.JOUR.OUVRE((SI(INDEX($C$29:$C$31;EQUIV("Seq"&0+STXT(B29&"   ";10;3);$A$29:$A$31;0));INDEX($C$29:$C$31;EQUIV("Seq"&0+STXT(B29&"   ";10;3);$A$29:$A$31;0));A$1));2));2);0)[/B][/COLOR]

ROGER2327
#3833

Mercredi 18 Gidouille 137 (Visitation de Mère Ubu, SS)
14 Messidor An CCXVIII
2010-W26-5T01:46:01Z

 

[rico99]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

Bonjour à tous, bonjour rico


Je te retrouve même ici, la formule suivante est peut-être la bonne... J'ai fait des tests sur cette formule par des exemples choisis arbitrairement et avec des "Evaluations de formules", ces tests m'ont semblé satisfaisants... Testes-la sur ton fichier et me dire tes remarques...

= SI($B29="Asap";SI($C29="";WORKDAY(Champs_date_dep;$L29;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20));SI($C29>WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(DROITE($B29;1)*1);0;CNUM(DROITE($B29;1)));18));0;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20);WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(DROITE($B29;1)*1);0;CNUM(DROITE($B29;1)));18));$L29;Listes!$K$2:$K$20)))

Cordialement

non fonctionne pas, ça ne prend pas en considération la date finale d'une autre tâche si celle-ci est dépendante :$

 

[rico99]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

bon finalement, je vais découper ma formule sur plusieurs cellules, et ça ira très bien

merci à tous tout de même

 

[ROGER2327]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

Re...

À tout hasard...​

ROGER2327
#3834

Mercredi 18 Gidouille 137 (Visitation de Mère Ubu, SS)
14 Messidor An CCXVIII
2010-W26-5T08:00:37Z

 

[rico99]

Re : SI, CNUM, DROITE: Formules seules OK, imbriquées KO

alors finalement je suis sur

=SI($B29="Asap";SI($C29="";WORKDAY(Champs_date_dep;$L29;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20));SI($C29>WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(DROITE($B29;1)*1);0;CNUM(DROITE($B29;1)));20));0;Listes!$K$2:$K$20);WORKDAY($C29;$L29;Listes!$K$2:$K$20);WORKDAY(INDIRECT(ADRESSE(28+SI(ESTERREUR(DROITE($B29;1)*1);0;CNUM(DROITE($B29;1)));20));$L29;Listes!$K$2:$K$20)))

qui correspond exactement au besoin... par contre j'ai un problème de rafraichissement du calcul... et je ne souhaite pas utiliser application.calculatefull et le application.calculate ne donne rien...

une idée ?