Répéter une macro

[emilienoel]

Bonjour,

J'ai recopié une macro qui crée un rappel sur Outlook à partir d'Excel.
Par contre, je ne sais pas comment répéter cette macro pour toutes les lignes de mon tableau.

Voici ma macro qui fonctionne mais uniquement pour la première ligne, je ne sais pas comment lui indiquer qu'elle passe à la ligne suivante.

Sub AjoutTache()
Dim OlApp As Object
Dim NS As Object, ObjTask As Object
Set OlApp = CreateObject("Outlook.Application")
Set NS = OlApp.GetNamespace("MAPI")
Set ObjTask = OlApp.CreateItem(olTaskItem)
With ObjTask
.Subject = "Visite médicale" & " " & [c2]
'.Body = "texte"
.ReminderTime = [g2]
.ReminderSet = True
.Display 'mettre en commentaire après mise au point
End With
ObjTask.Save
End Sub



Merci par avance,
Bonne journée,
Emilie

 

[titiborregan5]

Re : Répéter une macro

Bonjour emilie, le forum

essaie de la mettre dans une boucle

 Sub AjoutTache()
Dim OlApp As Object
Dim NS As Object, ObjTask As Object
Set OlApp = CreateObject("Outlook.Application")
Set NS = OlApp.GetNamespace("MAPI")
Set ObjTask = OlApp.CreateItem(olTaskItem)
for i = 1ère ligne To dernière ligne
ton code tu remplaces les numéros de ligne par i (par exemple [g2] devient cells(i,7))
With ObjTask
.Subject = "Visite médicale" & " " & [c2]
'.Body = "texte"
.ReminderTime = [g2]
.ReminderSet = True
.Display 'mettre en commentaire après mise au point
End With
ObjTask.Save
Next
end sub

 

[emilienoel]

Re : Répéter une macro

Bonjour titiborregan5,

Merci pour l'info et voici ce que j'ai fait mais ça ne fonctionne pas.
Quand on exécute la macro, on voit bien que tous les rappels se créent mais après il ne reste dans mes rappels sur Outlook que ma dernière ligne d'Excel.

Alors que je voudrais que pour chaque échéance un rappel se crée


Sub AjoutTache()
Dim OlApp As Object
Dim NS As Object, ObjTask As Object
Set OlApp = CreateObject("Outlook.Application")
Set NS = OlApp.GetNamespace("MAPI")
Set ObjTask = OlApp.CreateItem(olTaskItem)
For i = 2 To 78
With ObjTask
.Subject = "Visite médicale" & " " & Cells(i, 3)
'.Body = "texte"
.ReminderTime = Cells(i, 7)
.ReminderSet = True
.Display 'mettre en commentaire après mise au point
End With
ObjTask.Save
Next
End Sub

 

[bmonnoy]

Re : Répéter une macro

Bonjour Emilenoel

la boucle est bonne. Le souci ici c'est que tu sauvegardes ton objet sans en recréer un nouveau donc ta boucle sauvegarde sur le même objet ce qui fait que tu ne vois que le dernier à la fin.

L'idée est donc de mettre ceci :

Set ObjTask = OlApp.CreateItem(olTaskItem)

dans ta boucle.

Voir ci dessous ce que ça donne :

Sub AjoutTache()
  Dim OlApp As Object
  Dim NS As Object, ObjTask As Object
  Set OlApp = CreateObject("Outlook.Application")
  Set NS = OlApp.GetNamespace("MAPI")
  For i = 2 To 78
     Set ObjTask = OlApp.CreateItem(olTaskItem)
     With ObjTask
        .Subject = "Visite médicale" & " " & Cells(i, 3)
        '.Body = "texte"
        .ReminderTime = Cells(i, 7)
        .ReminderSet = True
        .Display 'mettre en commentaire après mise au point
      End With
      ObjTask.Save
   Next
End Sub

Bonne journée

 

[emilienoel]

Re : Répéter une macro

Bonjour!
merci, ça fonctionne! nickel!!
😉😉😉😉😉😉😉
Bonne journée,
A bientôt!!