[RÉSOLU] Somme des valeurs uniques avec filtres

[Excel_sior]

Bonjour ! 🙂

Je cherche la formule permettant de faire la somme des valeurs uniques d'une plage tout en utilisant les filtres.

x) Présentation du fichier
Dans le fichier Excel, nous avons :
A) Un type d'action publicitaire
B) L'enseigne concernée
C) Le nombre d'actions effectuées
D) Le coût total hors taxe des actions effectuées
E) Le chiffre d'affaire total de l'enseigne
F) La proportion du coût total dans le chiffre d'affaire de l'enseigne

x) Le total chiffre d'affaire
Le total du chiffre d'affaire (E13) doit être égal à la somme des chiffres d'affaires mais une enseigne peut être présente plusieurs fois. Dans ce cas, il ne faut tenir compte de son chiffre d'affaire qu'une seule fois.

La matrice :

{=SOMME(1/NB.SI(E4:E12;E4:E12)*E4:E12)}

fonctionne pour calculer le total de toutes les enseignes mais si on applique un filtre (sur l'enseigne ou le type), cette formule ne tient pas compte des cellules masquées et le résultat reste donc toujours le même.

Un simple SOUS.TOTAL inclura les doublons.

Je peux compter le nombre de lignes uniques (merci Google) :

{=SOMME(1*(FREQUENCE(SI(SOUS.TOTAL(3;DECALER(E4;LIGNE(E4:E12)-LIGNE(E4);;1));EQUIV(E4:E12;E4:E12;0));LIGNE(INDIRECT("1:"&LIGNES(E4:E12))))>0))}

mais je n'arrive pas à calculer la somme de ces valeurs.


Vos idées / solutions sont les bienvenues 🙂

 

[Lone-wolf]

Bonjour Excel_sior, le Forum.

Tu dit: Un simple SOUS.TOTAL inclura les doublons. Je ne comprends pas pourquoi si X qui apparaît 10 fois après le filtre doit avoir un total de 10000, si à lui seul il à 3500???

 

[JHA]

Bonjour à tous,
Pas sur mais à essayer

=SOMME(SI(1*(FREQUENCE(SI(SOUS.TOTAL(9;DECALER(E4;LIGNE(E4:E12)-LIGNE(E4);;1));EQUIV(E4:E12;E4:E12;0));LIGNE(INDIRECT("1:"&LIGNES(E4:E12))))>0);E4:E12))

Formule matricielle

JHA

 

[Excel_sior]

Bonjour Lone-wolf,

Je ne suis pas sûr de comprendre la question.

Dans la colonne CA (E), le chiffre d'affaire affiché est le chiffre d'affaire total pour cette enseigne.
Lorsque j'affiche plusieurs fois une enseigne (il peut y avoir plusieurs types d'animations pour la même enseigne), j'indique à nouveau le chiffre d'affaire qui sera toujours identique pour la même enseigne.
Cela me permet de calculer la proportion (colonne F).

Lorsque je fais le total de tous les chiffres d'affaires, je ne souhaite pas compter plusieurs fois le CA de la même enseigne.

Par exemple, si je sélectionne "Enseigne 1" dans mon fichier, j'ai 3 types d'animations.
La formule SOUS.TOTAL(109;E4:E12) me retournera 30 000.
Or, le total CA pour cette enseigne est (malheureusement) bien de 10 000.

 

[Lone-wolf]

Re,

Dans ce cas c'est autre chose, je comprend mieux maintenant.

 

[Excel_sior]

Bonjour JHA,

C'est çaaa \o/
J'avais dans l'idée d'ajouter un paramètre à la fin mais j'étais parti dans quelque chose de bien plus complexe... Pour rien.

Merci beaucoup 🙂
Sujet résolu, vite fait bien fait !

@Lone-wolf merci du temps que tu m'as accordé.