Recherche et Tri dynamique selon plage de dates

[Polobe36]

[Résolu] Recherche et Tri dynamique selon plage de dates

Bonjour à tous,

Je cherche à récupérer et trier depuis une matrice (A:C) par ordre décroissant des temps (col. C) en fonction d'une plage de date sélectionnée (I1 et J1).

Je joins un fichier d'exemple.

Peut-être existe t'il déjà un post à ce sujet, aussi merci de m'y aiguiller.

Merci d'avance pour votre aide!

 

[Caillou]

Re : Recherche et Tri dynamique selon plage de dates

Bonjour,

Voir fichier joiont (Feuil2)
1 - Créer une zone de critères
2 - Filtre avancé (Données / Trier et filtrer / Avancé
3 - Trier le résultat

Caillou

 

[Polobe36]

Re : Recherche et Tri dynamique selon plage de dates

Bonjour Caillou,

Merci de ta réponse, effectivement c'est une bonne méthodes, mais je souhterai un résultat automatique par FORMULE (éventuellement VBA exécutée à l'ouverture du fichier).

 

[Caillou]

Re : Recherche et Tri dynamique selon plage de dates

Bonjour,

Pour les formules, je ne sais pas, mais sinon, rien ne t'empêches d'utiliser l'enregistreur de macros pour effectuer les actions que je t'ai décrit dans mon post précédent.
Et ensuite de placer cette macro dans le module du classeur (Sur ouverture !)

Caillou

 

[job75]

Re : Recherche et Tri dynamique selon plage de dates

Bonjour Polobe36, salut Caillou,

Formule matricielle en F4 :

=SI(LIGNES(F$4:F4)>SOMME((Dates>=$I$1)*(Dates<=$J$1));"";INDEX(A:A;GRANDE.VALEUR((Dates>=$I$1)*(Dates<=$J$1)*LIGNE(Dates);LIGNES(F$4:F4))))

A valider par Ctrl+Maj+Entrée et copier/tirer à droite et vers le bas.

Voyez le nom Dates qui définit une plage dynamique.

C'est très classique, il y a de nombreux exemples de ce genre sur le forum.

Fichier joint.

A+

 

[Caillou]

Re : Recherche et Tri dynamique selon plage de dates

Bonjour job75,

Moi, ça m'a toujours impressionné ce genre de formule ! BRAVO 🙂

Caillou

 

[Polobe36]

Re : Recherche et Tri dynamique selon plage de dates

Bonjour job75,
Merci pour la réponse, par contre j'aurais besoin de trier par ordre décroissant la colonne des temps puis rechercher le numéro de ligne correspondant

 

[job75]

Re : Recherche et Tri dynamique selon plage de dates

par contre j'aurais besoin de trier par ordre décroissant la colonne des temps puis rechercher le numéro de ligne correspondant

Je ne comprends pas car c'est ce que fait ma formule matricielle 😕

A+

 

[job75]

Re : Recherche et Tri dynamique selon plage de dates

Re,

Si la colonne B est triée par dates décroissantes et qu'on veut le même ordre en colonne G, utiliser PETITE.VALEUR.

En F4, toujours en matriciel :

=SI(LIGNES(F$4:F4)>SOMME((Dates>=$I$1)*(Dates<=$J$1));"";INDEX(A:A;PETITE.VALEUR(SI((Dates>=$I$1)*(Dates<=$J$1);LIGNE(Dates));LIGNES(F$4:F4))))

Fichier (2).

A+

 

[Polobe36]

Re : Recherche et Tri dynamique selon plage de dates

Re job75,

Ta formule matricielle est nickel, je l'adapterai pour un autre besoin mais pour ce cas là, ce n'est pas tout à fait ce dont j'ai besoin:
par exemple du 01/02/2013 au 28/02/2013 j'ai besoin de retrouver d'abord la valeur 450 puis 250, 120, 90...

désolé je ne suis peut-être pas suffisamment clair

 

[job75]

Re : Recherche et Tri dynamique selon plage de dates

Re,

Oui, je n'avais pas percuté que la 3ème colonne s'appelle "Temps".

Alors j'ai introduit le nom défini TC (Temps corrigé) :

=N(DECALER(Feuil1!$C$1;LIGNE(Dates)-1;))-LIGNE(Dates)/1000000

L'ajout (matriciel) d'une très petite valeur (Edit : négative) permet de distinguer d'éventuels doublons.

La formule matricielle en F4 devient :

=SI(LIGNES(F$4:F4)>SOMME((Dates>=$I$1)*(Dates<=$J$1));"";INDEX(A:A;EQUIV(GRANDE.VALEUR((Dates>=$I$1)*(Dates<=$J$1)*TC;LIGNES(F$4:F4));TC;0)))

Fichier (3) avec le résultat trié sur la colonne H (Temps).

A+

 

[Polobe36]

Re : Recherche et Tri dynamique selon plage de dates

Re job75,

Génial, çà fonctionne à merveille!

Est-il possible de rajouter un critère? En colonne D, j'aurai par exemple un critère défini pour chaque ligne, puis dans le tri, je ne retrouverai que les valeurs concernées par un ou plusieurs critères.

 

[job75]

Re : Recherche et Tri dynamique selon plage de dates

Re,

Il faut absolument que vous compreniez la formule, regardez-la bien.

Pour l'instant il y a 2 critères : (Dates>=$I$1) et (Dates<=$J$1).

Vous pouvez ajouter autant de critères que vous voulez pourvu qu'ils renvoient VRAI ou FAUX.

Mais attention, en matriciel ET se traduit par * (multiplication) et OU par + (addition).

A+

 

[Polobe36]

Re : Recherche et Tri dynamique selon plage de dates

Re,

Très bien, avec tous ces conseils je devrai arriver au resultat souhaité.
Merci beaucoup !