Remplissage automatique d'une plage avec mot clé d'une autre plage

[vic78]

Bonjour à tous,

tout d'abord désolé pour la formulation du sujet, je ne sais pas si c'est très clair.

Je vous expose mon besoin:

J'ai un document excel avec plusieurs feuilles.
Dans la première j'ai une base de données (nom, prénom, téléphone,...). A chaque ligne correspond une personne a qui a été attribué un numéro (le premier que j'ai rentré à le n°001, le second le n°002, etc jusqu'à 80 en gros).

Dans les autres feuilles j'ai des tableaux qui reprennent une partie des infos de la première feuille.

Ma question: est-il possible d'avoir une formule me permettant de taper le numéro d'un de mes amis dans les feuilles 2,3,... qui ferait se remplir automatiquement les autres cellules en allant chercher les infos correspondantes dans la feuille 1?

Je vous met un petit tableau pour l'exemple en pj.

Merci d'avance à tous ceux qui me liront, et avec de la chance pourront m'aider.

Bonne soirée!

 

[Fred0o]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

Bonsoir vic78 et bienvenue sur le forum.

Voici une formule à mettre en C7 de la Feuil2, puis à tirer vers la droite et vers le bas :

=RECHERCHEV($B7;Sheet1!$A$2:$D$4;COLONNE()-1)

A+

 

[Jocelyn]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

Bonjour le Forum,
Bonjour Vic78,

En fichier joint un test, j'ai créer des plages nommées si tu ajoutes des données dans la feuille 1 rien a changer dans les formules, sur la feuille 2 dans les cellules numéro j'ai mis une liste de validation qui reprend tous les numéro de la feuille 1 ici pareil si tu ajoutes des données en feuille 1 la liste ce met a jour .

pour voir les plage nommées onglet formule -> gestionnaire de nom
pour la liste de validation onglet donnée -> Validation des données en ayant sélectionné une cellule contenant la liste

regardes et dis nous

cordialement

EDIT : Bonjour FredOo 🙂, bon il va faloir que j'aprenne a écrire plus vite, le truc c'est que je fais déjà tellement de fautes ça va être une cata🙁 enfin bien content de te croisé 🙂

 

[vic78]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

Tout d'abord merci beaucoup pour vos réponses.

Fred0o, votre formule fonctionne, maintenant je cherche à la comprendre. Pouvez-vous m'expliquer le fonctionnement svp? Et lorsque ma colone avec le numéro est vide, comment puis-je cacher le #N/A?



Jocelyn, merci aussi. Cependant la formule de Fred0o me semble plus simple pour commencer 🙂 je garde tout de même votre méthode pour la suite, on ne sait jamais!


Je vais rajouter une petite question si vous le permettez... est-il possible que dans la feuille 1, se rajoute dans une autre colone le(s) groupe(s) auquel est affecté une personne? J'ai tenté des choses mais souvent ça me dit erreur de redondance.

Encore merci à vous!

 

[Fred0o]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

Re-bonsoir Vic78, Jocelyn,

1°) Correction de la formule :

=SIERREUR(RECHERCHEV($B7;Sheet1!$A$2:$D$4;COLONNE()-1);"")

2°) Explication : SIERREUR => Si le résultat de la formule donne une erreur, alors on prend le résultat situé après le 2° point virgule, sinon le résultat de la formule après le 1° point virgule.

RECHERCHEV : On recherche un élément, puis lorsqu'on l'a trouvé, on renvoie la valeur située dans la nième colonne (nième étant ici renvoyé par la fonction COLONNE()).

COLONNE() : Correspond au n° de colonne dans lequel la fonction se trouve.

3°) Pour ce qui est de la question sur le n° de groupe, je n'ai pas compris ce que tu souhaites faire.

A+

 

[vic78]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

Re-bonsoir,

D'accord pour la formule. Merci pour tant de clarté!

La seconde question: chaque personne de ma liste va être affecté à un groupe (les feuilles 2,3,...).
Y'a-t-il une possibilité pour que, lorsque je rentre une personne dans un groupe (ce que vous venez de m'apprendre à faire), se rajoute sur la feuille 1 le nom du (ou des) groupe dans lequel il est?

Mon but est d'avoir une possibilité de connaitre immédiatement les groupes où sont affectés mes amis en n'ayant pas à chercher dans tous les groupes.

Je pense qu'il faut que je réutilise la formule rechercheV, en sélectionnant plusieurs données en plus c'est cela?

 

[wizzwid]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

Bonsoir, j ai un peu la même question mais je n'ai pas réussi a transposer vos réponses pour mon cas vu mon niveau de débutant.
ci joint le fichier
J'aimerai lorsque je clique sur la liste déroulante (feuille orthopédie colonne E, qu'il y ait un remplissage automatique des colonnes F à R feuille orthopédie ) et ce à partir de la feuille favoris orthopédie.
par ailleurs j'aimerai savoir si c'était possible de ne pas avoir de messages d'erreur lorsque les cases sont laissées vides? Et aussi une fois le remplissage réalisé est il possible de remodivier les informations par la suite.
merci pour votre aide
bien cdt

 

[Jocelyn]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

re,
Bonjour Wizzwid,

1) Alors dans la feuille Orthopédie j'ai supprimertoutes les liste de validation de la colonne F à O, puis dans ces colonnes j'ai mis les formules qui vont prendre les renseignements dans la feuille Favoriortho, de plus ces formule font appel à une plage nommée que tu verras en allant dans onglet Formule -> gestionnaire de nom. les formule sont étendues jusqu'en ligne 40 tu peux le étirées vers le bas sans soucis. des fois ces formules retournent 0 pour les masquer regardes le format personnalisé 0;;.

je n'ai traité que jusqu'a la colonne O si tu veux aller plus loin il suffit d'étire vers la droite.

2) Concernant la liste de validation de la colonne E je l'ai modifiée, elle elle aussi étirée jusqu'en ligne 40, par contre dans liste de debut tu avais plein de cellule vide, alors j'ai créé une feuille liste dans laquelle je récupère les donnée sans doublons et sans cellules de la colonne D de la feuille favoris arthopédie cette nouvelle est nommée et sert donc à la listte de validation si tu ajoutes des donnée dans la feuille favoris orthopédie elle la liste se mettra à jour toutes seule.

la formule de la colonne liste est étirée jusqu'en ligne 30 si tu as besoin tu peux l'étirée vers le bas

Voila si tu as des question n'hésites pas

Cordialement

 

[wizzwid]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

re,
Bonjour Wizzwid,

1) Alors dans la feuille Orthopédie j'ai supprimertoutes les liste de validation de la colonne F à O, puis dans ces colonnes j'ai mis les formules qui vont prendre les renseignements dans la feuille Favoriortho, de plus ces formule font appel à une plage nommée que tu verras en allant dans onglet Formule -> gestionnaire de nom. les formule sont étendues jusqu'en ligne 40 tu peux le étirées vers le bas sans soucis. des fois ces formules retournent 0 pour les masquer regardes le format personnalisé 0;;.

je n'ai traité que jusqu'a la colonne O si tu veux aller plus loin il suffit d'étire vers la droite.

2) Concernant la liste de validation de la colonne E je l'ai modifiée, elle elle aussi étirée jusqu'en ligne 40, par contre dans liste de debut tu avais plein de cellule vide, alors j'ai créé une feuille liste dans laquelle je récupère les donnée sans doublons et sans cellules de la colonne D de la feuille favoris arthopédie cette nouvelle est nommée et sert donc à la listte de validation si tu ajoutes des donnée dans la feuille favoris orthopédie elle la liste se mettra à jour toutes seule.

la formule de la colonne liste est étirée jusqu'en ligne 30 si tu as besoin tu peux l'étirée vers le bas

Voila si tu as des question n'hésites pas

Cordialement

C 'est effectivement ce que je souhaitai faire, mais je pense que sans ton aide je n'aurai jamais réussi.
Un grand merci.
Je vais remettre les listes de validation car de temps en temps j'ai besoin de rentrer les données manuellement, A priori j ai essayé et ca ne fait pas de conflit avec ce que tu as réalisé.

En fait tu n'as pas utilisé la fonction recherchev?

Pour ma culture et que je puisse le reproduire pour la feuille traumato


=SI($E17="";"";INDEX(DECALER(terrainorto;;COLONNE()-6);EQUIV($E17;DECALER(terrainorto;;-1);0)))
à quoi se rapporte terrainorto?
Je ne vois pas dans la formule ou tu demande le chemin vers la feuille favoris orthopédie


Bref pour moi ces formules sont vraiment du chinois mais j'essaye de décortiquer tout ça.

=SI(NBVAL('Favoris orthopedie'!$D$4:$D$103)>=LIGNE()-1;INDEX('Favoris orthopedie'!$D$1:$D$103;MIN(SI(('Favoris orthopedie'!$D$4:$D$103<>"")*(NB.SI(liste!$A$1:A6;'Favoris orthopedie'!$D$4:$D$103)=0);LIGNE('Favoris orthopedie'!$D$4:$D$103))));"")


Je vais essayer de la compléter pour la traumato et reproduire ces formules.
encore merci
Wizzwid

 

[Jocelyn]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

re,

à quoi se rapporte terrainorto?

Dans la formule cette partie est justement le lien vers favoris ortho, pour voir ce à quoi il correspond il faut juste cliquer sur formule dans la barre d'outil puis aller dans gestionnaire des nom ensuite tu clique sur le nom et en bas tu vois a quoi il fait référence.

je n'ai fait qu'une seule plage c'est pour cela que la formule qui ce sert de cette plage contient la fonction décaler cela permet a partir d'une plage de la decaler suivant la colonne ou l'on se trouve et celle dans la quelle on veut chercher, et pour calculer le nombre de colonne a decaler soit en plus soit en moins on ce sert de la fonction colonne qui renvoie le numéro de colonne dans la quelle elle se trouve

ici c'est une colonne entière de la fameuse feuille car pas simple de faire autrement vu le paquet de cellule vide de cette colonne.

autrement eu même endroit tu verras une autre plage nommée qui elle s'ajuste au nombre de valeur de la colonne A de la feuille liste et qui sert a la liste de validation de la colonne E.*

une ou deux explication concernant la formule :

=SI(NBVAL('Favoris orthopedie'!$D$4:$D$103)>=LIGNE()-1;INDEX('Favoris orthopedie'!$D$1:$D$103;MIN(SI(('Favoris orthopedie'!$D$4:$D$103<>"")*(NB.SI(liste!$A$1:A6; 'Favoris orthopedie'!$D$4:$D$103)=0);LIGNE('Favoris orthopedie'!$D$4:$D$103))));"")

la partie SI(NBVAL('Favoris orthopedie'!$D$4:$D$103)>=LIGNE()-1 permet de dire a excel si le nombre de valeur que l'on veut récupérer est supérieur à ligne()-1 qui renvoie 1 placer en ligne 2 2 en ligne 3 etc... a ce moment la on peut aller chercher

INDEX('Favoris orthopedie'!$D$1:$D$103;MIN(SI(('Favoris orthopedie'!$D$4:$D$103<>"")*(NB.SI(liste!$A$1:A6; 'Favoris orthopedie'!$D$4:$D$103)=0);LIGNE('Favoris orthopedie'!$D$4:$D$103))) c'est a dire la valeur de la plus petite ligne défini par MIN(plage;LIGNE('Favoris orthopedie'!$D$4:$D$103) de la plage que l'on définie par les conditions suivantes que les cellule ne soient pas vides 'Favoris orthopedie'!$D$4:$D$103<>"" et que la valeur n''existe pas déjà dans la plage de cellule A1:Aligne() NB.SI(liste!$A$1:A6; 'Favoris orthopedie'!$D$4:$D$103)=0); c'est pour ca que dans liste!$A$1:A6 le numéro de ligne du 2° A n'est pas bloqué par le dollars, a partir de la on regardes dans la plage INDEX('Favoris orthopedie'!$D$1:$D$103 et le numéro renvoyé par min donne l'index (ou numéro de ligne a prendre dans 'Favoris orthopedie'!$D$1:$D$103.

bien évidément dans toute les plages de cellule si tu vas jusqu'a la ligne 600 dans toutes la formule il faut changer les 103 par 600.

j'espère avoir été clair dans le cas contraire n'hésite pas

 

[wizzwid]

Re : Remplissage automatique d'une plage avec mot clé d'une autre plage

Merci pour toutes ces explication et du temps consacré; je vais y travailler ce we...