XL 2016 rendre dynamique la fonction INDIRECT

[piga25]

Bonjour le forum,

Après recherches et de multiples essais, pas moyen de rendre cette formule dynamique:

=NB.SI(INDIRECT(A2&"!"&C$4:C$55);$A4)

J'aimerai quand recopiant vers la droite que cela incrémente les colonnes.

=NB.SI(INDIRECT(A2&"!"&C$4:C$55);$A4)
Devienne
=NB.SI(INDIRECT(A2&"!"&D$4:D$55);$A4)
puis
=NB.SI(INDIRECT(A2&"!"&E$4:E$55);$A4)
ect...

J'ai bien cela qui fonctionne, mais y a t'il pas plus court ou plus simple

=NB.SI(INDIRECT($A$2&"!"&ADRESSE(4;COLONNE();2;;)&":"&ADRESSE(55;COLONNE();2));$A4)

Merci

 

[Johan]

Salut,

Tu figes peut-être mal tes cellules ?

=NB.SI(INDIRECT($A$2&"!"&C4:C55);$A$4)

Mais ca me paraît trop simple pour être ça...

 

[chris]

Bonjour

=NB.SI(INDIRECT($A2&"!L2C"&COLONNE(B2)&":L55C"&COLONNE(B2);0);$A4)

 

[piga25]

Bonjour,
Johan :
J'avais déjà essayé cette solution, le problème c'est que cela recherche bien sur la bonne plage mais pas que la bonne feuille.

Chris :
Plus court que moi.
J'avais complètement zappé cette façon de désigner une cellule (L1C1).

Merci à vous deux.

Je ne sais pas si cela peut se faire en plus court encore.

 

[chris]

Re

Dans la mesure ou ce qu'on utilise à l'intérieur d'INDIRECT est du texte tu ne peux avoir C4 sans guillemets donc pour faire varier la colonne il y a
soit la notation L1C1
soit l'interprétation de la lettre

=NB.SI(INDIRECT($A$2&"!"&CAR(CODE("C")+COLONNE(A1)-1)&"$4:"&CAR(CODE("C")+COLONNE(A1)-1)&"$55");$A4)
ou
=NB.SI(INDIRECT($A$2&"!"&CAR(CODE("B")+COLONNE(A1))&"$4:"&CAR(CODE("B")+COLONNE(A1))&"$55");$A4)

mais c'est plus long !

 

[piga25]

Bonjour,

Dans la mesure ou ce qu'on utilise à l'intérieur d'INDIRECT est du texte tu ne peux avoir C4 sans guillemets donc pour faire varier la colonne il y a
soit la notation L1C1
soit l'interprétation de la lettre

Effectivement