Rechercher une date dans plusieurs feuilles

[Mathieu]

Bonjour à tous,

Parcourant depuis longtemps le forum, j'ai souvent trouvé des solutions à mes pbs en vba !
Mais là... je coince !
Sur une feuille "Sommaire", je sélectionne une date grâce à un calendrier.
J'aimerais ensuite que cette date soit recherchée dans toutes les feuilles du classeur, et quand elle est trouvée, m'emmener sur la feuille où elle se trouve...

Pour le moment j'en suis là :

Private Sub BoutonOK_Click()
dialogue1.Hide
For Each cell In Sheets(Array("01", "02", "03", "04", "05", "06", "07", "08", "09", "10", "11", "12"))
If cell.Value = Sheets("Sommaire").Range("D9").Value Then
MsgBox "Trouvé la date !" 'pour faire les tests !
Else: MsgBox "Pas trouvé :-(" 'pour faire les tests !
Range("d9").Select 'là en fait je voudrais non pas que le focus se mette sur "d9" de ma première feuille, mais sur la cellule dans la feuille où la date a été trouvée... Clair ?
Exit Sub
End If
Next cell
End Sub

D'avance MERCI pour votre aide !

 

[michel]

bonsoir Mathieu

j'espere que cette macro pourra t'aider


Private Sub BoutonOK_Click()
Dim Cell As Range
Dim Valeur As Date
Dim FirstAddress As String
Dim Feuille As Variant

dialogue1.Hide

Valeur = Sheets("Sommaire").Range("D9").Value
If Valeur = 0 Then Exit Sub

For Each Feuille In Array("01", "02", "03", "04", "05", "06", "07", "08", "09", "10", "11", "12")

With Sheets(Feuille).UsedRange.Cells
Set Cell = .Find(Valeur, LookIn:=xlValues)
If Not Cell Is Nothing Then
FirstAddress = Cell.Address
Do
Sheets(Feuille).Activate
Cell.Select
MsgBox "Date trouvée!"
If MsgBox(" Continuer la recherche", 4, "Message") = vbNo Then Exit Sub

Set Cell = .FindNext(After:=ActiveCell)
Loop While Not Cell Is Nothing And Cell.Address <> FirstAddress
End If
End With

Next Feuille

If FirstAddress = "" Then MsgBox " La donnée " & Valeur & " n'a pas été trouvée dans le classeur . ", , "Message"

End Sub



bonne soiree
MichelXld

 

[Mathieu]

Merci mille fois

Effectivement cela semble fonctionner malgré un petit pb de format de date qui ne devrait pas être trop problématique cela dit !
Bonne soirée
MAT