Probleme formule AUJOURDHUI et MOIS.DECALER

[edlihtamm]

Bonjour,

Je vous expose ma situation pour que vous compreniez bien...
Je souhaite faire un tableau de gestion de stocks de produits d'occasions. Quand on reprend un produit chez un client, il est remis à la vente pour occasion. Pendant les 2 mois qui suivent la reprise, c'est le commercial qui a repris le produit qui a le droit exclusif de la vendre, ensuite elle passe dans le "pot commun".

J'ai donc créé un tableau Excel avec les colonnes suivantes :
- date de retour
- vendu par
- etat machine > je voudrais que cette colonne indique automatiquement, en fonction de la date du jour, si elle est dans le pot commun ou si elle appartien encore au commercial qui l'a vendue.

Ma formule est la suivante : =SI(AUJOURDHUI()>=MOIS.DECALER(A7;2);"Pot commun";B7)

Elle marche parfaitement quand le fichier est sur mon poste, mais pas quand je l'envoie à quelqu'un d'autre où l'erreur #NOM? s'affiche.

Aidez-moi please, mon cerveau commence à fumer de désespoir 😉
Merci !

Mathilde

 

[hoerwind]

Re : Probleme formule AUJOURDHUI et MOIS.DECALER

Bonjour et bienvenu sur le forum,

La fonction MOIS.DECALER fait partie des macros complémentaires du menu Outils.
Probablement que l'utilitaire d'analyse est coché sur ton poste et par sur les autres.

La formule MOIS.DECALER(A7;2) peut être remplacée par :

=DATE(ANNEE(A7);MOIS(A7)+2;JOUR(A7))

 

[david84]

Re : Probleme formule AUJOURDHUI et MOIS.DECALER

Bonjour,
vois sur quelle version d'excel la personne qui reçoit ton doc travaille.
Peut-être que la fonction utilisée n'est pas compatible avec sa version ou bien qu'elle doit être activée dans le cadre des macros complémentaires.
Cordialement

 

[job75]

Re : Probleme formule AUJOURDHUI et MOIS.DECALER

Bonjour le fil,

Pas d'accord avec hoerwind car en entrant 31/01/2009 en A1 :

=MOIS.DECALER(A1;1) renvoie 28/02/2009

=DATE(ANNEE(A1);MOIS(A1)+1;JOUR(A1)) renvoie 03/03/2009

Par contre :

=MIN(DATE(ANNEE(A1);MOIS(A1)+1;JOUR(A1));DATE(ANNEE(A1);MOIS(A1)+2;0))

renvoie bien 28/02/2009. Donc avec un décalage n, formule :

=MIN(DATE(ANNEE(A1);MOIS(A1)+n;JOUR(A1));DATE(ANNEE(A1);MOIS(A1)+n+1;0))

A+

 

[edlihtamm]

Re : Probleme formule AUJOURDHUI et MOIS.DECALER

Bonjour à tous et merci pour vos réponses !
Vais tester vos solutions, je vous tiens au jus !
Bonne journée,
Mathilde