Problème extraction de données

[gestel]

Bonjour à Tous,

Je suis loin d'être un pro en macro et je n'ai pas réussi à appliquer les exemples cités dans le forum.

J'aimerai extraire le nombre de données correspondantes aux critères réf. site de la colonne A depuis la base de données sur la feuille Export sachant que le liste de client va s'allonger.
L'extraction doit se faire sans TCD.

Ci-joint le fichier en exemple.
Vous remerciant d'avance pour votre aide.

 

[Catrice]

Re : Problème extraction de données

Bonjour,

Je ne comprends pas bien. Il faut extraire dans quel sens ?
Export => Synthese ?
ou
Synthese => Export ?

Quel sont les critères ?
cl2, cl3 ou cl4 etc ...

 

[gestel]

Re : Problème extraction de données

Bonjour Catrice,

Je voudrais extraire d'export vers synthèse.
La colonne A de l'onglet Synthèse représente une référence de site.
On retrouve cette même réf. dans l'onglet Export.

 

[Catrice]

Re : Problème extraction de données

Re,

Je doute d'avoir tout compris (par rapport aux données que je vois dans la feuille) mais ci-joint un fichier avec une solution basée sur les filtres elaborés piloté par une petite macro.
Dis moi si c'est que tu cherches à faire.

 

[gestel]

Re : Problème extraction de données

Catrice,

Je me suis mal exprimé, désolé.
En fait je voudrai par exemple qu'en F2 de l'onglet Synthèse s'affiche le nombre de classe Classic avec le modèle 5725 pour le site cl1.

 

[Catrice]

Re : Problème extraction de données

Re,

Je me disait bien qu'il y avait quelque chose d'autre avec ces cellules en jaune 😛
donc ci-joint une formule (zone rose).
Et un exemple avec TCD au passage ...
A+

 

[gestel]

Re : Problème extraction de données

Catrice,

Merci beaucoup, c'est exactement ce que je cherchais.
Je vais pouvoir continuer l'exploitation de mes données.
Merci! Merci! Merci!🙂

 

[gestel]

Re : Problème extraction de données

Catrice,

Vraiment impeccable.

Par contre, je ne comprends pas tout dans la formule =SOMMEPROD((F$1=Export!$F$2:$F$9&" sur "&Export!$E$2:$E$9)*($A2=Export!$D$2:$D$9)*1).
A quoi sert "sur" et la variable déclarée dans le premier onglet?
Répond uniquement si tu as le temps, je chercherai les infos un peu plus tard.
Merci

 

[Catrice]

Re : Problème extraction de données

Bonsoir,

Le nom base servait pour le precedent exemple avec la macro.
Donc plus besoin maintenant...

J'ai créé 3 autres noms dans la feuille export :
ref =DECALER(Export!$D$2;0;0;NBVAL(Export!$D:$D)-1)
modele =DECALER(Export!$E$2;0;0;NBVAL(Export!$E:$E)-1)
classe =DECALER(Export!$F$2;0;0;NBVAL(Export!$F:$F)-1)

Ceci créé des zones dynamiques dans la feuille export (si tu rajoutes des données, elles sont prises en compte).
Ces zones corespondent aux zones qui nous interessent.

Ca permet de simplifier serieusement et d'automatiser la formule dans la feuille Synthese :
=SOMMEPROD((F$1=classe&" sur "&modele)*($A2=ref)*1)

F$1=classe&" sur "&modele => Si F$1 (qui contient par exemple Classic sur 5725L) égale la matrice Classe concatenée (&" sur "&) à la matrice modele on recupere VRAI
Et si $A2=ref (A2 = cl1, cl2 etc..) on récupere VRAI aussi
On multiplie les VRAI et les FAUX on multiplie par 1 et on en fait ma somme (SOMMEPROD) 🙂

Par exemple en F2 la formule renvoie :
=SOMMEPROD({VRAI;FAUX;FAUX;VRAI;FAUX;FAUX;FAUX;VRAI}*{FAUX;FAUX;FAUX;VRAI;FAUX;FAUX;FAUX;VRAI})
C'est une multiplication de 2 matrices
qui donne :
=SOMMEPROD({0;0;0;1;0;0;0;1})
On en fait la somme qui donne 2

Pourquoi " sur " ?
Parce que dans Synthese tes entetes de colonnes sont du type "Classic sur 5725L" et dans export on a par exemple "CLASSIC" dans Classe et "5725L" dans Modele. Pour le moment ça ne "colle" pas.

Comme on veut chercher qq chose d'identique, on reconstruit la meme chose en concatenant, en fait :
"CLASSIC"&" sur "&"5725L" qui donne => "CLASSIC sur 5725L" 😉
Le & est l'opérteur de concatenation.

Enfin, les $ dans la formule sont importants.
$A2=ref on va chercher tjs ce qu'il y a dans la colonne A mais la ligne change
F$1=classe&" sur "&modele on va chercher tjs ce qu'il y a dans la ligne 1 mais la colonne change.

Le $ "fixe" la ligne ou la colonne => en finale une formule pour tout le tableau.
$ = adresse absolue
pas de $ = adresse relative

Rappel : cette méthode a un petit inconvénient. IL FAUT que le contenu des zones Modele et Classe dans export soient identiques à ce qu'on retrouve dans la ligne 1 de Synthese !!
S'il y a des espaces en plus ou en moins, comme ici : "CLASSICsur 5725L" ca ne fonctionne plus.

Ci-joint le fichier modifié.

 

[gestel]

Re : Problème extraction de données

Bonjour Catrice,

Je viens de consulter ta réponse.
Je te remercie pour ta patience et tes explications vraiment bien détaillées et enrichissantes.
Je peux te dire que je garde tout ça bien au chaud.

Merci encore pour ce grand service.

Bonne journée.
Gestel🙂