propriété de label d'après des listes

[dn35]

Bonjour le forum !!!

Bien longtemps que je ne suis pas venue faire un petit tour sur ce forum ...
Mais me revoici, heureuse de tous vous retrouver ... et bien évidemment avec un nouveau problème à vous soumettre.
J'ai un UF avec une série d'option button. Cet uf me sert pour plusieurs choses. Il est déclanché par un clic droit et en fonction de la sélection, la propriété "caption" de chacun est enseignée par une liste. Jusqu'ici pas de problème. Par contre, lorsque j'essaie d'appliquer le même principe à mes labels, cela ne fonctionne plus du tout.

Ci dessous morceau du code qui pose problème

    For x = 1 To 20
        If Worksheets("codes horaires").Range("A2").Offset(x, 0).Value <> "" Then
            UserForm1.Controls(x - 1).Visible = True
            UserForm1.Controls(x - 1).Caption = Worksheets("codes horaires").Range("A2").Offset(x, 0).Value
            UserForm1.Controls(x - 1).Value = False
            UserForm1.Height = x * 24 + 30
            'UserForm1.Label(x - 1).Visible = True
            'UserForm1.Label(x - 1).Caption = Worksheets("codes horaires").Range("B2").Offset(x, 0).Value
            'UserForm1.Label(x - 1).Value = False
        Else
            UserForm1.Controls(x - 1).Visible = False
            'UserForm1.Label(x - 1).Visible = False
        End If
    Next x
    UserForm1.Show
    Cancel = True

ainsi que petit classeur exemple .

Merci !
Bonne journée

Dn

 

[Pierrot93]

Re : propriété de label d'après des listes

Bonjour dn,

attention, la propriété "value" ne s'applique pas au "label", c'est ceci qui doit provoquer un message d'erreur...

bon après midi
@+

 

[Pierrot93]

Re : propriété de label d'après des listes

Re,

A noter également :

UserForm1.Controls("Label" & x - 1).Caption

@+

Edition : plutôt que :

UserForm1.Label(x - 1).Caption

 

[Cousinhub]

Re : propriété de label d'après des listes

Bonjour la Bretagne

Bonjour, Pierrot

essaie avec ce code :

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
Dim x As Integer
If Not Intersect(Target, Range("E6:R56")) Is Nothing Then
    Cancel = True
    With UserForm1
        For x = 1 To 20
            If Worksheets("codes horaires").Range("A2").Offset(x, 0).Value <> "" Then
                .Controls("OptionButton" & x).Visible = True
                .Controls("OptionButton" & x).Caption = Worksheets("codes horaires").Range("A1").Offset(x, 0).Value
                .Controls("Label" & x).Caption = Worksheets("codes horaires").Range("A1").Offset(x, 1).Value
                .Controls("OptionButton" & x).Value = False
                .Height = x * 24 + 30
            Else
                .Controls("OptionButton" & x).Visible = False
            End If
        Next x
        .Show
    End With
End If
End Sub

Bonne soirée

 

[dn35]

Re : propriété de label d'après des listes

Bonjour bhbh, Pierrot

Simple, efficace et sans bavures ... en un mot parfait. Les deux solutions fonctionnent à merveille.
Par contre il était temps que je revienne faire un tour par ici, je me suis rouillée et suis en train de perdre les connaissances acquises grace à vous tous. J'y retourne !!!

La Bretagne (ensolleillée si si je vous jure) vous remercie encore !

Bonne journée

DN