Reference a celule

[patrick92]

Bonjour
J'ai deux tableaux sur deux onglets.
Le premier permet de saisir des lignes à la suite.
Le second tableau figurant dans l'onglet N°2 pointe sur le tableau figurant dans l'onglet N° 1. La ligne numero 1 est décomposée dans tous les cas en trois lignes sur le tableau N°2.
Ma question :
Lorsque je suis en e4 du tableau N°2 et que je fais un copier coller sur la ligne e7 je souhaite qu'il vienne chercher la valeur de la cellule b4 du tableau N°1, lorsque je copie et je colle la ligne e7, je souhaite qu'il vienne chercher le contenu de la cellule b5 du tableau N°1...etc
Merci par avance

 

[Tibo]

Re : Reference a celule

Bonjour,

Sans fichier, il va être difficile de te répondre.

Envoie nous un petit bout de fichier (anonymisé et taille < 48.8 ko)

Le tout accompagné d'une petite explication sur le pourquoi du comment.

A te (re)lire avec suffisamment de détails

@+

 

[PascalXLD]

Re : Reference a celule

Bonjour

Fil déplacé sur le bon forum

 

[JCGL]

Re : Reference a celule

Bonjour à tous,

Un essai avec utilisation de :

=SI(MOD(LIGNE();3);B2;INDIRECT("'N1'!A"&$A3))

Utilisation d'une colonne sup en A qui peut être masquée

Aura au moins le mérite de remonter le sujet 😀

A+ à tous

 

[Tibo]

Re : Reference a celule

Bonjour Patrick, salut Pascal et Jean Claude,

Ce que j'ai vu dans le fichier me fait penser très fortement au logiciel que j'utilise tous les jours.

Une proposition pour le journal d'écritures :

Laisser les 2 premières lignes vides puis en A3 :

=SI(INDEX('N1'!$A$3:$A$50;ENT((LIGNE()-3)/3)+1)="";"";
INDEX('N1'!$A$3:$A$50;ENT((LIGNE()-3)/3)+1))

en B3 : le code de ton journal

en C3 :

=SI(A3="";"";CHOISIR(MOD(LIGNE()-3;3)+1;"411TEST"&
INDEX('N1'!$B$3:$B$50;ENT((LIGNE()-3)/3)+1);707;44571))

en D3 :

=SI(A3="";"";INDEX('N1'!$C$3:$C$50;ENT((LIGNE()-3)/3)+1))

en E3 :

=SI(A3="";"";INDEX('N1'!$B$3:$B$50;ENT((LIGNE()-3)/3)+1))

en F3 :

=SI(A3="";"";SI(MOD(LIGNE();3)=0;INDEX('N1'!$D$3:$D$50;ENT((LIGNE()-3)/3)+1);""))

en G3 :

=SI(A3="";"";SI(MOD(LIGNE();3)=0;"";SI(MOD(LIGNE();3)=1;
ARRONDI(INDEX('N1'!$D$3:$D$50;ENT((LIGNE()-3)/3)+1)/1.196;2);F1-G2)))

en H3 : la devise

Formules à recopier vers le bas


On peut aller beaucoup plus loin en gérant les montants négatifs (pour les avoirs par exemple), car je pense (en fait je sais) que les montants négatifs ne sont pas gérés par ton logiciel.

Je te laisse déjà essayer tout ceci.

@+