Microsoft 365 Reporter automatiquement le nombre de valeurs uniques d'un tableau structuré filtré par plusieurs segments.

[Bernard_XLD]

Bonjour le forum

Je désire connaitre le nombre de valeurs uniques d'une référence affichées dans un tableau structuré filtré par plusieurs segments, cela sans autre action par l'utilisateur que d'utiliser un segment ou masquer une ligne manuellement.
Cela a l'air simple ! Eh bien non, je sèche dessus depuis hier.
Dès que je cumule des segments, ça part en sucette.
Toutes les fonctions que j'ai utilisé, à part sous.total, prennent en compte les lignes masquées, ou du moins, je n'ai pas trouvé comment faire avec Unique et Fréquence.
Dans le fichier joint, si je clique sur le segment Mois/9, je devrais avoir 7 Réf1 différentes (en cellule orange), sur le Mois/11, je devrais avoir 8 Réf1 différentes.
Je préfèrerais une solution purement formule, mais je prendrai avec plaisir une solution en fonction personnalisée, événementielle, sorcellerie ou boule de cristal.

En précision, la Réf1 est toujours de type long, le nombre de Réf1 différentes de base n'est pas limité, elles peuvent être plusieurs milliers.

Cordialement, @+

 

[chris]

Bonjour

En ajoutant une colonne Vis (masquée) au tableau avec la formule

=SOUS.TOTAL(3;[@Mois])

Ensuite

=NBVAL(UNIQUE(FILTRE(Tableau_Structure_01[Réf 1];Tableau_Structure_01[Vis]=1)))

 

[Bernard_XLD]

Bonjour Chris

Excellente formule, c'est presque cela ! ( bon à 99,99% )
Je n'ai en fait trouvé qu'un seul cas ou la formule renvoie une valeur fausse, si toutes les valeurs sont filtrées, elle renvoie 1 au lieu de zéro.

exemple:
segment mois sur 10
segment Réf3 sur M
renvoie1 au lieu de zéro

Je contourne avec un MIN sur le nombre de valeurs filtrées forcément supérieur ou égal au nombre de Réf1 filtrés uniques, pas super joli mais cela fonctionne. Si tu as mieux, n'hésite pas.

=MIN(NBVAL(UNIQUE(FILTRE(Tableau_Structure_01[Réf 1];Tableau_Structure_01[Vis]=1)));SOUS.TOTAL(103;Tableau_Structure_01[Valeur]))

Je vais tester sur mes fichiers finaux qui contiennent quelques milliers de lignes et des valeurs très différentes.
Merci,
Amicalement,
Bernard_XLD

 

[chris]

RE

=SI(SOUS.TOTAL(3;Tableau_Structure_01[Réf 1])<>0;NBVAL(UNIQUE(FILTRE(Tableau_Structure_01[Réf 1];Tableau_Structure_01[Vis]=1)));0)