Microsoft 365 remplissage selon une date

[Moi69]

Bonjour le Forum et Bonne Année

Je suis à la recherche d'une formule qui doit certainement être simple, mais je ne la trouve pas.
Mon souci : je voudrais qu'une cellule me donne le nombre de jours restants selon différentes dates
Un dessin valant plus qu'un long discours, je mets en PJ ma feuille.

Le résultat souhaité serait :
Ma date de référence se situe en D3 (ici le 9/9/2022)
Il faudrait donc que de D17 à D24 le résultat soit 0
En D25 = 22
En D26 = 31
En D27 = 30
En D28 = 31

J'espère avoir été assez clair et je vous remercie d'avance pour les solutions que vous allez m'apporter.

 

[Hasco]

Bonsoir,

Je ne sais pas si je suis dans votre logique, mais s'il s'agit de calculer le nombre de jours cumulés entre le 1/9/2022 et la fin d'un mois égal ou supérieur à cette date, alors de D17 à D28 :

=SI($C17>=$D$10;(FIN.MOIS(C17;0)-$E$3)+1;0)

Vous donnera de Septembre à Décembre 2022 :

septembre-22	22
octobre-22	53
novembre-22	83
décembre-22	114

Pour des données non cumulées :

=SI($C17>=$D$10;(FIN.MOIS(C17;0)-$E$3)+1-SOMME($D$16:$D16);0)

Vous donnera :

septembre-22	22
octobre-22	31
novembre-22	30
décembre-22	31

Autre détail, si c'est la fin de mois de C17:C28 qui compte dans vos calculs, alors vous pourriez avoir dans ces cellules (à tirer de D17 à D28)

=FIN.MOIS(MOIS.DECALER($C$33;LIGNE(1:1)-1);0)

Où Ligne(1:1) vous permet de retourner un nombre de 1 à n

Et en $D17:$D28 :

=SI($C17>=$D$10;(C17-$E$3)+1-SOMME($D$16:$D16);0)

Comme dans le fichier ci-joint

Voyez également en J17:J28 pour exemple la formule suivante qui permet de faire l'économie de la somme des jours précédents :

=SI($C17=FIN.MOIS($E$3;0);$C17-$E$3+1;SI($C17>FIN.MOIS($E$3;0);JOUR($C17)))

Et en colonne K, la plus courte et ma préférée :

=SI($C17>$D$10;MIN($C17-$E$3+1;JOUR($C17)))

cordialement

 

[Moi69]

Waouh... je vais regarder toutes ces formules, je devrais y trouver mon bonheur.
Merci beaucoup