quel mot apparaît le plus souvent

[BAILAOR]

bonjour,

je souhaite savoir quels sont les mots qui apparaissent le plus souvent dans une feuille excel (lignes 2 à 50 dans les colonnes A, B et C), avoir une colonne (F) où apparaissent les mots et une autre colonne (G) où apparaît le nombre de fois que ce numéro apparaît.

merci

 

[R@chid]

Bonjour @ tous,
avec une formule matricielle de notre cher chef David84.
Voir PJ


Cordialement

 

[BAILAOR]

merci, c'est ce que je cherche, par contre je ne veux pas qu'il s'affiche les noms de la ligne 1, j'ai rajouté des noms sur la ligne 7,8, 9... qui ne sont pas sur les autres lignes et d'autres oui mais les nouveaux mots n'apparaissent pas et les mots qui sont répétés ne sont pas calculés, de plus je souhaiterais rajouter des colonnes.

merci

 

[R@chid]

Bonjour,
oui tu peux redéfinir le champs qui contient les mots.

Cordialement

 

[job75]

Bonjour BAILAOR, salut R@chid, heureux de te revoir 🙂

Solution VBA classique avec un Dictionary :

Sub Compter()
Dim F As Worksheet, ncol%, dest As Range, r As Range, tablo, d As Object, e
Set F = Sheets("Hoja1") 'à adapter
ncol = 3 'à adapter
Set dest = F.[E1] 'à adapter
Set r = F.UsedRange.Resize(, ncol).Offset(1) 'Offset(1) si en-têtes
Application.ScreenUpdating = False
If F.FilterMode Then F.ShowAllData 'si la feuille est filtrée
dest(2).Resize(Rows.Count - dest.Row, 2).Delete xlUp 'RAZ
If r Is Nothing Then Exit Sub
tablo = r 'matrice, plus rapide
Set d = CreateObject("Scripting.Dictionary")
d.CompareMode = vbTextCompare 'la casse est ignorée
For Each e In tablo
    If e <> "" Then d(e) = d(e) + 1
Next
'---restitution---
If d.Count = 0 Then Exit Sub
dest(2).Resize(d.Count) = Application.Transpose(d.keys) 'Transpose limitée à 65536 lignes
dest(2, 2).Resize(d.Count) = Application.Transpose(d.items)
dest(2).Resize(d.Count, 2).Interior.ColorIndex = 19 'jaune clair
dest(2).Resize(d.Count, 2).Borders.Weight = xlThin 'bordures
dest(2).Resize(d.Count, 2).Sort dest(1, 2), xlDescending, dest, , xlAscending, Header:=xlNo 'tri sur les 2 colonnes
dest.Resize(d.Count, 2).Columns.AutoFit 'ajustement largeurs
With F.UsedRange: End With 'actualise la barre de défilement verticale
End Sub

A+

 

[BOISGONTIER]

Bonjour,

Avec une fonction perso -avec classement - (réutilisable)

=frequencetexte(A2:C1000)

Boisgontier

 

[BAILAOR]

Bonjour,
oui tu peux redéfinir le champs qui contient les mots.
Regarde la pièce jointe 1027189

Cordialement

merci, cela fonctionne

 

[BAILAOR]

merci à tous