Remplir liste view

[Florian53]

Bonjour à tous je souhaiterais remplir un listview pour cela voici le code:

Private Sub UserForm_Initialize()


'----- remplissage ListView------------------------
With ListView1
'Définit le nombre de colonnes et Entêtes
With .ColumnHeaders
'Supprime les anciens entêtes
.Clear
'Ajoute 9 colonnes en spécifiant le nom de l'entête
'et la largeur des colonnes
.Add , , "Place", 30
.Add , , "Équipe", 65
.Add , , "Points", 35
.Add , , "Gagné", 35
.Add , , "Nul", 35
.Add , , "Perdu", 35
.Add , , "But Marqués", 60
.Add , , "But encaissés", 60
.Add , , "Différence de but", 75
End With
.View = 3
.Gridlines = True
.FullRowSelect = True
.HideColumnHeaders = False
.LabelEdit = 1

'Remplissage de la 1ere colonne (création de 3 lignes)
With .ListItems
.Add , , "1"
.Add , , "2"
.Add , , "3"
.Add , , "4"
End With

'Remplissage des colonnes 2 et 3 dans la 1ere ligne
. ListView1.ListItems.Add , "AA" & cellule.Row, cellule.Offset(0, 0).Value
.ListItems(1).ListSubItems.Add , , 30

End With
'--------------------------------------------------

'Spécifie l'affichage en mode "Détails"

End Sub

Le problème se situe sur la ligne en gras je souhaiterais remplir la ligne par valeur qui se trouve dans la cellule AA5.

Je n'arrive pas à lui indiquer, merci à vous

 

[Florian53]

Re : Remplir liste view

J'ai essayer avec ce code là en dessous de private sub:

For Each cel In Range("AA5:AH8)
Next

Mais cela ne fonctionne pas non plus

 

[job75]

Re : Remplir liste view

Bonsoir Florian53,

Essayez :

'Remplissage des colonnes 2 et 3, lignes 1 à 4
For i = 1 To 4
With ListView1.ListItems(i).ListSubItems
.Add , , Range("AA" & i + 4)
.Add , , 30
End With
Next

Bonne nuit.

 

[job75]

Re : Remplir liste view

Bonjour Florian53, le forum,

Je crois que j'arrive à lire assez bien dans la boule de cristal, essayez maintenant :

Private Sub UserForm_Initialize()
Dim cel As Range

'----- remplissage ListView------------------------
With ListView1

'Définit le nombre de colonnes et Entêtes
With .ColumnHeaders
'Supprime les anciens entêtes
.Clear
'Ajoute 9 colonnes en spécifiant le nom de l'entête
'et la largeur des colonnes
.Add , , "Place", 30
.Add , , "Équipe", 65
.Add , , "Points", 35
.Add , , "Gagné", 35
.Add , , "Nul", 35
.Add , , "Perdu", 35
.Add , , "But Marqués", 60
.Add , , "But encaissés", 60
.Add , , "Différence de but", 75
End With
.View = 3
.Gridlines = True
.FullRowSelect = True
.HideColumnHeaders = False
.LabelEdit = 1

[COLOR="Red"]'Remplissage des lignes 1 à 4
For Each cel In Range("AA5:AH8")
If cel.Column = 27 Then .ListItems.Add , , cel.Row - 4
.ListItems(cel.Row - 4).ListSubItems.Add , , cel
Next[/COLOR]

End With
'--------------------------------------------------

'Spécifie l'affichage en mode "Détails"

End Sub

A+

 

[Florian53]

Re : Remplir liste view

Merci à toi cela fonctionne .

Sujet résolu