[Résolu] Contrôler un texte destiné à la nomination d'un fichier

[Djus]

Bonjour,

Je n'ai pas trouvé de post répondant à mon problème, que voici:

J'ai construit un classeur Excel qui permet, de manière automatisée via un bouton de commande et une macro VBA associée, de sauvegarder le classeur sur mon réseau en le nommant en fonction d'un numéro de série construit grâce aux renseignement de plusieurs cases (Date, Site, Etc.) suivi d'un titre succinct.
J'ai mis en place une validation de donnée sur cette case Titre pour interdire la saisie des caractères interdits par Windows (?.:\/<>"'*).
J'ai donc opté pour une validation de type personnalisée avec la formule suivante:
=ET(NBCAR(F3)<=25;ESTERREUR(TROUVE(".";F3));ESTERREUR(TROUVE("/";F3));ESTERREUR(TROUVE("?";F3));ESTERREUR(TROUVE(">";F3));ESTERREUR(TROUVE("<";F3));ESTERREUR(TROUVE(":";F3));ESTERREUR(TROUVE("""";F3));ESTERREUR(TROUVE(CAR(42);F3)))

ça fonctionne au poil, mais vous aurez remarqué que tous les caractères interdits n'y figurent pas. En fait, je suis bloqué car Excel limite la longueur en caractère de la formule, et je ne peux plus ajouter de bloc ESTERREUR(TROUVE(...)) supplémentaire...

Quelqu'un aurait il une alternative ou alors une formulation plus compacte?

Sous Excel 2007, Windows XP.

 

[mapomme]

Re : Contrôler un texte destiné à la nommination d'un fichier

Bonjour et bienvenu,

Essayez cette formule de validation:

=ET(NBCAR(F3)<=25;ESTERR(CHERCHE(STXT(F3;LIGNE(INDIRECT("1:" & NBCAR(F3)));1);"\/:*?""<>")))

Si vous voulez tester la formule dans une cellule, notez que cette formule est une formule matricielle.

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

 

[Djus]

Re : Contrôler un texte destiné à la nommination d'un fichier

Ca fonctionne très bien!
Je n'aurais jamais trouvé ça tout seul. Merci beaucoup mapomme,

Etant débutant sur ce forum, je ne sais pas s'il faut taguer le sujet comme résolu (rien dans la charte à ce sujet) et surtout comment?

 

[mapomme]

Re : Contrôler un texte destiné à la nommination d'un fichier

(re)Bonjour,
Il me semble qu'on peut modifier le titre du fil en le précédant de la mention [Résolu].

 

[Djus]

Re : [Résolu] Contrôler un texte destiné à la nommination d'un fichier

En effet, en modifiant le premier message. Encore merci mapomme et bonne journée.