Renvoi d'une valeur en fonction d'une plage de valeurs

[minipuce]

Bonjour,

suite au post d'abcd sur ce fil

formule : =CHOISIR(EQUIV(A1;{0;10;12;14});"mauvais";"moyen"; "bon";"très bon")

J'ai voullu l'adapter à mon problème qui est le suivant :
Renvoyer le trimestre en fonction d'une date.
La formule que j'ai saisie est la suivante :

=CHOOSE(MATCH(MONTH(D8),{3,6,9,12}),"Q1","Q2","Q3","Q4")

Seulement, si j'ai le mois de janvier, il ne trouve pas la valeur...

Voila, si quelqu'un peut m'aider.

Merci à tous

Minipuce

 

[Guest]

Re : Renvoi d'une valeur en fonction d'une plage de valeurs

Bonjour Minipuce,

Avec une date en D8:

="Q" & CHOISIR(MOIS(D8);1;1;1;2;2;2;3;3;3;4;4;4)

Je te laisse le soin d'adapter à ta version anglaise.

A+

 

[minipuce]

Re : Renvoi d'une valeur en fonction d'une plage de valeurs

Merci Hasco,

ta formule marche très bien, je te remercie beaucoup, beaucoup.
Bonne journée
Minipuce

 

[abcd]

Re : Renvoi d'une valeur en fonction d'une plage de valeurs

Bonjour,

Essaie ceci :
=CHOISIR(EQUIV(MOIS(A1);{0;4;7;10});"Q1";"Q2";"Q3";"Q4")
comme Hasco, que je salue au passage, je te laisse traduire.

abcd

 

[minipuce]

Re : Renvoi d'une valeur en fonction d'une plage de valeurs

Merci abcd,

je comprends mieux cette formule maintenant, surement adaptable à d'autres problèmes.

Bonne journée
Minipuce

 

[job75]

Re : Renvoi d'une valeur en fonction d'une plage de valeurs

Bonjour minipuce, Hasco, abcd 🙂

Pour le fun, une solution simple :

="Q"&MATCH(MONTH(D8),{1,4,7,10})

A+

 

[Guest]

Re : Renvoi d'une valeur en fonction d'une plage de valeurs

Re tous,

Allez! encore une autre, différente:

="Q" & INT((MONTH(D8)+2)/3)

A+

 

[minipuce]

Re : Renvoi d'une valeur en fonction d'une plage de valeurs

Re tous,

Ben voila, j'ai un autre problème maintenant, je choisis laquelle 🙄 ?
Je rigole, bien sûr, quoi que ...
Merci a vous tous et bonne journée

Minipuce

Edit : une alternative à la formule d'Hasco pour éviter d'ajouter le "+2", mais on ajoute ",0"
="Q" & ROUNDUP((MONTH(D10))/3,0)
Je ne connais pas l'adaptation de "roundup" en français