recherchev avec résultat multiples et sur ligne multiples

[robin du 07]

Bonjour,

Mon but est de faire un classement de mes vendeurs selon les clients, j'ai donc commencé un tableau mais je bloque pour finaliser l'automatisation :

J'aimerai dans ma feuille 2 avoir en case B2 le numéro du client consulter par le vendeur 1 qu'on peux retrouver dans la feuille 1, et en case B3 le deuxième numéro du client consulter par le vendeur 1, etc...

J'essaye donc d'utiliser la recherchev mais sans grand résultat...

 

[job75]

Re : recherchev avec résultat multiples et sur ligne multiples

Bonsoir robin du 07, bienvenue sur XLD,

En B2 de Feuil2 entrez cette formule matricielle :

=SI(LIGNES(B$2:B2)>NB.SI(Feuil1!$A:$A;B$1);"";INDEX(Feuil1!$B:$B;PETITE.VALEUR(SI(Feuil1!$A$2:$A$10=B$1;LIGNE($A$2:$A$10));LIGNES(B$2:B2))))

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

Puis copier/coller la plage B2:B11 sur D2 F2 H2 J2.

Fichier joint.

Nota 1 : il manquait un espace devant le 1 en A9 de Feuil1.

Nota 2 : en Feuil2 les colonnes C E G I K sont bien inutiles.

En B12 on peut mettre la formule =NB(B2:B11) pour compter des nombres.

Ou =NB.SI(B2:B11;"><") pour compter des textes.

Nota 3 : il manquait des signes $ à la formule en B13 pour copier la cellule vers la droite.

A+

 

[robin du 07]

Re : recherchev avec résultat multiples et sur ligne multiples

Merci job75, mais j'ai du mal à comprendre la formule, car dans mon fichier originale, j'ai une liste plus importante de client et mes vendeurs apparaissent qu'au client 100, j'ai donc du mal à retransmettre ta formule dans mon bon fichier du fait surtout que je ne maitrise pas la formule petite.valeur.

Peux donc tu m'expliquer la formule pour que je puisse la réutilisé à ma guise ?

Merci encore pour ton aide.

 

[job75]

Re : recherchev avec résultat multiples et sur ligne multiples

Bonjour robin du 07,

Dans la formule il faut bien sûr adapter les plages au tableau en Feuil1.

Pour que cette adaptation se fasse automatiquement il suffit de rendre ces plages dynamiques par des noms définis :

Vendeur =DECALER(Feuil1!$A$1;;;EQUIV("zzz";Feuil1!$A:$A))
Client =DECALER(Vendeur;;1)

La formule matricielle en Feuil2!B2 devient :

=SI(LIGNES(B$2:B2)>NB.SI(Vendeur;B$1);"";INDEX(Client;PETITE.VALEUR(SI(Vendeur=B$1;LIGNE(Client));LIGNES(B$2:B2))))

Vous aurez des informations sur la fonction PETITE.VALEUR en consultant l'Aide Excel (touche F1).

Fichier (2) où j'ai supprimé les colonnes inutiles.

Edit : une petite aide supplémentaire.

La fonction PETITE.VALEUR analyse une matrice.

Pour voir cette matrice, allez dans la barre de formule, sélectionnez SI(Vendeur=B$1;LIGNE(Client)) et appuyez sur F9.

A+

 

[robin du 07]

Re : recherchev avec résultat multiples et sur ligne multiples

Merci job75, c'est parfait. J'ai pris le temps mais j'ai compris la formule et j'arrive à m'en servir.

+