recherche de la position d'une valeur / excel

[rouxnati]

Bonjour à toutes et à tous, j'ai un petit problème à résoudre

En effet, je m'occupe des plannings pour une petite société et j'attribue, en fonction des heures de chacun des codes couleurs pour leur affecter une tache.
Je voudrais donc attribuer automatiquement la couleur par ex le 1er 7:00 à la couleur jaune, le 2e le vert et le 3e le rouge dans la colonne a1:a3.
Avec la fonction equiv dans les formats conditionnelles en mettant la formule est, j'arrive à trouver la position de la 1er cellule qui contient 7:00 et la couleur à associer également :
MFC : LA FORMULE EST : =ET(EQUIV(cible;matrice;ordre)=réf)
puis format vert
*avec en réf dans une colonne contiguë les n°1,2,3 pour faire correspondre la position de equiv avec ces n° pour qu'il mette la couleur mais cela ne fonctionne pas pour le 2e 7:00 avec equiv.
Si quelqu'un a une soluce pour arriver à trouver comment je peux déterminer la position du 2e 7:00, ce serait super : MERCI POUR VOS REPONSES

 

[Tibo]

Re : recherche de la position d'une valeur / excel

Bonjour et bienvenue,

Pour qu'on puisse t'aider, il est préférable de nous joindre un fichier Excel plutôt qu'une image.

A te (re)lire avec ce fichier Excel (un extrait devrait suffire).

@+

 

[rouxnati]

Re : recherche de la position d'une valeur / excel

Merci TIBO de répondre aussi vite, je joins le fichier excel tout de suite.

 

[rouxnati]

Re : recherche de la position d'une valeur / excel

heu, je crois que le fichier n'a pas été pris, je recommence. Oui le fichier est trop lourd, je vais l'alléger.

 

[rouxnati]

Re : recherche de la position d'une valeur / excel

45 ko pour un fichier, c'est pas énorme, mais voici le fichier MERCI

 

[rouxnati]

Re : recherche de la position d'une valeur / excel

Personne n'a d'idée?
Peut-être n'est-il pas possible de rechercher la position de la cellule du 2e 7:00 avec la fonction EQUIV?

Y aurait-il une autre solution?

 

[jeanpierre]

Re : recherche de la position d'une valeur / excel

Bonjour rousnati,

Pour répondre à : "45 ko pour un fichier, c'est pas énorme", il te suffit de le zipper, avec le compresseur de Windows et tu en mets 6 à 7 fois plus si tu n'as pas de macros, un peu moins sinon.

Jean-Pierre

 

[rouxnati]

Re : recherche de la position d'une valeur / excel

Bonjour JeanPierre, tu as raison et je n'y avait pas penser, mais finalement dans le fichier que j'ai envoyé, je n'ai pas besoin de plus car l'exemple est assez explicite mais peut-être as-tu une idée pour rechercher le deuxième 7:00 dans la colonne C62:C78 pour y attribuer une couleur à la cellule?

 

[Tibo]

Re : recherche de la position d'une valeur / excel

re,

Un essai avec cette formule pour ta MFC sur C62:C78 :

=ET($C62=$AD$47;NB.SI($C$62:$C62;$AD$47)<=2)

Même principe pour les autres couleurs

Je te laisse tester

@+

 

[rouxnati]

Re : recherche de la position d'une valeur / excel

Je viens de lire ta formule ; si je l'applique stricto-censu je comprend :c62 doit être égal à 7:00 et la cellule C62, si elle est égale à 7:00 nb.si renvoi 1 et donc 1<2 à ce moment la condition est VRAI et donc à chaque fois que l'on trouvera 7:00 la condition sera VRAI. Donc ta soluce ne me donne que l'endroit où se trouve les 7:00, maintenant ta formule s'applique avec NB.SI($C$62:$C$78.... les conditions sont alors toutes fausses car il y a trois 7:00
Ce que je cherche à faire c'est associer une couleur le violet avec le premier 7:00 dans la colonne C62:C78, en jaune le deuxième 7:00 en C62:C78
Avec la formule equiv, je peux mettre le violet sur le premier 7:00 mais pas de jaune sur le deuxième 7:00.
Mais je pense que ta reflection n'est peut-être pas mauvaise, je me plonge dessus.

 

[Tibo]

Re : recherche de la position d'une valeur / excel

re,

La formule pour la MFC que je t'ai proposé permettait de mettre en violet les 2 premiers 7:00

J'avais pas vu (lu) qu'il fallait une 2ème couleur pour le 2ème 7:00

Correction :

1ère condition :

=ET($C62=$AD$47;NB.SI($C$62:$C62;$AD$47)=1)

+ violet

2ème condition :

=ET($C62=$AD$47;NB.SI($C$62:$C62;$AD$47)=2)

+ jaune

Je te laisse tester

@+

 

[rouxnati]

Re : recherche de la position d'une valeur / excel

re,

La formule pour la MFC que je t'ai proposé permettait de mettre en violet les 2 premiers 7:00

J'avais pas vu (lu) qu'il fallait une 2ème couleur pour le 2ème 7:00

Correction :

1ère condition :

=ET($C62=$AD$47;NB.SI($C$62:$C62;$AD$47)=1)

+ violet

2ème condition :

=ET($C62=$AD$47;NB.SI($C$62:$C62;$AD$47)=2)

+ jaune

Je te laisse tester

@+

GENIAL cela fonctionne si je n'oublie pas d'incrémenter le nb.si
par ex sur la ligne 71
1er condition =et(C71=$AD$47;NB.SI(C62:C71;$AD$47)=1)
2e condition =et(C71=$AD$47;NB.SI(C62:C71;$AD$47)=2)

et en ligne 73
1er condition =et(C73=$AD$47;NB.SI(C62:C73;$AD$47)=1)
2e condition =et(C73=$AD$47;NB.SI(C62:C73;$AD$47)=2)

et ainsi de suite C'EST SUPER GENIAL !!!!!!!
Merci beaucoup TIBO
Peut-être à une prochaine fois certainement.

 

[mick35]

Re : recherche de la position d'une valeur / excel

Bonjour à toutes et à tous, j'ai plusieurs problèmes "jaune" à résoudre et cela devient un casse tête pour moi.🙂

En effet, dans le fichier joint "Jour.xls" j'aimerais que :

1/. Les chiffres ce trouvant dans les cellules B1:H1 devront être comparés aux chiffres contenus dans B2:H5.
Si des chiffres correspondent alors mettre une couleur de remplissage par exemple le "jaune".

J'ai essayé les formules suivantes : =SI.(NB.SI(B2:F5=$B$1;$C$1;$D$1;$E$1;$F$1);"jaune";"") puis =SI.(NB.SI(B2:F5;$B$1:$C$1:$D$1:$E$1:$F$1);"jaune";"") sans succès.
En utilisant la mise en forme conditionnelle : ="1;12;25;30;6;15;9"; ="1:12:25:30:6:15:9"; "1:12:25:30:6:15:9"; "1"+"12"+"25"+"30"+"6"; "15"+"9"; ="1";"12";"25";"30";"6";"15";"9"; 1' 12' 25' 30' 6' 15' 9'; B1;C1;D1;E1;F1;G1;H1; ="B1;C1;D1;E1;F1;G1;H1"; "B1"C1"D1"E1"F1"G1"H1 sans succès.

J'ai repris la formule proposée par Tibo "=ET($C62=$AD$47;NB.SI($C$62:$C62;$AD$47)=2)"
Sauf que la mise en forme conditionnelle propose trois conditions et je n'ai pas compris pourquoi cela fonctionne.
En effet, j'ai télécharger le fichier proposé par rouxnati "PLANNINGS SEPTEMBRE.xls" afin de reproduire et comprendre la mise en forme conditionnelle.
Alors, je trouve les couleurs suivantes et j'aurais aimer savoir si c'était juste :
C71=violet; C73=orange; C74=vert; E71=orange; E72=vert; E73=orange; E74=orange; K70=violet; K72=violet; K73=violet; K74=violet.
Si oui, comment est-il possible d'avoir deux couleurs orange à la suite en E73 et E74 ou bien quatre couleurs violettes en K70:K74 ?
Je ne comprend pas. 😕

2/. Comptabiliser les dates en surbrillance "jaune" sans compter deux fois la même date et mettre le total dans la cellule "L3".
"La première étape je ne l'ai pas passé alors la seconde :
Je baigne dans l'huile. :-(
J'ai essayé avec NB.SI sans succès.

3/. Dans la cellule "L1", afficher la suite des dates mises en surbrillance "jaune" ce trouvant dans les cellules "B2:H5".
Avec NB.SI, je n'ai pas su mettre une suite de nombre séparé par une virgule dans une cellule.
Par conséquent, j'ai essayé avec =CONCATENER(A2;" ";A3), afin de m'afficher deux nombres ou textes dans une cellule.
En fin de compte, je n'ai pas su récupérer la couleur "jaune" et ni mettre une virgule.
Pfiou, pas simple Excel.

Je vous remercie pour votre aide et vos éclaircissements.

mick35

 

[Tibo]

Re : recherche de la position d'une valeur / excel

Bonjour mick et bienvenue,

Pour ce qui est de ta MFC sur les cellules B2:H5, je te propose cette formule :

=NB.SI($B$1:$H$1;B2)

+ couleur jaune

Cette fonction retourne 0 ou 1. Pour Excel, 0 équivaut à FAUX et il n'est donc pas besoin de poser un test.


Pour L3, essaye avec cette formule :

=SOMMEPROD((ESTNUM(EQUIV($B$2:$H$5;$B$1:$H$1;0)))*1)

Pour L1, ça va être plus complexe. Je ne pense pas que ce soit possible avec les fonctions de bases d'Excel (quoique on ne sait jamais, je vais peut-être être démenti). Je songe à une fonction issue de la macro complémentaire morefunc de Laurent Longre (téléchargeable sur le net), mais je ne l'utilise que très peu et ne la maîtrise donc pas.

Par contre, on peut, avec une formule matricielle, mettre les différentes valeurs dans plusieurs cellules successives.

Je te laisse déjà voir les deux premiers points.

@+

 

[Tibo]

Re : recherche de la position d'une valeur / excel

re,

Pour la formule en L1, une solution avec, comme indiqué, une formule matricielle :

=SI(COLONNES($A:A)>SOMME((ESTNUM(EQUIV($B$2:$H$5;$B$1:$H$1;0)))*1);"";INDEX(
$A$1:$H$5;PETITE.VALEUR(SI(ESTNUM(EQUIV($B$2:$H$5;$B$1:$H$1;0));(ESTNUM(EQUIV(
$B$2:$H$5;$B$1:$H$1;0)))*LIGNE($A$2:$A$5));COLONNES($A:A));MOD(PETITE.VALEUR(
SI(ESTNUM(EQUIV($B$2:$H$5;$B$1:$H$1;0));(ESTNUM(EQUIV($B$2:$H$5;$B$1:$H$1;0)))*
LIGNE($A$2:$A$5)+(ESTNUM(EQUIV($B$2:$H$5;$B$1:$H$1;0)))*COLONNE($B$1:$H$1)/100);
COLONNES($A:A));1)*100))

Formule matricielle, donc à valider par CTRL + MAJ + ENTREE

à recopier vers la droite

Bon, la formule ne gère pas les doublons. Mais je vais faire appel à un ami 😉😛 qui pourrait peut-être nous trouver quelque chose.

Je te laisse tester cette dernière formule.

@+