XL 2019 Remplacer recherche sur feuille par une zone définie

[AIXELS]

Bonjour à tous les amis du Forum.
Je vous joint un fichier qui modifie les commentaires.
Tout fonctionne très bien, mais je ne vois pas comment
faire les modifications des commentaires uniquement
dans une zone dont le nom défini est "BASE_COM"
et non dans toutes les cellules de la feuille.

For Each MyCmt In ActiveSheet.Comments
        
        ' comment remplacer la ligne ci-dessus pour ne chercher
        ' que dans les cellules de la zone définies par le nom : "BASE_COM"

Merci pour votre aide.
Bien cordialement.

 

[Jacky67]

Bonjour à tous les amis du Forum.
Je vous joint un fichier qui modifie les commentaires.
Tout fonctionne très bien, mais je ne vois pas comment
faire les modifications des commentaires uniquement
dans une zone dont le nom défini est "BASE_COM"
et non dans toutes les cellules de la feuille.

For Each MyCmt In ActiveSheet.Comments
     
        ' comment remplacer la ligne ci-dessus pour ne chercher
        ' que dans les cellules de la zone définies par le nom : "BASE_COM"

Merci pour votre aide.
Bien cordialement.

Bonjour,
Comme ceci peut-être

Sub Personnaliser_Commentaires()
    Dim MyCmt As Range
    If MsgBox("        Voulez-vous réellemnt" & vbCrLf _
            & "     modifier les commentaires  ?", vbYesNo Or vbQuestion, "Confirmer votre choix...") = 6 Then
        For Each MyCmt In [BASE_COM]
            If Not MyCmt.Comment Is Nothing Then
                ' COMMENT REMPLACER LA LIGNE CI-DESSUS POUR NE CHERCHER
                ' QUE DANS LES CELLULES DE LA ZONE DÉFINIE PAR "BASE_COM"
                With MyCmt.Comment.Shape
                    .TextFrame.AutoSize = True
                    .AutoShapeType = msoShapeRoundedRectangle
                    With .OLEFormat.Object
                        .Font.Name = "Roboto"
                        .Font.Size = 16
                        .Font.ColorIndex = 0
                        .Font.Bold = True
                        .ShapeRange.Fill.ForeColor.RGB = RGB(255, 255, 0)
                        .ShapeRange.Fill.BackColor.RGB = RGB(255, 255, 0)
                        .ShapeRange.Line.BackColor.RGB = 6
                    End With
                End With
            End If
        Next
        MsgBox "Mise en forme des commentaires" & vbCrLf _
             & "        modifiée avec succès", 64, "Traitement terminé"
    End If
End Sub

 

[AIXELS]

Bonjour Jacky67
Merci ta réponse. Elle fonctionne très bien.
Bien cordialement.