[Résolu] Calcule du nombres de cellules contenant un chiffre

[Linrasis]

Bonjour,

Après plusieurs heures de recherches sur google, je post ma demande d'aide sur se forum.

Voici mon problème :

J'aurais besoin de calculer le nombres de cellules contenant le chiffre 67, mais il faut savoir que les cellules sont former d'adresse : "Entreprise X, F-67100 Strasbourg"

J'ai utiliser plusieurs formules, peut être mal utiliser .. ensuite si la formule est trouver, une possibilité d'ajouter un département en plus ? ("67";"68" par exemple) Sa me permettrais de les trier par régions. Au pire des cas, je bidouillerais =A1+A2 qui m'additionnerais le 67 + 68.

Bonne journée, cordialement.

 

[Guest]

Re : Calcule du nombres de cellules contenant un chiffre

Bonjour,

Avec un fichier exemple se serait mieux. Aller lire la charte du forum pour savoir comment obtenir des réponses pertinentes.

Proposition par formule matricielle(à valider par CTRL+MAJ+ENTRER)

=SOMME(SI(ESTNUM(TROUVE("67";A1:A21));1;0))

A+

[Edit]Salut Job🙂, hoerwind🙂
ch'ai pas pourquoi ch'ui parti là dessus moi(oublié nb.si)😉

 

[job75]

Re : Calcule du nombres de cellules contenant un chiffre

Bonjour,

=NB.SI(A:A;"*67*")

=NB.SI(A:A;"*68*")

=NB.SI(A:A;"*67*68*")

=NB.SI(A:A;"*68*67*")

A+

 

[hoerwind]

Re : Calcule du nombres de cellules contenant un chiffre

Bonjour,

Essaie ceci : =NB.SI(A1:A20;"*67*")

N'est valable que pour compter des codes postaux, mais 16700 ou 26720 sont également pris en compte (il me semble qu'ils ne peuvent exister), par contre les valeurs numériques contenant 67 ne sont pas pris en compte, bien d'éventuels n° dans une adresse.

Il faudrait tester si "-67*" n'est pas plus efficace.

 

[job75]

Re : Calcule du nombres de cellules contenant un chiffre

Re,

Noter que les formules précédentes ne font pas la différence entre 67049 et 49067...

Pour obtenir le numéro du département, il faut vérifier que le caractère qui précède n'est pas un nombre :

=SOMME(SI(ESTNUM(TROUVE("67";A1:A100));--ESTERR(-STXT(A1:A100;TROUVE("67";A1:A100)-1;1))))

Formule matricielle à valider par Ctrl+Maj+Entrée.

A+

 

[JBOBO]

Re : Calcule du nombres de cellules contenant un chiffre

Bonjour,

En adaptant vos formules on peut essayer :

=NB.SI($D:$D;"*67??? *")

 

[Linrasis]

Re : Calcule du nombres de cellules contenant un chiffre

Bonjour,

Avec un fichier exemple se serait mieux. Aller lire la charte du forum pour savoir comment obtenir des réponses pertinentes.

Proposition par formule matricielle(à valider par CTRL+MAJ+ENTRER)

=SOMME(SI(ESTNUM(TROUVE("67";A1:A21));1;0))

A+

[Edit]Salut Job🙂, hoerwind🙂
ch'ai pas pourquoi ch'ui parti là dessus moi(oublié nb.si)😉

Bonjour Hasco,

Parmit toutes les solutions que j'ai tester la tienne fonctionne parfaitement.
J'ai réfléchi pendant la pause au repas que si nous avons un code postal 89670 la formule le prendrais en compte se qui est mauvais. Mais vue que j'ai ajouté F- devant (F = France)

=SOMME(SI(ESTNUM(TROUVE("F-67";A1:A21));1;0))

Fonctionne parfaitement, c'est parfait.. mais maintenant tu pense qu'on puisse ajouté plusieurs critères ? 67 - 68 par exemple ?
C'est se qui m'intérèse le plus actuellement pour les classé par régions.

En attente d'une réponse de ta part, je vais essayer les de bidouillé ou de tester les propositions des autres internaute qui ont répondu à mon appel d'aide.

 

[Linrasis]

Re : Calcule du nombres de cellules contenant un chiffre

Bonjour,

=NB.SI(A:A;"*67*")

=NB.SI(A:A;"*68*")

=NB.SI(A:A;"*67*68*")

=NB.SI(A:A;"*68*67*")

A+

Bonjour,

Malheureusement ta formule ne fonctionne pas.. j'obtient 0.

=NB.SI(Général!I8:I22;"*67*68*")

 

[job75]

Re : Calcule du nombres de cellules contenant un chiffre

Re,

=NB.SI(A:A;"*67*") donne 0 ??? Vous plaisantez...

Avec le F- ça donne :

=NB.SI(A:A;"*F-67*")

A+

 

[job75]

Re : Calcule du nombres de cellules contenant un chiffre

Re,

Au cas où vous n'auriez pas compris.

Nombres d'adresses avec F-67 OU F-68 :

=NB.SI(A:A;"*F-67*")+NB.SI(A:A;"*F-68*")

Nombre d'adresses avec F-67 ET F-68 dans la même cellule :

=NB.SI(A:A;"*F-67*F-68*")

A+

 

[Linrasis]

Re : Calcule du nombres de cellules contenant un chiffre

Sa fonctionne, merci.