[RESOLU] Fonction personnalisée- Descriptif des arguments dans l'assistant excel

[nicoloc]

Bonjour à tous
Je viens de decouvrir les fonction personnalisée dans Excel et je suis fan 😀
Je cherche a rendre mes fonction le plus accessible possible et je souhaiterai avoir un descriptif complet des argument dans l'assistant de formule Excel.

De nombreux site explique comment commenter la fonction via MAcroOption

Application.MacroOptions Macro:="MTTR_SI_ENS2", _
Description:="Permet de calculer le MTTR avec 2 critères de filtrage" _
, Category:=14

Mais aucun ne decrit commenter chacun des arguments (Tps_arret , Plage1, critere1 , Plage2 , critere2) de la fonction

Function MTTR_SI_ENS2(Tps_arret As Range, Plage1 As Range, critere1 As Variant, Plage2 As Range, critere2 As Variant)

Est ce possible ?
Merci de votrea aide 🙂
Nicoloc

 

[MJ13]

Re : Fonction personnalisée- Descriptif des arguments dans l'assistant excel

Bonjour Nicoloc

Voir peut-être ici de notre ami Jean-Marie:

https://www.excel-downloads.com/thr...un-objet-selon-la-valeur-dune-cellule.213670/

 

[nicoloc]

Re : Fonction personnalisée- Descriptif des arguments dans l'assistant excel

MJ13: Le lien ne m'apporte pas la solution car cela semble focalisé sur la description de la fonction et non des arguments.
Par contre, le lien pointe sur un forum qui à un lien , qui à un lien , qui a un lien ect .... qui pointe vers

Spreadsheet Page Excel Tips: User-Defined Function Argument Descriptions In Excel 2010

qui fournit toute les explications sur l'utilisation de Argument description 🙂
et ca marche 🙂

Je recopie l'astuce au cas ou un jours la page disparait

One of the new features in Excel 2010 is the ability to provide argument descriptions for user-defined functions. These descriptions appear in Function Arguments dialog box -- which is displayed after you choose a function using the Insert Function dialog box.

Here's a simple (but very useful) user-defined function:

Function EXTRACTELEMENT(Txt, n, Separator) As String
     EXTRACTELEMENT = Split(Application.Trim(Txt), Separator)(n - 1)
End Function

Here's a VBA macro that provides a description for the EXTRACTELEMENT function, assigns it to a function category, and provides a description for each of its three arguments:

  Sub DescribeFunction()
   Dim FuncName As String
   Dim FuncDesc As String
   Dim Category As String
   Dim ArgDesc(1 To 3) As String

   FuncName = "EXTRACTELEMENT"
   FuncDesc = "Returns the nth element of a string that uses a separator character"
   Category = 7 'Text category
   ArgDesc(1) = "String that contains the elements"
   ArgDesc(2) = "Element number to return"
   ArgDesc(3) = "Single-character element separator"

   Application.MacroOptions _
      Macro:=FuncName, _
      Description:=FuncDesc, _
      Category:=Category, _
      ArgumentDescriptions:=ArgDesc
End Sub

You need to run this macro only one time. After doing so, the descriptive information is stored in the workbook (or add-in) that defines the function.

Merci a eux
Merci MJ13
j'adore ce forum 😀

Nicoloc