Autres [RÉSOLU] Peut-on faire une macro qui met une seule macro en commentaires puis le contraire!!!

[un internaute]

Bonjour le forum
Allo! job75
Ta macro un bijou
Comme dit dans le titre est-ce possible?
Non pas sélectionner la macro puis faire "commenter bloc" puis le contraire "Ne pas commenter bloc" peut-on le faire avec une macro puis un bouton?
C'est certainement IDIOT ou C$N!!!
Te tente quand même .. mais interdit de rigoler!!!

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim plage As Range, trim%, txt$, W#, n%
Set plage = Range("D18,D37,D56,D75")
Application.ScreenUpdating = False
Application.EnableEvents = False
For trim = 1 To 4
    txt = "Montant Fonds Travaux " & trim & IIf(trim = 1, "er", "ème") & " Trimestre "
    Set Target = plage.Areas(trim)
    W = Target.ColumnWidth
    n = 0
    Do
        n = n + 1
        Target = txt & String(n, "-") & ">"
        Target.Columns.AutoFit
    Loop While Target.ColumnWidth < W + 1
    Target.ColumnWidth = W
    Target.Characters(Len(txt) - 14, 14).Font.Color = vbRed
Next trim
Application.EnableEvents = True
End Sub

 

[patricktoulon]

Bonjour
pour bloquer une macro tu n'a peut être pas besoin de la mettre en commentaire
tu peux tout simplement utiliser un flag boolean switché par un bouton et mettre tout le code de la macro dans un if flag

 

[un internaute]

Bonjour
pour bloquer une macro tu n'a peut être pas besoin de la mettre en commentaire
tu peux tout simplement utiliser un flag boolean switché par un bouton et mettre tout le code de la macro dans un if flag

Bonjour patricktoulon
Oh! là là c'est de l'hébreu pour un nonagénaire
Si tu peux expliquer ou encore mieux le faire stp

 

[patricktoulon]

re

Option Explicit

Dim flag As Boolean 'variable flag

Private Sub Worksheet_Change(ByVal Target As Range)
    If flag Then
           Dim plage As Range, trim%, txt$, W#, n%
        Set plage = Range("D18,D37,D56,D75")
        Application.ScreenUpdating = False
        Application.EnableEvents = False
        For trim = 1 To 4
            txt = "Montant Fonds Travaux " & trim & IIf(trim = 1, "er", "ème") & " Trimestre "
            Set Target = plage.Areas(trim)
            W = Target.ColumnWidth
            n = 0
            Do
                n = n + 1
                Target = txt & String(n, "-") & ">"
                Target.Columns.AutoFit
            Loop While Target.ColumnWidth < W + 1
            Target.ColumnWidth = W
            Target.Characters(Len(txt) - 14, 14).Font.Color = vbRed
        Next trim
        Application.EnableEvents = True
    End If
End Sub

'sub du bouton en shape
Sub deflag()
    flag = Not flag
ActiveSheet.DrawingObjects("boutonflag").Text = Array("no", "")(Abs(flag)) & " Flag"
End Sub

au départ l'event change ne fonctionne pas
si tu clique il fonctionnera
si tu re clique il sera à nouveau bloqué
et ainsi de suite
le bouton change de texte pour un visuel sur l'etat du flag
te reste plus qu'a mettre une shape nommée boutonflag dans ta feuille

 

[mapomme]

Bonjour @un internaute , @patricktoulon😉,

Un peu en retard (comme d'hab.)... Sinon même solution que @patricktoulon :
La forme sur la feuille est nommée "OKmacro" et sa macro associée a aussi pour nom OKmacro dans le module de la feuille Feuil1.
Les codes :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim plage As Range, trim%, txt$, W#, n%
   ' si AlternativeText est égal à "1", on continue l'exécution de cette macro sinon on quitte cette macro
   If Me.Shapes("OKmacro").AlternativeText <> "1" Then Exit Sub
   Set plage = Range("D18,D37,D56,D75")
   Application.ScreenUpdating = False
   Application.EnableEvents = False
   For trim = 1 To 4
      txt = "Montant Fonds Travaux " & trim & IIf(trim = 1, "er", "ème") & " Trimestre "
      Set Target = plage.Areas(trim)
      W = Target.ColumnWidth
      n = 0
      Do
         n = n + 1
         Target = txt & String(n, "-") & ">"
         Target.Columns.AutoFit
      Loop While Target.ColumnWidth < W + 1
      Target.ColumnWidth = W
      Target.Characters(Len(txt) - 14, 14).Font.Color = vbRed
   Next trim
   Application.EnableEvents = True
End Sub

Sub OKmacro()
Dim shp As Shape
   ' la forme s'appelle "OKmacro". AlternativeText de cette forme vaut "1" si la macro Worksheet_Change
   ' doit être exxécutée
   Set shp = Me.Shapes("OKmacro")      ' shp est la forme nommée "OKmacro" sur la feuille
   ' si AlternativeText de cette forme vaut "1" alors AlternativeText est mis à "0" sinon à "1"
   shp.AlternativeText = IIf(shp.AlternativeText = "1", "0", "1")
   ' On adapte le texte de la forme en fonction de AlternativeText
   shp.TextFrame2.TextRange.Characters.Text = IIf(shp.AlternativeText = 1, "Inhiber Worksheet_Change", "Activer Worksheet_Change")
End Sub

 

[patricktoulon]

re
bonjour je n'y ai pas pensé sur le coup @mapomme mais tu a raison c'est même mieux
mieux pourquoi:
par ce que il n'y a pas de memorisation dans variable vba
au cas ou il y a un debugage c'est pas perdu
donc ta solution est encore mieux

 

[un internaute]

Bonjour le forum
Je met le fichier car je n'y comprend rien mais alors strictement rien
Si mapomme tu peux le faire fonctionner je suis preneur!!
Pourquoi pas mettre en double click cellule I7 par exemple Mode commentaires et mode non commentaires?
C'est certainement une C$$$$$$E!!!
Bien cordialement à vous tous
PS: je suis sous encore sous Excel 2003 et si le PC lâche moi aussi compte tenu de l'âge et de mes maladies

 

[Valtrase]

Bonjour à tous,
@un internaute Il faut juste ajouter une forme sur la feuille et lui donner le nom 'OKmacro' et lui affecter la macro OKmacro de la feuille 10. Ensuite mettre 1 ou 0 dans la propriété 'texte de remplacement' de la forme (Son emplacement diffère selon les versions d'Excel)

 

[patricktoulon]

re
je l'ai laissé en ".xls" mais bon

 

[un internaute]

re
je l'ai laissé en ".xls" mais bon

Bonjour Patricktoulon
J'ai mis ton bouton mais ça me met
Propriété ou méthode non gérée par cet objet
Bonjour Valtrase
Toi ça met

 

[un internaute]

Bonjour Patricktoulon
J'ai mis ton bouton mais ça me met
Propriété ou méthode non gérée par cet objet
Bonjour Valtrase
Toi ça met
Regarde la pièce jointe 1220350

re
je l'ai laissé en ".xls" mais bon

Bonjour Patricktoulon
J'ai mis ton bouton mais ça me met
Propriété ou méthode non gérée par cet objet
Bonjour Valtrase
Toi ça met

 

[un internaute]

On avance on avance mais...

 

[dysorthographie]

Bonjour,
Je ne sais pas, en revanche dans l'éditeur VBA tu peux faire un clic droit sur la barre de menu et ajouter l'option édition.

Après tu pourras sélectionner tout le code de la Macro et la passer en commentaire en un seule click.

 

[un internaute]

Bonjour dysorthographie
Oui oui j'ai fait et c'est bon

 

[patricktoulon]

re:
tu n'avais rien à mettre juste tester le fichier que je t'ai retourné
et je le redit si ta version d'excel n'est pas 2003, laisser le fichier en xls provoque le mode rétrocompatibilité
de ce fait la gestion des shapes peut être légèrement différente (si je me souviens bien )
donc par pitié essaie de travailler avec la bonne version d'excel autrement dit si tu n'es pas en excel 2003 sauve le en xlsm et vire moi ce xls

patrick