XL 2013 (RESOLU) Vérifier si elle existe une copie identique

[chaelie2015]

Bonsoir Forum
ci dessous un code vba, ce code me permet d’enregistrer une feuille de calcul active sous forme de fichier PDF. Il utilise des données provenant des cellules AL5, AL6 et Y3 pour construire le nom du fichier PDF qui sera enregistré dans le répertoire où se trouve le classeur actuel. jusqu'au la, le code fonctionne correctement
le reste du code ne fonctionne pas ( Si un fichier portant le même nom existe déjà dans le répertoire, un message s’affiche pour demander si l’utilisateur souhaite remplacer le fichier existant. Si l’utilisateur clique sur « Non », la procédure est interrompue et le fichier n’est pas remplacé. Si l’utilisateur clique sur « Oui », le fichier existant est remplacé par le nouveau fichier PDF) ?
merci par avance

Sub Enregistrer_PDF()

Dim NomFichierPDF As String
Dim Mois As String
Dim Annee As String
Dim Nom As String
Dim NomFichier As String

Mois = Range("AL6").Value
Annee = Range("AL5").Value
Nom = Range("Y3").Value

NomFichierPDF = "CRJT-" & Mois & "-" & Annee & "-" & Nom
NomFichierPDF = ThisWorkbook.Path & "\" & NomFichierPDF

If Dir(NomFichierPDF) <> "" Then
    If MsgBox("Le fichier PDF '" & NomFichierPDF & "' existe déjà. Voulez-vous le remplacer ?", vbYesNo + vbQuestion) = vbNo Then
        Exit Sub
    End If
End If

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, FileName:= _
    NomFichierPDF, Quality:=xlQualityStandard, _
    IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False

NomFichier = Split(NomFichierPDF, "\")(UBound(Split(NomFichierPDF, "\")))

MsgBox "Un nouveau fichier PDF nommé '" & vbCrLf & vbCrLf & NomFichier & vbCrLf & vbCrLf & " a été enregistré dans le répertoire " & vbCrLf & vbCrLf & ThisWorkbook.Path & "'."

End Sub

 

[Bernard_XLD]

Bonjour Chaelie2015, le forum

Sans fichier test, je pense que pour tester avec dir, il vaudrait mieux spécifier l'extension PDF, elle se met automatiquement lors de l'export puisque c'est un export PDF mais elle n'est pas présente dans votre nom de fichier prédéfini et dir ne trouve pas le fichier s'il existe déjà.

Cordialement, @+

NomFichierPDF = ThisWorkbook.Path & "\" & NomFichierPDF & ".pdf"

 

[chaelie2015]

Bonsoir Bernard_XLD et Forum
Je vous prie de m’excuser pour cette erreur. Je vous remercie beaucoup pour votre réponse et pour m’avoir expliqué ce qui se passe. Votre aide est très appréciée. mon souci est résolu grâce à votre aide.
A+