Récupère les données - VBA

[JANO]

Bonsoir le forum,

j'utilise de puis longtemps le code ci dessous, que vous m'avez aidé à élaborer.

il récupère les données de toutes les feuilles sauf celle nommé objectif.

j'aurais besoin qu'il ignore également toutes les feuilles situées après l'onglet objectif.

mais voila je n'y arrive pas, quelqu'un peut il m'aider.

merci



Sub TraiterToutesLesFeuilles()


Dim CompteurDeFeuille As Byte
For CompteurDeFeuille = 1 To Worksheets.Count
If Sheets(CompteurDeFeuille).Name <> "Objectif" And Sheets(CompteurDeFeuille).Name <> "" And Sheets(CompteurDeFeuille).Name <> "Cumul" Then
With Sheets(CompteurDeFeuille)
.Range("AO6:AW6").Copy
Sheets("Cumul").Range("A" & Sheets("Cumul").Range("A65536").End(xlUp).Row + 1).PasteSpecial Paste:=xlPasteValues
End With
End If
Next

Call mise_en_forme


End Sub

 

[Efgé]

Re : Récupère les données - VBA

Bonjour JANO,
Une proposition :

Sub TraiterToutesLesFeuilles()
Dim CompteurDeFeuille As Byte, Limite As Long
Limite = Sheets("Objectif").Index
    For CompteurDeFeuille = 1 To Worksheets.Count
    If Sheets(CompteurDeFeuille).Name <> "Objectif" And Sheets(CompteurDeFeuille).Name <> "" And Sheets(CompteurDeFeuille).Name <> "Cumul" And Sheets(CompteurDeFeuille).Index < Limite Then
        With Sheets(CompteurDeFeuille)
            .Range("AO6:AW6").Copy
            Sheets("Cumul").Range("A" & Sheets("Cumul").Range("A65536").End(xlUp).Row + 1).PasteSpecial Paste:=xlPasteValues
        End With
    End If
Next
Call mise_en_forme
End Sub

Ps: je ne suis pas certain qu'il faille vérifier si la feuille a un nom.

And Sheets(CompteurDeFeuille).Name <> ""

Cordialement

 

[Robert]

Re : Récupère les données - VBA

Bonsoir Jano, bonsoir le forum,

Peut-être comme ça (modification avant dernière ligne du code) :

Sub TraiterToutesLesFeuilles()
Dim CompteurDeFeuille As Byte
For CompteurDeFeuille = 1 To Worksheets.Count
    If Sheets(CompteurDeFeuille).Name <> "Objectif" And Sheets(CompteurDeFeuille).Name <> "" And Sheets(CompteurDeFeuille).Name <> "Cumul" Then
        With Sheets(CompteurDeFeuille)
            .Range("AO6:AW6").Copy
            Sheets("Cumul").Range("A" & Sheets("Cumul").Range("A65536").End(xlUp).Row + 1).PasteSpecial Paste:=xlPasteValues
        End With
    End If
    If Sheets(CompteurDeFeuille).Name = "Objectif" Then Exit For
Next
Call mise_en_forme
End Sub

[Édition]
Bonsoir Efgé on sé st croisé... Bonne remarque pour les feuilles sans nom... Ça court pas les rues, les champs non plus d'ailleurs (allusion à Modeste et plagiat de Coluche)...

 

[JANO]

Re : Récupère les données - VBA

Merci Robert et Efgé

Je viens d'essayer le code Robert et c'est parfait, je vais pouvoir avancer.

Encore merci et bonne continuation à tous