probleme planning

[pkerga]

bonjour,
je suis entrain d'essayer de réaliser un fichier excel pour faire les gardes du service d'urgences dans lequel je travail.
J'ai qq problèmes (CF piece jointe) :
- l'objetif est que soit rempli les 2 colonnes "Med" et "Chir". La personne en "Med" pour un jour donné est celle sur pour laquelle je mets "SBM" et celle en "Chir" est celle "SBC". Comment rendre cela automatique. Par exemple le lundi 31, BLT est de garde en Med, comment mettre ses initiales automatiquement en E6 ?
- un "x" et une case grisée signifie que l'on ne peut pas etre de garde. Comment griser automtiquement les jours d'après et parfois d'avant les gardes et mettre les gardes en rouge (Cf tableau de W5 à AC7)
- quelles solutions pour me dire : "j'ai mis qq de garde alors que sa case est grisée" et "j'ai mis 2 personnes sur la meme garde".
Je ne peux pas utiliser de VBA car le fichier est distribué dans un hopital ou les versions d'excel ne l'accepte pas.
merci de votre aide précieuse.
Pierre

 

[piga25]

Re : probleme planning

Bonjour,

Un essai à mettre en E6 :

=SIERREUR(INDEX($G$5:$L$5;EQUIV("SBM";$G6:$L6;0));"")

en F6:

=SIERREUR(INDEX($G$5:$L$5;EQUIV("SBC";$G6:$L6;0));"")

Modif : Ajout
Pour excel 2003
en E6

=SI(ESTNA(INDEX($G$5:$L$5;EQUIV("SBM";$G6:$L6;0)));"";INDEX($G$5:$L$5;EQUIV("SBM";$G6:$L6;0)))

En F6

=SI(ESTNA(INDEX($G$5:$L$5;EQUIV("SBC";$G6:$L6;0)));"";INDEX($G$5:$L$5;EQUIV("SBC";$G6:$L6;0)))

 

[pkerga]

Re : probleme planning

Merci bcp, ça marche nickel, 1er probleme résolu !
CF piece jointe
J'ai resolu le pb "j'ai mis 2 personnes sur la meme garde", cela met en rose la case doublée.

Reste 2 pb :
- un "x" et une case grisée signifie que l'on ne peut pas etre de garde. Comment griser automtiquement les jours d'après et parfois d'avant les gardes et mettre les gardes en rouge (Cf tableau de W5 à AC7)

-avertissment "j'ai mis qq de garde alors que sa case est grisée"

Pierre

Bonjour,

Un essai à mettre en E6 :

=SIERREUR(INDEX($G$5:$L$5;EQUIV("SBM";$G6:$L6;0));"")

en F6:

=SIERREUR(INDEX($G$5:$L$5;EQUIV("SBC";$G6:$L6;0));"")

Modif : Ajout
Pour excel 2003
en E6

=SI(ESTNA(INDEX($G$5:$L$5;EQUIV("SBM";$G6:$L6;0)));"";INDEX($G$5:$L$5;EQUIV("SBM";$G6:$L6;0)))

En F6

=SI(ESTNA(INDEX($G$5:$L$5;EQUIV("SBC";$G6:$L6;0)));"";INDEX($G$5:$L$5;EQUIV("SBC";$G6:$L6;0)))

 

[piga25]

Re : probleme planning

Re

Si tout bien compris un essai comme ceci pour les MFC
Si garde :

=OU(G6=$X$6;G6=$Y$6;G6=$Z$6;G6=$AA$6;G6=$AB$6;G6=$AC$6)

couleur = rouge
Si x ou garde jour avant et jour après :

=OU(G7=$X$6;G7=$Y$6;G7=$Z$6;G7=$AA$6;G7=$AB$6;G7=$AC$6;G5=$X$6;G5=$Y$6;G5=$Z$6;G5=$AA$6;G5=$AB$6;G5=$AC$6;G6="x")

couleur = gris

le tout appliqué au tableau : =$G$6:$L$37

 

[pkerga]

Re : probleme planning

merci bcp, ca marche impeccable !
Il me reste 1 probleme :
j'ai fait un tableau de stat (CF piece jointe) et je me demande comment faire pour compter le nombre de jour de WE, Sam et Dim (de manière automatique histoire que je puisse copier les feuilles des mois suivants et des années suivantes), case G43 (WEM = WE du mois et WEA = WE année). Même problème pour les vendredi et les lundi.

 

[piga25]

Re : probleme planning

Bonjour

A mettre en
G42 (C/M) : =SI(ESTERREUR(G$49/G$50);"";G$49/G$50)
G43 (WeM): =SOMMEPROD((JOURSEM($C$6:$C$37;2)>5)*(ESTTEXTE(G$6:G$37)))
G44 (WeA): =G43 (pour janvier) pour les autres mois : =G43 + mois précédent
G45 (VeM): =SOMMEPROD((JOURSEM($C$6:$C$37;2)=5)*(ESTTEXTE(G$6:G$37)))
G46 (LuM): =SOMMEPROD((JOURSEM($C$6:$C$37;2)=1)*(ESTTEXTE(G$6:G$37)))

 

[pkerga]

Re : probleme planning

merci bcp, tout marche au poil !!!

 

[pkerga]

Re : probleme planning

bonjour,
le fichier excel est en utlisation et on me rapporte des problème de stat.
Le problème est que nous utilisons le remplissage par "x" pour un jour off et qu'il est comptabilisé en tant que jour travaillé (pour les WE du mois case G44 ou pour les vendredi du mois case G50) par la formule
=SOMMEPROD((JOURSEM($C$6:$C$37;2)>5)*(ESTTEXTE(G$6:G$37)))
qui ne fait pas le distinguo entre "chir" ou "med" et un "x".
Merci de votre aide.

 

[pkerga]

Re : probleme planning

ai essayé de trouver une solution auprès des informaticiens de mon hosto, ils n'ont pas réussi mais il ne maitrisent pas trop excel. QQ a une idée ?

 

[piga25]

Re : probleme planning

Bonjour,

Un essai en G44 et a recopier vers la droite

=SOMMEPROD((JOURSEM($C$6:$C$37;2)>5)*((G$6:G$37)="X"))

puis en G50

=SOMMEPROD((JOURSEM($C$6:$C$37;2)=5)*((G$6:G$37)="X"))

 

[pkerga]

Re : probleme planning

merci, ca roule !!!