recherche

[ludo]

bonjour,j'aimerais savoir comment trouver la première cellule vide dans une plage de cellule.
par exemple:
a1: 1 b1: 2 c1 : d1 :3
existe-til une fonction qui donne C1 comme résultat ?
merci pour votre réponse. Ludo.

 

[Dan]

Bonjour,

Tu veux connaitre la référence de la cellule ou simplement visualiser dans ta plage les cellules vides.

dans l'attente de te lire.

@+ Dan

 

[ludo]

je voudrais plutot connaitre la référence de la cellule.
merci pour ta réponse.
Ludo.

 

[Monique]

Bonjour,

Formules matricielles, à valider par ctrl, maj et entrée.

Pour une colonne
Le n° de la colonne
=MIN(SI(A1:H1="";COLONNE(A1:H1)))
L'adresse de la cellule :
=ADRESSE(LIGNE(A1:H1);MIN(SI(A1:H1="";COLONNE(A1:H1)));4)
ou bien, si c'est la 1ère ligne :
=ADRESSE(1;MIN(SI(A1:H1="";COLONNE(A1:H1)));4)

Pour une ligne
Le n° de la ligne
=MIN(SI(A1:A11="";LIGNE(A1:A11)))
L'adresse de la cellule :
=ADRESSE(MIN(SI(A1:A10="";LIGNE(A1:A10)));COLONNE(A1:A10);4)
ou bien si c'est la colonne A :
=ADRESSE(MIN(SI(A1:A10="";LIGNE(A1:A10)));1;4)

=ADRESSE(1;3;4) te donne C1
=ADRESSE(1;3;3) te donne $C1
=ADRESSE(1;3;2) te donne C$1
=ADRESSE(1;3;1) ou bien ADRESSE(1;3) te donne $C$1

 

[Ludo]

Monique,je t'aime.
j'ai appris beaucoup de choses sur Excel depuis hier.
encore merci.
Ludo,
Paris.