Autres [RÉSOLU] Souligner texte VBA

[un internaute]

Bonjour le forum
Dans la macro ci-dessous je voudrais souligner CB: & Chq:
Voir peut-être aussi si je peux "jouer" sur l'épaisseur du trait de soulignement mais si trop compliqué ne pas "s'acharner" dessus (pour épaisseur du trait)
Merci pour vos éventuels retours
Cordialement

Mais je ne sait pas faire

Option Explicit
Dim Ligne As Long
Dim Msg As String

Private Sub Opb100_Click()
  Me.TbMontant.Visible = False
  Me.LbMontant.Visible = False
  With Range("I" & Ligne)
    .Value = 1
    .NumberFormat = "00 %"
    End With
    Columns("I").AutoFit
End Sub

Private Sub OpbCB_Click()
  Me.TbMontant.Visible = True
  Me.LbMontant.Visible = True
  Msg = "CB: "
  With Range("I" & Ligne)
    .Value = Msg & Format(Replace(Me.TbMontant, ".", ","), "#,##0.00 €")
    .NumberFormat = "@"
    End With
    Columns("I").AutoFit
End Sub

Private Sub OpbChèque_Click()
  Me.TbMontant.Visible = True
  Me.LbMontant.Visible = True
  Msg = "Chq: "
  With Range("I" & Ligne)
    .Value = Msg & Format(Replace(Me.TbMontant, ".", ","), "#,##0.00 €")
    .NumberFormat = "@"
    End With
    Columns("I").AutoFit
End Sub

Private Sub TbMontant_Change()
  With Range("I" & Ligne)
    .Value = Msg & Format(Replace(Me.TbMontant, ".", ","), "#,##0.00 €")
    .NumberFormat = "@"
    End With
    Columns("I").AutoFit
End Sub

Private Sub TbMontant_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
 If InStr(1, "0123456789.,", Chr(KeyAscii)) = 0 And KeyAscii <> 8 Then
    KeyAscii = 0
 End If
End Sub

Private Sub UserForm_Initialize()
  Ligne = ActiveCell.Row
  Me.TbMontant.Visible = False
  Me.LbMontant.Visible = False
  Me.LbLigne.Caption = "Ligne " & Ligne
End Sub

 

[sousou]

Bonjour.
Pas de fichier joint?

 

[un internaute]

Bonjour sousou
Désolé mais pas de fichier joint impossible
Merci quand même

 

[TooFatBoy]

Bonjour,

A tester :

Private Sub OpbCB_Click()
  Me.TbMontant.Visible = True
  Me.LbMontant.Visible = True
  Msg = "CB : "
  With Range("I" & Ligne)
    .Value = Msg & Format(Replace(Me.TbMontant, ".", ","), "#,##0.00 €")
    .Characters(1, 4).Font.Underline = True
    .NumberFormat = "@"
    End With
    Columns("I").AutoFit
End Sub

Private Sub OpbChèque_Click()
  Me.TbMontant.Visible = True
  Me.LbMontant.Visible = True
  Msg = "Chq : "
  With Range("I" & Ligne)
    .Value = Msg & Format(Replace(Me.TbMontant, ".", ","), "#,##0.00 €")
    .Characters(1, 5).Font.Underline = True
    .NumberFormat = "@"
    End With
    Columns("I").AutoFit
End Sub

 

[un internaute]

Bonjour TooFatBoy
Presque super
Ça souligne tout alors que je voudrais stp
Chq: sans espace entre q et :
CB: sans espace entre B et :

 

[TooFatBoy]

T'es sûr que tu as bien recopié les deux macros ?

---

Si tu ne mets pas l'espace insécable avant le caractère ":", tu dois alors retrancher un au nombre de caractères à souligner et donc mettre respectivement 3 et 4 à la place de 4 et 5.

Private Sub OpbCB_Click()
  Me.TbMontant.Visible = True
  Me.LbMontant.Visible = True
  Msg = "CB: "
  With Range("I" & Ligne)
    .Value = Msg & Format(Replace(Me.TbMontant, ".", ","), "#,##0.00 €")
    .Characters(1, 3).Font.Underline = True
    .NumberFormat = "@"
    End With
    Columns("I").AutoFit
End Sub

Private Sub OpbChèque_Click()
  Me.TbMontant.Visible = True
  Me.LbMontant.Visible = True
  Msg = "Chq: "
  With Range("I" & Ligne)
    .Value = Msg & Format(Replace(Me.TbMontant, ".", ","), "#,##0.00 €")
    .Characters(1, 4).Font.Underline = True
    .NumberFormat = "@"
    End With
    Columns("I").AutoFit
End Sub

 

[un internaute]

Re TooFatBoy
SUPER
Oui tu as raison pour ci-dessous mais des "manies" de vieux!!!
Normalement en français il faut une espace insécable avant le caractère ":".
Merci à toi
Bonne journée
Cordialement

 

[TooFatBoy]

Normalement en français il faut une espace insécable avant le caractère ":".

J'ai supprimé cette partie de mon message pendant que tu répondais. 😉

---

SUPER

Content pour toi si ça répond à ta question initiale. 👍

Bonne journée
🖖