[RESOLU] SOMMEPROD et conditions

[@ntoine]

Bonjour.

Comment puis je utiliser au mieux la fonction SOMMEPROD ?
En utilisation "normale",La fonction SOMMEPROD permet d'effectuer horizontalement le produit de deux valeurs situées dans des colonnes différentes et d'en additionner les résultats.

Mais si la recherche doit s'effectuer dans une seule et meme plage de colonne, avec 2 argument de recherche ?.

Ci joint un classeur excel version 2003 comme exemple.

Merci pour toute précision.

 

[Dugenou]

Re : SOMMEPROD et conditions

Bonjour
=SOMMEPROD((D8:K17=D1)+(D8:K17=E1))
à l'intérieur de chaque parenthèse on a une matrice composée de 0 ou de 1 (vrai, faux)
avec sommeprod tu fais la somme de chaque matrice
il faut additionner les deux résultats (la multiplication équivaut à demander les deux critères en même temps)
ici l'intérêt du sommeprod est de faire l'opération sur des matrices : tu obtiendrais la même chose avec la fonction somme déclarée en matriciel :
=somme((D8:K17=D1)+(D8:K17=E1)) validée par ctrl+maj+enter

Cordialement

 

[Paf]

Re : SOMMEPROD et conditions

bonjour

s'il s'agit de compter dans la plage le nombre de valeur = D1 et le nombre de valeur = E1,

on peut conserver sommeprod: =SOMMEPROD((D8:K17=D1)+(D8:K17=E1))
ou bien utiliser par exemple : =NB.SI(D8:K17;D1)+NB.SI(D8:K17;E1)

A+

Edit: bonjour Dugenou, GerardCalc

 

[GerardCalc]

Re : SOMMEPROD et conditions

Bonjour,

Avec une SOMME matricielle :

=SOMME(FREQUENCE(SI(D8:K17=D1;LIGNE(D8:K17));LIGNE(D8:D17))*FREQUENCE(SI(D8:K17=E1;LIGNE(D8:K17));LIGNE(D8:D17)))

A+

 

[@ntoine]

Re : SOMMEPROD et conditions

onsoir.

Merci à tous .

Dugenou, Paf , GerardCalc.

Merci pour les formules et les explicatifs.
Cela me permet de réduire de beaucoup le nombre de formules.

GerardCalc, la formule SOMME matricielle, belle réalisation, qui répond à une question que j'avais omise (ou plutot mal formulé).

Encore merci à vous.

+