Saisie à partir de la ligne 33

[isa44]

Bonsoir ,

que faut il mettre pour commencer la saisie à partir de la ligne 33 jusqu'à la ligne 95 ?

Sheets("memoire").[A65000].End(xlUp).Offset(0, 1) = Now

Merci pour votre aide

 

[Robert]

Re : Saisie à partir de la ligne 33

Bonsoir Isa, bonsoir le forum,

Pas sûr d'avoir bien compris... Essaie comme ça :

Sheets("memoire").Range("A33:A95").Value = Now

 

[isa44]

Re : Saisie à partir de la ligne 33

Bonsoir , en fait il faudrait que l'inscription des valeurs commencent à partir de la ligne 33.

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Sheets("memoire").[A65000].End(xlUp).Offset(0, 1) = Now
Sheets("memoire").[A65000].End(xlUp).Offset(0, 2) = Environ("username")
Sheets("memoire").[A65000].End(xlUp).Offset(0, 3) = Environ("computername")
Sheets("memoire").Visible = xlVeryHidden
For s = 2 To Sheets.Count ' on masque les feuilles
Sheets(s).Visible = xlVeryHidden
Next s
End Sub
Private Sub Workbook_Open()
Sheets("memoire").[A65000].End(xlUp).Offset(1, 0) = Now
For s = 2 To Sheets.Count ' on affiche les feuilles
Sheets(s).Visible = True
Next s
Sheets("memoire").Visible = xlVeryHidden
End Sub

 

[KenDev]

Re : Saisie à partir de la ligne 33

Bonjour Isa, Robert,

Sous réserve d'avoir compris et non testé (car j'ai la flemme de renommer une feuille) essayes ceci sur une copie.
Si tu es sous 2003 attention, à partir de la 65505 ème ouverture du classeur ce sera la ligne 33 qui sera modifiée à chaque fois. Cordialement

KD

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Dim Rw&, w As Worksheet, s%
Set w = Worksheets("memoire")
Rw = w.Cells(Rows.Count, 1).End(xlUp).Row
If Rw < 33 Then Rw = 33
w.Cells(Rw, 1).Offset(0, 1) = Now
w.Cells(Rw, 1).Offset(0, 2) = Environ("username")
w.Cells(Rw, 1).Offset(0, 3) = Environ("computername")
w.Visible = xlVeryHidden
For s = 2 To Worksheets.Count ' on masque les feuilles
    Worksheets(s).Visible = xlVeryHidden
Next s
End Sub
Private Sub Workbook_Open()
Dim Rw&, w As Worksheet, s%
Set w = Worksheets("memoire")
Rw = w.Cells(Rows.Count, 1).End(xlUp).Row
If Rw < 33 Then Rw = 33
w.Cells(Rw, 1).Offset(1, 0) = Now
For s = 2 To Worksheets.Count ' on masque les feuilles
    Worksheets(s).Visible = True
Next s
w.Visible = xlVeryHidden
End Sub