[Résolu par job75]Problème recherche avec Listview et suppression ligne de la feuille

[Lone-wolf]

Bonjour le Forum,

le but de la macro suivante est de sélectionner un item dans la listview. De là, elle doit rechercher la ligne correspondante et la supprimer. Dans l'exemple j'ai mis un fond de couleur rouge pour test, sans résultat.

Private Sub CmdSup_Click()
Dim Dt As String, cel As Range, i As Integer

'MsgBox "Vous allez supprimer l'enregistrement.", , "MIMI"

For i = 1 To ListView1.ListItems.Count
Dt = ListView1.ListItems(i).ListSubItems(3).Text
    ListView1.ListItems(i).Selected = True
    With Sheets("Feuil1").Range("a3:g53")
    Set cel = .Find(Dt, , xlValues, xlWhole)
    If Not cel Is Nothing Then
    If cel.Offset(0, 3).Value = Dt Then cel.Offset(0, 3).Interior.Color = vbRed
    End If
        End With
Next
    'ListView1.ListItems.Remove (ListView1.SelectedItem.Index)
End Sub

Avant celà j'ai fais un test avec Msgbox = ListView1.ListItems(i).ListSubItems(3).Text, elle me donne bien le text, je ne comprends pas pourquoi je n'arrive pas à supprimer cette ligne.


A+ 😎

 

[grisan29]

Re : Problème recherche avec Listview et suppression ligne de la feuille

bonjour lone-wolf

est ce que ce lien te permettra d'arriver a ce que tu veux

 

[Lone-wolf]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Bonjour grisan,

supprimer la ligne de la listview(avant dernière ligne de la macro), c'est une chose. Moi j'aimerais qu'elle me supprime la même ligne dans la feuille.




A+ 😎

 

[job75]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Bonjour Lone-wolf, le forum,

Pas trop compris ce que tu fabriques avec ton cel.Offset(0, 3) tu recherches 2 fois Dt ???

A priori je supposerai que tu recherches Dt en colonne C.

De plus il est inutile de sélectionner la ligne de la ListView pour la supprimer :

Private Sub CmdSup_Click()
Dim i As Long, Dt As String, cel As Range
For i = 1 To ListView1.ListItems.Count
  Dt = ListView1.ListItems(i).ListSubItems(3).Text
  Set cel = Sheets("Feuil1").[C3:C53].Find(Dt, , xlValues, xlWhole)
  If Not cel Is Nothing Then
    ListView1.ListItems.Remove i
    cel.Interior.Color = vbRed
    Exit For
  End If
Next
End Sub

Enfin avec Application.Match la recherche est plus rapide qu'avec Find :

Private Sub CmdSup_Click()
Dim i&, x, j As Variant
With Sheets("Feuil1")
  For i = 1 To ListView1.ListItems.Count
    x = ListView1.ListItems(i).ListSubItems(3)
    j = Application.Match(x, .[C:C], 0)
    If IsNumeric(j) Then
      ListView1.ListItems.Remove i
      .Cells(j, 3).Interior.Color = vbRed
      Exit For
    End If
  Next
End With
End Sub

Bonne journée.

 

[Lone-wolf]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Re,

en prenant l'exemple de l'insertion d'une ligne dans la feuille et en modifiant comme ceci

Private Sub CmdSup_Click()
Dim i As Integer, j As Integer

    For i = 1 To ListView1.ListItems.Count
    ListView1.ListItems(i).Selected = True
        For j = 1 To ListView1.ColumnHeaders.Count - 1
          With Sheets("Feuil1")
            If .Cells(i, j + 1) = ListView1.ListItems(i).ListSubItems(j).Text Then _
            .Cells(i, j + 1).Interior.Color = vbRed
            End With
        Next j
    Next i
End Sub

C'est toujours la même chose et ça m'énerve, aucun résultat.



A+ 😎

 

[job75]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Re, salut grisan29 je ne t'avais pas vu,

supprimer la ligne de la listview(avant dernière ligne de la macro), c'est une chose. Moi j'aimerais qu'elle me supprime la même ligne dans la feuille.

Bon alors pourquoi tu colorais la cellule ???

Private Sub CmdSup_Click()
Dim i As Long, Dt As String, cel As Range
For i = 1 To ListView1.ListItems.Count
  Dt = ListView1.ListItems(i).ListSubItems(3).Text
  Set cel = Sheets("Feuil1").[C3:C53].Find(Dt, , xlValues, xlWhole)
  If Not cel Is Nothing Then
    ListView1.ListItems.Remove i
    cel(1, -1).Resize(, 7).Delete xlUp 'colonnes A à G
    Exit For
  End If
Next
End Sub

Private Sub CmdSup_Click()
Dim i&, x, j As Variant
With Sheets("Feuil1")
  For i = 1 To ListView1.ListItems.Count
    x = ListView1.ListItems(i).ListSubItems(3)
    j = Application.Match(x, .[C:C], 0)
    If IsNumeric(j) Then
      ListView1.ListItems.Remove i
      .Cells(j, 1).Resize(, 7).Delete xlUp 'colonnes A à G
      Exit For
    End If
  Next
End With
End Sub

A+

 

[Lone-wolf]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Bonjour job,

j'ai tester la macro avec Match 1, pas de résultat, et ça continue à m'enerver. 😡 C'est quand même pas croyable?! 😕


Edit: on c'est croisés, j'ai mis un fond rouge juste pour tester. Je vais tester Match 2.

Edit 2: cette fois c'est ok. Il fallait mettre listsubitems(2) au lieu de 3, puisque ça part de 0.
C'était tout con, et il a fallut que je m'énerve.


Merci infiniment job.



A+ 😎

 

[job75]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Re,

Tu pourrais être plus clair sur ce que tu veux chercher et où.

Ça veut dire quoi Match 1 et Match 2 ???

Edit OK vu ton Edit 2 et puisque ça marche il fallait bien chercher en colonne C, merci ma boule de cristal 🙄

Cela dit au post #1 tu avais testé .ListSubItems(3) 😕

Avant celà j'ai fais un test avec Msgbox = ListView1.ListItems(i).ListSubItems(3).Text, elle me donne bien le text

A+

 

[Lone-wolf]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Re job,

Ça veut dire quoi Match 1 et Match 2 ???

Bein..., ce sont les deux macros que tu viens de me proposer. 😉

Et il fallait ajouter + 1 à .Cells(j, 1).Resize.


Dans tous les cas merci encore une fois pour avoir résolu le problème.

Très bonne journée

Amicalement Lone-wolf 😎

 

[job75]

Re : Problème recherche avec Listview et suppression ligne de la feuille

Et il fallait ajouter + 1 à .Cells(j, 1).Resize.

Ah bon, ajouter +1 où ? Tu es champion pour les énigmes toi 🙄

.Cells(j, 1).Resize(, 7).Delete xlUp supprime les cellules de A à G un point c'est tout.

Dans ta macro du post #1 tu parlais bien de ces colonnes...

A+

 

[Lone-wolf]

Re : [Résolu par job75]Problème recherche avec Listview et suppression ligne de la fe

Re job,

désolé pour le + 1, c'est moi qui a mal selectionné la ligne de la listview. Et puisque tu es là, je ne comprends pas pourquoi quand je sélectionne la ligne la sélection(en bleu) s'arrête à la première colonne. Comment faire pour garder la sélection en bleu sur toute la ligne?


A+ 😎

 

[job75]

Re : [Résolu par job75]Problème recherche avec Listview et suppression ligne de la fe

Re enigme, champion,

La variable j n'a rien à voir avec la ListView 🙄

Et tu la sélectionnes comment ta ligne dans la ListView ? On pourrait voir la macro ?

Cela dit je n'ai pas de contrôle ListView sur mon ordi...

A+

A+

 

[job75]

Re : [Résolu par job75]Problème recherche avec Listview et suppression ligne de la fe

Re,

Bon 15 secondes pour trouver ce lien :

[VB.NET] Sélection ligne entière ListView [Résolu]

A+

 

[Lone-wolf]

Re : [Résolu par job75]Problème recherche avec Listview et suppression ligne de la fe

Re,

Et tu la sélectionnes comment ta ligne dans la ListView ?

Et bein je clique dans la listview, et ensuite sur le bouton. Et dans les propriétés, fullrowselect est à true.


A+ 😎

 

[job75]

Re : [Résolu par job75]Problème recherche avec Listview et suppression ligne de la fe

Re,

Peux-tu expliquer pourquoi tu sélectionnes ?

Si c'est pour supprimer la ligne sélectionnée ce n'est sûrement pas avec le bouton "CmdSup" objet de ce fil !!!

Maintenant pour sélectionner la ligne entière il me semble avoir vu qu'il faut aussi que la propriété View soit sur Details.

A+